// URL: https://yukicoder.me/problems/no/703

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int n; io.getV(n);
  long[] a; io.getA(n, a);
  long[] x; io.getA(n, x);
  long[] y; io.getA(n, y);

  auto dp = new long[](n+1), cht = ConvexHullTrick!long();

  foreach (i; 0..n) {
    cht.add(-2*x[i], dp[i]+x[i]^^2+y[i]^^2);
    dp[i+1] = cht.query(a[i]) + a[i]^^2;
  }

  io.put(dp[n]);
}

struct ConvexHullTrick(T, alias comp = "a>=b")
{
  import std.functional;
  alias compFun = binaryFun!comp;

  void add(T a, T b)
  {
    auto line = Line(a, b);
    while (lines.length >= 2 && check(lines[$-2], lines[$-1], line))
      lines = lines[0..$-1];
    lines ~= line;
  }

  pure T query(T x)
  {
    ptrdiff_t low = -1, high = lines.length-1;
    while (high-low > 1) {
      auto mid = (high+low)/2;
      (compFun(lines[mid].f(x), lines[mid+1].f(x)) ? low : high) = mid;
    }
    return lines[high].f(x);
  }

  private
  {
    struct Line
    {
      T a, b;
      auto opCmp(Line r)
      {
        if (a < r.a) return -1;
        else if (a > r.a) return 1;
        if (b < r.b) return -1;
        else if (b > r.b) return 1;
        return 0;
      }
      auto f(T x) { return a*x+b; }
    }
    Line[] lines;

    bool check(Line l1, Line l2, Line l3)
    {
      if (l1 < l3) swap(l1, l3);
      return (l3.b-l2.b)*(l2.a-l1.a) >= (l2.b-l1.b)*(l3.a-l2.a);
    }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(string floatFormat = "%.10f", string delimiter = " ", alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r); foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    {
      v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  auto put(bool flush = false, T...)(T v)
  {
    foreach (i, w; v) { putA(w); if (i < v.length-1) OUT.write(delimiter); }
    OUT.writeln;
    static if (flush) OUT.flush();
  }
  auto putB(S, T)(bool c, S t, T f) { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putR(T)(T v)
    {
      auto w = v;
      while (!w.empty) { putA(w.front); w.popFront(); if (!w.empty) OUT.write(delimiter); }
    }
    auto putA(T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putR(v);
      else if (isFloatingPoint!T) OUT.write(format(floatFormat, v));
      else OUT.write(v);
    }
  }
}