// URL: https://yukicoder.me/problems/no/743

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int N, M; io.getV(N, M);
  struct E { int a, b; }
  E[] e; io.getS!("a", "b")(N, e);

  foreach (ref ei; e)
    if (ei.a > ei.b) swap(ei.a, ei.b);

  e.sort!"a.a < b.a";

  auto ft = fenwickTree!int(M), r = 0L;
  foreach (ei; e) {
    r += ft[ei.a..ei.b];
    ++ft[ei.b];
  }

  io.put(r);
}

class FenwickTree(T)
{
  const size_t n;

  this(size_t n) { this.n = n; this.buf = new T[](n+1); }

  void opIndexOpAssign(string op)(T val, size_t i) if (op=="+"||op=="-")
  { ++i; for (; i <= n; i += i&-i) mixin("buf[i]"~op~"=val;"); }

  void opIndexUnary(string op)(size_t i) if (op=="++"||op=="--")
  { ++i; for (; i <= n; i += i&-i) mixin(op~"buf[i];"); }

  pure T opIndex(size_t i) { return opSlice(i, i+1); }
  pure T opSlice(size_t r, size_t l) { return get(l) - get(r); }
  pure size_t opDollar() { return n; }

  private
  {
    T[] buf;

    pure T get(size_t i)
    {
      auto s = T(0);
      for (; i > 0; i -= i & -i) s += buf[i];
      return s;
    }
  }
}
FenwickTree!T fenwickTree(T)(size_t n) { return new FenwickTree!T(n); }

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits, core.stdc.stdlib;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  { v = new T(r); foreach (ref w; v) getA(c, w); }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    { v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");"); }
  }

  auto put(alias conf = "{}", T...)(T v)
  { mixin("const PutConf c = "~conf~"; putMain!c(v);"); }
  auto putB(alias conf = "{}", S, T)(bool c, S t, T f)
  { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i < v.length-1) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    auto putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else OUT.write(v);
    }
    auto putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}
const struct PutConf
{
  bool newline = true, flush, exit;
  string floatFormat = "%.10f", delimiter = " ";
}