// URL: https://yukicoder.me/problems/no/171

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  string S; io.getV(S);

  auto c = new int[](26);
  foreach (Si; S) ++c[Si-'A'];

  auto cn = 1000, primes = Prime(cn.isqrt);
  auto f = new int[](cn+1), n = cast(int)S.length;
  foreach (i; 2..n+1)
    foreach (e; primes.div(i)) f[e.prime] += e.exp;

  foreach (ci; c)
    foreach (i; 2..ci+1)
      foreach (e; primes.div(i)) f[e.prime] -= e.exp;

  auto r = mint(1);
  foreach (i, fi; f)
    r *= mint(i)^^fi;

  io.put(r-1);
}

pure T isqrt(T)(T n)
{
  static if (is(T == int)) auto max = 46341;
  else static if (is(T == long)) auto max = 3037000500L;
  auto bs = iota(T(0), max).map!(x => tuple(x, x^^2)).assumeSorted!"a[1]<=b[1]";
  return bs.lowerBound(tuple(0, n)).back[0];
}

pure T icbrt(T)(T n)
{
  static if (is(T == int)) auto max = 1291;
  else static if (is(T == long)) auto max = 2097152L;
  auto bs = iota(T(0), max).map!(x => tuple(x, x^^3)).assumeSorted!"a[1]<=b[1]";
  return bs.lowerBound(tuple(0, n)).back[0];
}

pure T powr(alias pred = "a*b", T, U)(T a, U n, T one)
{
  import std.functional;
  alias predFun = binaryFun!pred;
  if (n == 0) return one;
  auto r = one;
  for (; n > 0; n >>= 1) { if (n&1) r = predFun(r, a); a = predFun(a, a); }
  return r;
}
pure T powr(alias pred = "a*b", T, U)(T a, U n) { return powr!(pred, T, U)(a, n, T(1)); }

pure T extGcd(T)(T a, T b, out T x, out T y)
{
  auto g = a; x = 1; y = 0;
  if (b) { g = extGcd(b, a%b, y, x); y -= a/b*x; }
  return g;
}

struct Prime
{
  import std.bitmanip;
  struct Factor(T) { T prime; int exp; }

  const int n;
  @property array() { return primes; }
  alias array this;

  this(int n)
  {
    this.n = n;

    auto sieve = BitArray();
    sieve.length((n+1)/2);
    sieve = ~sieve;

    foreach (p; 1..(n.isqrt-1)/2+1)
      if (sieve[p])
        for (auto q = p*3+1; q < (n+1)/2; q += p*2+1)
          sieve[q] = false;

    primes = sieve.bitsSet.map!(p => cast(int)p*2+1).array;
    primes[0] = 2;
  }

  pure Factor!T[] div(T)(T x) in { assert(x > 0 && x.isqrt <= n); } do
  {
    Factor!T[] factors;
    auto t = isqrt(x);
    foreach (p; primes) {
      if (p > t) break;
      auto c = 0;
      for (; x%p == 0; x /= p) ++c;
      if (c > 0) factors ~= Factor!T(p, c);
      if (x == 1) break;
    }
    if (x > 1) factors ~= [Factor!T(x, 1)];
    return factors;
  }

  pure T[] divisors(T)(T x) in { assert(x > 0 && x.isqrt <= n); } do
  {
    auto factors = div(x);
    auto r = divisorsProc(factors, 0, 1);
    r.sort();
    return r;
  }

  private
  {
    int[] primes;

    pure T[] divisorsProc(T)(Factor!T[] factors, int i, T c)
    {
      if (i == factors.length) return [c];
      T[] r;
      foreach (j; 0..factors[i].exp+1)
        r ~= divisorsProc(factors, i+1, c*factors[i].prime^^j);
      return r;
    }
  }
}

const mod = 573;
alias mint = ModInt!mod;

struct ModInt(int m, bool pos = false)
{
  version(BigEndian) union { long l; struct { int i2; int i; } } else union { long l; int i; }
  alias M = ModInt!(m, pos), Op = string;
  @property static init() { return M(0); }
  @property int value() { return i; }
  @property void value(int v) { i = nm(v); }
  alias value this;

  this(T)(T v = 0) { i = nm(v); }
  ref M opAssign(T)(T v) { i = nm(v); return this; }

  static if (!pos) pure M opUnary(Op op: "-")() { return M(-i); }

  static if (m < int.max / 2) {
    pure M opBinary(Op op)(int r) if(op=="+"||!pos&&op=="-") { return M(mixin("i"~op~"r")); }
    ref M opOpAssign(Op op)(int r) if(op=="+"||!pos&&op=="-") { i=nm(mixin("i"~op~"r")); return this; }
  } else {
    pure M opBinary(Op op)(int r) if(op=="+"||!pos&&op=="-") { return M(mixin("l"~op~"r")); }
    ref M opOpAssign(Op op)(int r) if(op=="+"||!pos&&op=="-") { i=nm(mixin("l"~op~"r")); return this; }
  }
  pure M opBinary(Op op: "*")(int r) { return M(l*r); }
  ref M opOpAssign(Op op: "*")(int r) { i=nm(l*r); return this; }

  pure M opBinary(Op op)(M r) if(op=="+"||!pos&&op=="-"||op=="*") { return opBinary!op(r.i); }
  ref M opOpAssign(Op op)(M r) if(op=="+"||!pos&&op=="-"||op=="*") { return opOpAssign!op(r.i); }

  pure M opBinary(Op op: "^^", T)(T n) { return this.powr(n); }

  static if (!pos) {
    pure M opBinary(Op op: "/")(M r) { return M(l*r.inv.i); }
    ref M opOpAssign(Op op: "/")(M r) { i=nm(l*r.inv.i); return this; }

    pure M opBinary(Op op: "/")(int r) { return opBinary!op(M(r)); }
    ref M opOpAssign(Op op: "/")(int r) { return opOpAssign!op(M(r)); }

    pure M inv() { int x = i, a, b; extGcd(x, m, a, b); return M(a); }
  }

  private
  {
    pure int nm(int v) { static if (pos) return v%m; else return (v%m+m)%m; }
    pure int nm(long v) { static if (pos) return cast(int)(v%m); else return cast(int)((v%m+m)%m); }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(string floatFormat = "%.10f", string delimiter = " ", alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits;
  alias assignable = hasAssignableElements;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (assignable!T) { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v) if (allSatisfy!(assignable, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v) if (assignable!T && assignable!(ElementType!T))
  {
    v = new T(r); foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    {
      v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  auto put(bool flush = false, T...)(T v)
  {
    foreach (i, w; v) { putA(w); if (i < v.length-1) OUT.write(delimiter); }
    OUT.writeln;
    static if (flush) OUT.flush();
  }
  auto putB(S, T)(bool c, S t, T f) { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putR(T)(T v)
    {
      auto w = v;
      while (!w.empty) { putA(w.front); w.popFront(); if (!w.empty) OUT.write(delimiter); }
    }
    auto putA(T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putR(v);
      else if (isFloatingPoint!T) OUT.write(format(floatFormat, v));
      else OUT.write(v);
    }
  }
}