// URL: https://yukicoder.me/problems/no/751

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int n1; io.getV(n1);
  int[] A; io.getA(n1, A);
  int n2; io.getV(n2);
  int[] B; io.getA(n2, B);

  auto c = frac(A[0], 1);
  foreach (Ai; A[1..$]) c = c*frac(1, Ai);

  auto d = frac(1, 1);
  foreach_reverse (Bi; B) d = frac(Bi, 1)/d;

  auto e = c/d;
  io.put(e.a, e.b);
}

struct Frac(T)
{
  import std.numeric;
  alias F = Frac!T, Op = string;
  T a, b;

  this(T a, T b) in { assert(b != 0); } do { this.a = a; this.b = b; }

  pure bool opEquals(F r) { return a == 0 && r.a == 0 || a == r.a && b == r.b;  }
  pure int opCmp(F r) { return a*r.b<r.a*b ? -1 : a*r.b>r.a*b ? 1 : 0; }

  pure F inv() in { assert(a != 0); } do { return F(b, a).normalizeSign; }
  pure F opUnary(Op op: "-")() { return F(-a, b); }

  pure F opBinary(Op op)(F r) if (op=="+"||op=="-")
  {
    auto g = gcd(b, r.b);
    return F(mixin("r.b/g*a"~op~"b/g*r.a"), b/g*r.b).reduction();
  }
  ref F opOpAssign(Op op)(F r) if (op=="+"||op=="-")
  {
    auto g = gcd(b, r.b);
    a = mixin("r.b/g*a"~op~"b/g*r.a"); b = b/g*r.b; return reduction();
  }

  pure F opBinary(Op op: "*")(F r)
  {
    auto g1 = gcd(a.abs, r.b), g2 = gcd(r.a.abs, b);
    return F((a/g1)*(r.a/g2), (b/g2)*(r.b/g1));
  }
  ref F opOpAssign(Op op: "*")(F r)
  {
    auto g1 = gcd(a.abs, r.b), g2 = gcd(r.a.abs, b);
    a = (a/g1)*(r.a/g2); b = (b/g2)*(r.b/g1); return this;
  }

  pure F opBinary(Op op: "/")(F r) in { assert(r.b != 0); } do
  {
    auto g1 = gcd(a.abs, r.a.abs), g2 = gcd(b, r.b);
    return F((a/g1)*(r.b/g2), (b/g2)*(r.a/g1)).normalizeSign();
  }
  ref F opOpAssign(Op op: "/")(F r) in { assert(r.b != 0); } do
  {
    auto g1 = gcd(a.abs, r.a.abs), g2 = gcd(b, r.b);
    a = (a/g1)*(r.b/g2); b = (b/g2)*(r.a/g1); return normalizeSign();
  }

  private
  {
    ref F reduction() { auto g = gcd(a.abs, b); a /= g; b /= g; return this; }
    ref F normalizeSign() { if (b < 0) { a = -a; b = -b; } return this; }
  }
}
auto frac(T)(T a, T b) { return Frac!T(a, b).normalizeSign().reduction(); }

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits, core.stdc.stdlib;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  { v = new T(r); foreach (ref w; v) getA(c, w); }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    { v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");"); }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  auto put(alias conf = "{}", T...)(T v)
  { mixin("const PutConf c = "~conf~"; putMain!c(v);"); }
  auto putB(alias conf = "{}", S, T)(bool c, S t, T f)
  { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i < v.length-1) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    auto putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else OUT.write(v);
    }
    auto putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}