// URL: https://yukicoder.me/problems/no/303

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  int L; io.getV(L);

  if (L == 2) { io.put(3); io.put!"{exit: true}"("INF"); }

  auto calc(int n)
  {
    auto m = Matrix!GmpInt([[1, 1], [1, 0]]);
    return (m^^(n-2))[0].sum;
  }

  io.put(L);
  io.put(calc(L) - (L%2 == 0 ? calc(L/2)^^2 : GmpInt(0)));
}

struct GmpInt
{
  pure nothrow @nogc @safe
  {
    this(long v)
    {
      __gmpz_init_set_si(&z, v);
    }
    this(ref return scope const GmpInt v)
    {
      __gmpz_init_set(&z, &v.z);
    }
    ~this()
    {
      __gmpz_clear(&z);
    }

    long toLong() const
    {
      return __gmpz_get_si(&z);
    }

    bool opEquals(const GmpInt v) const
    {
      return __gmpz_cmp(&z, &v.z) == 0;
    }
    bool opEquals(T)(T v) const
      if (isIntegral!T)
    {
      return __gmpz_cmp_si(&z, v) == 0;
    }
    int opCmp(const GmpInt v) const
    {
      return __gmpz_cmp(&z, &v.z);
    }
    int opCmp(T)(T v) const
      if (isIntegral!T)
    {
      return __gmpz_cmp_si(&z, v);
    }

    ref GmpInt opAssign(const GmpInt v)
    {
      __gmpz_init_set(&z, &v.z);
      return this;
    }
    ref GmpInt opAssign(T)(T v)
      if (isIntegral!T)
    {
      __gmpz_init_set_si(&z, v);
      return this;
    }

    GmpInt opBinary(string op)(const GmpInt v) const
      if (op == "+" || op == "-" || op == "*" || op == "/" || op == "%")
    {
      auto r = GmpInt(0);
      static      if (op == "+") __gmpz_add(&r.z, &z, &v.z);
      else static if (op == "-") __gmpz_sub(&r.z, &z, &v.z);
      else static if (op == "*") __gmpz_mul(&r.z, &z, &v.z);
      else static if (op == "/") __gmpz_tdiv_q(&r.z, &z, &v.z);
      else static if (op == "%") __gmpz_tdiv_r(&r.z, &z, &v.z);
      return r;
    }
    ref GmpInt opOpAssign(string op)(const GmpInt v)
      if (op == "+" || op == "-" || op == "*" || op == "/" || op == "%")
    {
      static      if (op == "+") __gmpz_add(&z, &z, &v.z);
      else static if (op == "-") __gmpz_sub(&z, &z, &v.z);
      else static if (op == "*") __gmpz_mul(&z, &z, &v.z);
      else static if (op == "/") __gmpz_tdiv_q(&z, &z, &v.z);
      else static if (op == "%") __gmpz_tdiv_r(&z, &z, &v.z);
      return this;
    }

    GmpInt opBinary(string op, U)(U v) const
      if ((op == "+" || op == "-" || op == "*" || op == "/" || op == "%" || op == "^^")
          && isIntegral!U)
    {
      auto r = GmpInt(0);
      static      if (op == "+") __gmpz_add_ui(&r.z, &z, v);
      else static if (op == "-") __gmpz_sub_ui(&r.z, &z, v);
      else static if (op == "*") __gmpz_mul_ui(&r.z, &z, v);
      else static if (op == "/") __gmpz_tdiv_q_ui(&r.z, &z, v);
      else static if (op == "%") __gmpz_tdiv_r_ui(&r.z, &z, v);
      else static if (op == "^^") __gmpz_pow_ui(&r.z, &z, v);
      return r;
    }
    ref GmpInt opOpAssign(string op, U)(U v)
      if ((op == "+" || op == "-" || op == "*" || op == "/" || op == "%" || op == "^^")
          && isIntegral!U)
    {
      static      if (op == "+") __gmpz_add_ui(&z, &z, v);
      else static if (op == "-") __gmpz_sub_ui(&z, &z, v);
      else static if (op == "*") __gmpz_mul_ui(&z, &z, v);
      else static if (op == "/") __gmpz_tdiv_q_ui(&z, &z, v);
      else static if (op == "%") __gmpz_tdiv_r_ui(&z, &z, v);
      else static if (op == "^^") __gmpz_pow_ui(&z, &z, v);
      return this;
    }

    GmpInt abs() const
    {
      auto r = GmpInt(0);
      __gmpz_abs(&r.z, &z);
      return r;
    }
    GmpInt sqrt() const
    {
      auto r = GmpInt(0);
      __gmpz_sqrt(&r.z, &z);
      return r;
    }
    size_t popcnt() const
    {
      return __gmpz_popcount(&z);
    }
    bool probabPrime(int reps = 20) const
    {
      return __gmpz_probab_prime_p(&z, reps) != 0;
    }
  }

  pure nothrow
  {
    @safe this(string s, int base = 10)
    {
      __gmpz_init_set_str(&z, s.toStringz, base);
    }
    @trusted string toString(int base = 10) const
    {
      auto sz = __gmpz_sizeinbase(&z, base);
      auto buf = new char[](sz + 2);
      __gmpz_get_str(buf.ptr, base, &z);
      return buf.ptr.fromStringz.to!string;
    }
  }

  size_t fprint(File f, int base = 10) const
  {
    return __gmpz_out_str(f.getFP, base, &z);
  }

  private
  {
    import std.stdio : File;
    __mpz_struct z;
  }
}

extern(C) pragma(inline, false)
{
  import core.stdc.stdio : FILE;
  alias __mp_limb_t = ulong;

  struct __mpz_struct
  {
    int _mp_alloc;
    int _mp_size;
    __mp_limb_t* _mp_d;
  }

  alias mpz_srcptr = const(__mpz_struct)*;
  alias mpz_ptr = __mpz_struct*;

  pure nothrow @nogc @safe
  {
    void __gmpz_init(mpz_ptr);
    void __gmpz_clear(mpz_ptr);

    void __gmpz_init_set(mpz_ptr, mpz_srcptr);
    void __gmpz_init_set_si(mpz_ptr, long);
    int __gmpz_init_set_str(mpz_ptr, const char*, int);

    void __gmpz_set(mpz_ptr, mpz_srcptr);
    void __gmpz_set_si(mpz_ptr, long);

    long __gmpz_get_si(mpz_srcptr);
    char *__gmpz_get_str(char*, int, mpz_srcptr);
    size_t __gmpz_sizeinbase(mpz_srcptr, int);

    size_t __gmpz_out_str(FILE*, int, mpz_srcptr);

    int __gmpz_cmp(mpz_srcptr, mpz_srcptr);
    int __gmpz_cmp_si(mpz_srcptr, long);

    void __gmpz_add(mpz_ptr, mpz_srcptr, mpz_srcptr);
    void __gmpz_add_ui(mpz_ptr, mpz_srcptr, ulong);
    void __gmpz_sub(mpz_ptr, mpz_srcptr, mpz_srcptr);
    void __gmpz_sub_ui(mpz_ptr, mpz_srcptr, ulong);
    void __gmpz_mul(mpz_ptr, mpz_srcptr, mpz_srcptr);
    void __gmpz_mul_ui(mpz_ptr, mpz_srcptr, ulong);
    void __gmpz_tdiv_q(mpz_ptr, mpz_srcptr, mpz_srcptr);
    void __gmpz_tdiv_r(mpz_ptr, mpz_srcptr, mpz_srcptr);
    ulong __gmpz_tdiv_q_ui(mpz_ptr, mpz_srcptr, ulong);
    ulong __gmpz_tdiv_r_ui(mpz_ptr, mpz_srcptr, ulong);
    void __gmpz_pow_ui(mpz_ptr, mpz_srcptr, ulong);

    void __gmpz_abs(mpz_ptr, mpz_srcptr);
    void __gmpz_sqrt(mpz_ptr, mpz_srcptr);
    size_t __gmpz_popcount(mpz_srcptr);
    int __gmpz_probab_prime_p(mpz_srcptr, int reps);
  }
}
pragma(lib, "gmp");

pure nothrow @safe
{
  T powr(alias pred = "a*b", T, U)(const T a, U n, T one)
    if (isIntegral!U)
  {
    auto b = T(a);
    alias predFun = binaryFun!pred;
    if (n == 0) return one;
    auto r = one;
    for (; n > 0; n >>= 1) {
      if (n&1) r = predFun(r, b);
      b = predFun(b, b);
    }
    return r;
  }
  T powr(alias pred = "a*b", T, U)(const T a, U n)
    if (isIntegral!U)
  {
    return powr!(pred, T, U)(a, n, T(1));
  }
}

struct Vector(T)
{
  size_t n;
  @property T[] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    this(size_t n, T zero = T(0))
      in { assert(n > 0); }
    do
    {
      this.n = n; this.zero = zero;
      a = new T[](n);
      if (T.init != zero)
        foreach (i; 0..n) a[i] = zero;
    }
    this(U)(U[] b, T zero = T(0))
      in { assert(b.length > 0); }
    do
    {
      n = b.length; this.zero = zero;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[](n);
        foreach (i; 0..n) a[i] = b[i];
      }
    }
    this(ref return scope const Vector!T v)
    {
      n = v.n; zero = v.zero;
      a = new T[](n);
      foreach (i; 0..n) a[i] = v.a[i];
    }

    Vector!T dup() const
    {
      return Vector!T(this);
    }

    Vector!T opBinary(string op)(const Vector!T b) const
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = mixin("a[i]"~op~"b.a[i]");
      return x;
    }
    ref Vector!T opOpAssign(string op)(const Vector!T b)
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      foreach (i; 0..n) mixin("a[i]"~op~"=b.a[i];");
      return this;
    }
    Vector!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!T)
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = a[i]*b;
      return x;
    }
    ref Vector!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!T)
    {
      foreach (i; 0..n) a[i] *= b;
      return this;
    }
    T opBinary(string op: "*")(const Vector!T b) const
      in { assert(n == b.n); }
    do
    {
      auto x = T(zero);
      foreach (i; 0..n) x += a[i]*b.a[i];
      return x;
    }
  }

  private
  {
    T[] a;
    T zero;
  }
}

pure nothrow @safe
{
  auto vector(T)(T[] a, T zero = T(0))
  {
    return Vector!T(a, zero);
  }
  T hypot2(T)(const Vector!T a)
  {
    return a*a;
  }
  pure Vector!T cross(T)(Vector!T a, Vector!T b)
    in { assert(a.n == 3 && b.n == 3); }
  do
  {
    return Vector!T([a[1]*b[2]-a[2]*b[1], a[2]*b[0]-a[0]*b[2], a[0]*b[1]-a[1]*b[0]], a.zero);
  }
}

struct Matrix(T)
{
  size_t r, c;
  @property T[][] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    static Matrix!T unit(size_t n, T zero = T(0), T one = T(1))
      in { assert(n > 0); }
    do
    {
      auto r = Matrix!T(n, n, zero, one);
      foreach (i; 0..n) r[i][i] = one;
      return r;
    }

    this(size_t r, size_t c, T zero = T(0), T one = T(1))
      in { assert(r > 0 && c > 0); }
    do
    {
      this.r = r; this.c = c; this.zero = zero; this.one = one;
      a = new T[][](r, c);
      if (T.init != zero)
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = zero;
    }
    this(U)(U[][] b, T zero = T(0), T one = T(1))
      in { assert(b.length > 0 && b[0].length > 0 && b.all!(l => l.length == b[0].length)); }
    do
    {
      r = b.length; c = b[0].length; this.zero = zero; this.one = one;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[][](r, c);
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = b[i][j];
      }
    }
    this(ref return scope const Matrix!T v)
    {
      r = v.r; c = v.c; zero = v.zero; one = v.one;
      a = new T[][](r, c);
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] = v.a[i][j];
    }

    Matrix!T dup() const
    {
      return Matrix!T(this);
    }

    bool opEquals(Matrix!T b) const
    {
      return r == b.r && c == b.c && zip(a, b.a).all!"a[0]==a[1]";
    }

    Matrix!T opBinary(string op)(const Matrix!T b) const
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = mixin("a[i][j]"~op~"b.a[i][j]");
      return x;
    }
    ref Matrix!T opOpAssign(string op)(const Matrix!T b)
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      foreach (i; 0..r) foreach (j; 0..c) mixin("a[i][j]"~op~"=b.a[i][j];");
      return this;
    }
    Matrix!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!U)
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = a[i][j]*b;
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!U)
    {
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] *= b;
      return this;
    }
    Matrix!T opBinary(string op: "*")(const Matrix!T b) const
      in { assert(c == b.r); }
    do
    {
      auto x = Matrix!T(r, b.c, zero, one);
      foreach (i; 0..r) foreach (j; 0..b.c) foreach (k; 0..c) x[i][j] += a[i][k]*b.a[k][j];
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*")(const Matrix!T b)
      in { assert(c == b.r); }
    do
    {
      auto x = this*b;
      r = x.r; c = x.c; a = x.a;
      return this;
    }
    Vector!T opBinary(string op: "*")(const Vector!T b) const
      in { assert(c == b.n); }
    do
    {
      auto x = Vector!T(r, zero);
      foreach (i; 0..r) foreach (j; 0..c) x[i] += a[i][j]*b.a[j];
      return x;
    }
    Matrix!T opBinary(string op: "^^", U)(U n) const
      if (isIntegral!U)
      in { assert(r == c); }
    do
    {
      return powr(this, n, Matrix!T.unit(r, zero, one));
    }
  }

  private
  {
    T[][] a;
    T zero, one;
  }
}

pure nothrow @safe
{
  auto matrix(T)(T[][] a, T zero = T(0), T one = T(1))
  {
    return Matrix!T(a, zero, one);
  }

  T det(T)(Matrix!T a)
    in { assert(a.r == a.c); }
  do
  {
    auto n = a.r, b = a.dup, d = a.one;

    foreach (i; 0..n) {
      auto p = i;
      foreach (j; i+1..n)
        if (b[p][i].abs < b[j][i].abs) p = j;
      swap(b[p], b[i]);
      foreach (j; i+1..n)
        foreach (k; i+1..n)
          b[j][k] -= b[i][k]*b[j][i]/b[i][i];
      d *= b[i][i];
      if (p != i) d = -d;
    }

    return d;
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}