module main;
// https://kmjp.hatenablog.jp/entry/2015/03/20/0900 より
// 二分探索
import std;

// https://ei1333.github.io/library/structure/union-find/union-find.hpp より
struct UnionFind {
	int[] data;

	this(size_t sz)
	{
		data = [-1].replicate(sz);
	}

	bool unite(int x, int y) {
		x = find(x), y = find(y);
		if (x == y) return false;
		if (data[x] > data[y]) swap(x, y);
		data[x] += data[y];
		data[y] = x;
		return true;
	}

	int find(int k) {
		if (data[k] < 0) return k;
		return data[k] = find(data[k]);
	}

	int size(int k) {
		return -data[find(k)];
	}

	bool same(int x, int y) {
		return find(x) == find(y);
	}

	int[][] groups() {
		int n = data.length.to!int;
		auto ret = new int[][](n);
		foreach (i; 0 .. n) {
			ret[find(i)] ~= i;
		}
		ret = ret.remove!(a => a.empty);
		return ret;
	}
}

int N;
long[] X, Y;
long[][] D;

bool ok(long v)
{
	auto uf = UnionFind(N);
	foreach (x; 0 .. N)
		foreach (y; 0 .. N)
			if (D[x][y] <= v * v)
				uf.unite(x, y);
	return uf.same(0, N - 1);
}

void main()
{
	// 入力
	N = readln.chomp.to!int;
	X = new long[](N), Y = new long[](N);
	foreach (ref x, ref y; lockstep(X, Y))
		readln.chomp.formattedRead("%d %d", x, y);
	// 答えの計算
	D = new long[][](N, N);
	foreach (x; 0 .. N)
		foreach (y; 0 .. N)
			D[x][y] = (X[x] - X[y]) * (X[x] - X[y]) + (Y[x] - Y[y]) * (Y[x] - Y[y]);
	long ans = (1L << 31) - 1;
	foreach_reverse (i; 0 .. 31)
		if (ok(ans - (1L << i))) ans -= 1L << i;
	// 答えの出力(1の位を切り上げ)
	writeln((ans + 9) / 10 * 10);
}