import std.conv, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.container, std.math, std.range, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) throw new EOFException; tokens = readln.split; } auto token = tokens[0]; tokens.popFront; return token; }
int readInt() { return readToken().to!int; }
long readLong() { return readToken().to!long; }
real readReal() { return readToken().to!real; }

void chmin(T)(ref T t, in T f) { if (t > f) t = f; }
void chmax(T)(ref T t, in T f) { if (t < f) t = f; }

int binarySearch(T)(in T[] as, in bool delegate(T) test) { int low = -1, upp = cast(int)(as.length); for (; low + 1 < upp; ) { int mid = (low + upp) >> 1; (test(as[mid]) ? low : upp) = mid; } return upp; }
int lowerBound(T)(in T[] as, in T val) { return as.binarySearch((T a) => (a < val)); }
int upperBound(T)(in T[] as, in T val) { return as.binarySearch((T a) => (a <= val)); }



debug{
long counter;
}

// a^-1 (mod 2^64)
long modInv(long a)
in {
  assert(a & 1, "modInv: a must be odd");
}
do {
  long b = ((a << 1) + a) ^ 2;
  b *= 2 - a * b;
  b *= 2 - a * b;
  b *= 2 - a * b;
  b *= 2 - a * b;
  return b;
}

// a^-1 (mod m)
long modInv(long a, long m)
in {
  assert(m > 0, "modInv: m > 0 must hold");
}
do {
  long b = m, x = 1, y = 0, t;
  for (; ; ) {
    t = a / b;
    a -= t * b;
    if (a == 0) {
      assert(b == 1 || b == -1, "modInv: gcd(a, m) != 1");
      if (b == -1) {
        y = -y;
      }
      return (y < 0) ? (y + m) : y;
    }
    x -= t * y;
    t = b / a;
    b -= t * a;
    if (b == 0) {
      assert(a == 1 || a == -1, "modInv: gcd(a, m) != 1");
      if (a == -1) {
        x = -x;
      }
      return (x < 0) ? (x + m) : x;
    }
    y -= t * x;
  }
}

// 2^-31 a (mod M)
long montgomery(long M)(long a) if (1 <= M && M <= 0x7fffffff && (M & 1))
in {
  assert(0 <= a && a < (M << 31), "montgomery: 0 <= a < 2^31 M must hold");
}
do {
  enum negInvM = -modInv(M) & 0x7fffffff;
  const b = (a + ((a * negInvM) & 0x7fffffff) * M) >> 31;
  return (b >= M) ? (b - M) : b;
}

// FFT on Z / M Z with Montgomery multiplication (x -> 2^31 x)
//   G: primitive 2^K-th root of unity
class FFT(long M, int K, long G)
    if (is(typeof(montgomery!(M)(0))) && K >= 0 && 0 < G && G < M) {
  import std.algorithm : swap;
  import core.bitop : bsf;

  int n, invN;
  long[] g;

  this(int n)
  in {
    assert(!(n & (n - 1)), "FFT.this: n must be a power of 2");
    assert(4 <= n && n <= 1 << K, "FFT.this: 4 <= n <= 2^K must hold");
  }
  do {
    this.n = n;
    this.invN = ((1L << 31) / n) % M;
    g.length = n + 1;
    g[0] = (1L << 31) % M;
    g[1] = (G << 31) % M;
    foreach (_; 0 .. K - bsf(n)) {
      g[1] = montgomery!(M)(g[1] * g[1]);
    }
    foreach (i; 2 .. n + 1) {
      g[i] = montgomery!(M)(g[i - 1] * g[1]);
    }
    assert(g[0] != g[n >> 1] && g[0] == g[n],
           "FFT.this: G must be a primitive 2^K-th root of unity");
    for (int i = 0, j = 0; i < n >> 1; ++i) {
      if (i < j) {
        swap(g[i], g[j]);
        swap(g[n - i], g[n - j]);
      }
      for (int m = n >> 1; (m >>= 1) && !((j ^= m) & m); ) {}
    }
  }

  void fftMontgomery(long[] x, bool inv)
  in {
    assert(x.length == n, "FFT.fftMontgomery: |x| = n must hold");
  }
  do {
    foreach_reverse (h; 0 .. bsf(n)) {
      const l = 1 << h;
      foreach (i; 0 .. n >> 1 >> h) {
        const gI = g[inv ? (n - i) : i];
        foreach (j; i << 1 << h .. ((i << 1) + 1) << h) {
debug{
++counter;
}
          const t = montgomery!(M)(gI * x[j + l]);
          if ((x[j + l] = x[j] - t) < 0) {
            x[j + l] += M;
          }
          if ((x[j] += t) >= M) {
            x[j] -= M;
          }
        }
      }
    }
    for (int i = 0, j = 0; i < n; ++i) {
      if (i < j) {
        swap(x[i], x[j]);
      }
      for (int m = n; (m >>= 1) && !((j ^= m) & m); ) {}
    }
    if (inv) {
      foreach (i; 0 .. n) {
        x[i] = montgomery!(M)(invN * x[i]);
      }
    }
  }

  long[] convolution(long[] a, long[] b)
  in {
    assert(a.length <= n, "FFT.convolution: |a| <= n must hold");
    assert(b.length <= n, "FFT.convolution: |b| <= n must hold");
  }
  do {
    auto x = new long[n], y = new long[n];
    foreach (i; 0 .. a.length) {
      const t = a[i] % M;
      x[i] = (((t < 0) ? (t + M) : t) << 31) % M;
    }
    foreach (i; 0 .. b.length) {
      const t = b[i] % M;
      y[i] = (((t < 0) ? (t + M) : t) << 31) % M;
    }
    fftMontgomery(x, false);
    fftMontgomery(y, false);
    foreach (i; 0 .. n) {
      x[i] = montgomery!(M)(x[i] * y[i]);
    }
    fftMontgomery(x, true);
    foreach (i; 0 .. n) {
      x[i] = montgomery!(M)(x[i]);
    }
    return x;
  }
}

// P0 P1 P2 > 2^90, P0 + P1 + P2 = 2^32 + 3
enum FFT_P0 = 2013265921L;  // 2^27 15 + 1
enum FFT_P1 = 1811939329L;  // 2^26 27 + 1
enum FFT_P2 =  469762049L;  // 2^26  7 + 1
alias FFT0 = FFT!(FFT_P0, 27, 440564289L);  // 31^15
alias FFT1 = FFT!(FFT_P1, 26,  72705542L);  // 13^27
alias FFT2 = FFT!(FFT_P2, 26,      2187L);  //  3^ 7

// Convolution of a and b (indices mod fft0.n)
//   modify a and b so that 0 <= a[i] < m, 0 <= b[i] < m
long[] convolution(FFT0 fft0, FFT1 fft1, FFT2 fft2, long[] a, long[] b, long m)
in {
  assert(fft0.n == fft1.n && fft0.n == fft2.n,
         "convolution: fft0.n = fft1.n = fft2.n must hold");
  assert(1 <= m && m <= 0x7fffffff, "convolution: 1 <= m < 2^31 must hold");
}
do {
  enum FFT_INV01 = modInv(FFT_P0, FFT_P1);
  enum FFT_INV012 = modInv(FFT_P0 * FFT_P1, FFT_P2);
  foreach (i; 0 .. a.length) {
    if ((a[i] %= m) < 0) {
      a[i] += m;
    }
  }
  foreach (i; 0 .. b.length) {
    if ((b[i] %= m) < 0) {
      b[i] += m;
    }
  }
  const x0 = fft0.convolution(a, b);
  const x1 = fft1.convolution(a, b);
  const x2 = fft2.convolution(a, b);
  auto x = new long[fft0.n];
  foreach (i; 0 .. fft0.n) {
    auto y0 = x0[i] % FFT_P0;
    auto y1 = (FFT_INV01 * (x1[i] - y0 + FFT_P1)) % FFT_P1;
    auto y2 = (FFT_INV012 * ((x2[i] - y0 - FFT_P0 * y1) % FFT_P2 + FFT_P2)) % FFT_P2;
    x[i] = (y0 + FFT_P0 * y1 + ((FFT_P0 * FFT_P1) % m) * y2) % m;
  }
  return x;
}

// X^k mod f(X), coefficients in Z / m Z
//   f: monic (array length: deg f)
long[] polyPower(long k, long[] f, long m)
in {
  assert(k >= 0, "polyPower: k >= 0 must hold");
  assert(f.length >= 1, "polyPower: deg f >= 1 must hold");
  assert(1 <= m && m <= 0x7fffffff, "polyPower: 1 <= m < 2^31 must hold");
}
do {
  import core.bitop : bsr;
  const n = cast(int)(f.length);
  auto fRev = new long[n + 1];
  fRev[0] = 1;
  foreach (i; 1 .. n + 1) {
    fRev[i] = f[n - i];
  }

  auto negInvFRev = [m - 1];
  for (int l = 1; l < n; l <<= 1) {
    auto fft0 = new FFT0(l << 2), fft1 = new FFT1(l << 2), fft2 = new FFT2(l << 2);
    auto t = convolution(fft0, fft1, fft2, fRev[0 .. min(l << 1, n + 1)], negInvFRev, m)[0 .. l << 1];
    t[0] += 2;
    negInvFRev = convolution(fft0, fft1, fft2, negInvFRev, t, m)[0 .. l << 1];
  }

  auto a = new long[n];
  if ((a[0] = 1) >= m) {
    a[0] -= m;
  }
  if (k > 0) {
    int nn;
    for (nn = 4; nn < 2 * n; nn <<= 1) {}
    auto fft0 = new FFT0(nn), fft1 = new FFT1(nn), fft2 = new FFT2(nn);
    foreach_reverse (h; 0 .. bsr(k) + 1) {
      a = convolution(fft0, fft1, fft2, a, a, m);
      auto aRev = new long[n];
      foreach (i; 0 .. n) {
        aRev[i] = a[2 * n - 1 - i];
      }
      auto negRevQ = convolution(fft0, fft1, fft2, aRev, negInvFRev, m);
      auto negQ = new long[n];
      foreach (i; 0 .. n) {
        negQ[i] = negRevQ[n - 1 - i];
      }
      auto t = convolution(fft0, fft1, fft2, f, negQ, m);
      foreach (i; 0 .. n) {
        if ((a[i] += t[i]) >= m) {
          a[i] -= m;
        }
      }
      a.length = n;
      if ((k >> h) & 1) {
        a = [0L] ~ a;
        foreach (i; 0 .. n) {
          if (((a[i] -= a[n] * f[i]) %= m) < 0) {
            a[i] += m;
          }
        }
        a.length = n;
      }
    }
  }
  return a;
}



immutable MO = 10L^^9 + 7;
immutable A = [2,3,5,7,11,13];
immutable B = [4,6,8,9,10,12];

long[] getPatterns(int num, in int[] die) {
  const lim = num * die.maxElement;
  auto dp = new long[][](num + 1, lim + 1);
  dp[0][0] = 1;
  foreach (d; die) {
    foreach (i; 0 .. num) foreach (j; d .. lim + 1) {
      (dp[i + 1][j] += dp[i][j - d]) %= MO;
    }
  }
  return dp[num];
}

long N;
int P, Q;

void main() {
  try {
    for (; ; ) {
debug{
counter=0;
}
      N = readLong();
      P = readInt();
      Q = readInt();
      
      auto patA = getPatterns(P, A);
      auto patB = getPatterns(Q, B);
      
      const d = (cast(int)(patA.length) - 1) + (cast(int)(patB.length) - 1);
      int dd;
      for (dd = 4; dd < d; dd <<= 1) {}
      auto pat = convolution(new FFT0(dd), new FFT1(dd), new FFT2(dd), patA, patB, MO);
      auto f = new long[d];
      foreach (i; 0 .. d) {
        f[i] = -pat[d - i];
      }
      debug {
        writeln(patA[0 .. min($, 30)]);
        writeln(patB[0 .. min($, 30)]);
        writeln(pat[0 .. min($, 30)]);
        writeln("d = ", d);
      }
      
      const res = polyPower(N + d - 1, f, MO);
      long ans = res.sum % MO;
      writeln(ans);
debug{
writeln("counter = ",counter);
stdout.flush;
}
    }
  } catch (EOFException e) {
  }
}