func main()
	var x: []int :: #[5]int
	var y: []int :: #[5]int
	for i(0, 4)
		do x[i] :: cui@inputInt()
		do y[i] :: cui@inputInt()
	end for
	
	for i(0, 2)
		for j(i + 1, 3)
			var xij: int :: x[i] - x[j]
			var yij: int :: y[i] - y[j]
			for k(j + 1, 4)
				var xjk: int :: x[j] - x[k]
				var yjk: int :: y[j] - y[k]
				if(xij * yjk = xjk * yij)
					do cui@print("NO\n")
					ret
				end if
			end for
		end for
	end for
	
	var target: float :: lib@pi * 3.0
	for i(0, 4)
		for j(0, 4)
			for k(0, 4)
				var t1: float :: f(i, j, k, x, y)
				for l(0, 4)
					var t2: float :: f(j, k, l, x, y)
					for m(0, 4)
						var t3: float :: f(k, l, m, x, y)
						var t4: float :: f(l, m, i, x, y)
						var t5: float :: f(m, i, j, x, y)
						var sum: float :: t1 + t2 + t3 + t4 + t5
						if(target - 0.1 < sum & sum < target + 0.1)
							do cui@print("YES\n")
							ret
						end if
					end for
				end for
			end for
		end for
	end for
	
	do cui@print("NO\n")
	
	func f(i: int, j: int, k: int, x: []int, y: []int): float
		if(i = j | j = k | k = i)
			ret - 100.0
		end if
		var t1: float :: lib@invRot(x[i] $ float, y[i] $ float, x[j] $ float, y[j] $ float)
		var t2: float :: lib@invRot(x[k] $ float, y[k] $ float, x[j] $ float, y[j] $ float)
		var res: float :: t1 - t2
		while(res < 0.0)
			do res :+ 2.0 * lib@pi
		end while
		if(res > lib@pi)
			ret - 100.0
		end if
		ret res
	end func
end func