// URL: https://yukicoder.me/problems/no/759

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int N; io.getV(N);
  struct S { int P, T, R, i; }
  S[] s; io.getS!("P", "T", "R")(N, s);
  foreach (i, ref si; s) {
    ++si.P; ++si.T; ++si.R;
    si.i = cast(int)i;
  }

  s.multiSort!("a.P>b.P", "a.T>b.T", "a.R>b.R");

  auto st = new SegmentTree!(max, int)(10^^4+2), b = new bool[](N);
  b[] = true;

  foreach (si; s) {
    if (st[si.T..$] >= si.R)
      b[si.i] = false;

    st[si.T] = max(st[si.T], si.R);
  }

  foreach (i; 0..N)
    if (b[i]) io.put(i+1);
}

class SegmentTree(alias pred = "a+b", T)
{
  import std.functional;
  alias predFun = binaryFun!pred;
  const size_t n;
  @property auto data() { return buf[an..an+n]; }

  this(size_t n, T dflt = T.init)
  {
    this.n = n;
    this.dflt = dflt;
    an = n == 1 ? 1 : (n-1).nextPow2;
    buf = new T[](an*2);

    if (T.init != dflt) {
      buf[an..an+n][] = dflt;
      propagateAll();
    }
  }

  this(T[] init, T dflt = T.init)
  {
    this.n = init.length;
    this.dflt = dflt;
    an = (n-1).nextPow2;
    buf = new T[](an*2);

    buf[an..an+n][] = init[];
    propagateAll();
  }

  void opIndexAssign(T val, size_t i)
  { buf[i+=an] = val; propagate(i); }

  void opIndexOpAssign(string op)(T val, size_t i)
  { mixin("buf[i+=an]"~op~"=val;"); propagate(i); }

  void opIndexUnary(string op)(size_t i) if (op=="++"||op=="--")
  { mixin(op~"buf[i+=an];"); propagate(i); }

  pure T opIndex(size_t i) { return buf[i+an]; }

  pure T opSlice(size_t l, size_t r)
  {
    l += an; r += an;
    T r1 = dflt, r2 = dflt;
    while (l != r) {
      if (l % 2) r1 = predFun(r1, buf[l++]);
      if (r % 2) r2 = predFun(buf[--r], r2);
      l /= 2; r /= 2;
    }
    return predFun(r1, r2);
  }

  pure size_t opDollar() { return n; }

  private
  {
    const size_t an;
    const T dflt;
    T[] buf;

    void propagateAll() { foreach_reverse (i; 1..an) buf[i] = predFun(buf[i*2], buf[i*2+1]); }
    void propagate(size_t i) { while (i /= 2) buf[i] = predFun(buf[i*2], buf[i*2+1]); }
  }
}
SegmentTree!(pred, T) segmentTree(alias pred = "a+b", T)(size_t n, T dflt = T.init)
{ return new SegmentTree!(pred, T)(n, dflt); }
SegmentTree!(pred, T) segmentTree(alias pred = "a+b", T)(T[] init, T dflt = T.init)
{ return new SegmentTree!(pred, T)(init, dflt); }

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits, core.stdc.stdlib;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  { v = new T(r); foreach (ref w; v) getA(c, w); }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    { v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");"); }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  auto put(alias conf = "{}", T...)(T v)
  { mixin("const PutConf c = "~conf~"; putMain!c(v);"); }
  auto putB(alias conf = "{}", S, T)(bool c, S t, T f)
  { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i < v.length-1) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    auto putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else OUT.write(v);
    }
    auto putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}