// URL: https://yukicoder.me/problems/no/187

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int N; io.getV(N);
  int[] X, Y; io.getC(N, X, Y);

  auto x = GmpInt(X[0]), y = GmpInt(Y[0]);
  foreach (i; 1..N)
    if (!calc(x, y, GmpInt(X[i]), GmpInt(Y[i]))) io.put!"{exit: true}"(-1);

  auto mod = 10^^9+7;
  io.putB(x == 0, y%mod, x%mod);
}

auto calc(T)(ref T X1, ref T Y1, T X2, T Y2)
{
  T b1, b2;
  auto g = extGcd(Y1, Y2, b1, b2);
  if ((X2-X1)%g != 0) return false;

  auto y1 = Y1/g, y2 = Y2/g;
  Y1 = y1*y2*g;
  X1 = ((b1*y1*(X2-X1)+X1)%Y1+Y1)%Y1;
  return true;
}

auto lowerBoundBy(alias conv = "a", alias comp = "a<b", R, T)(R a, T v)
{ return a.sortedTuple!(conv, comp).lowerBound(tuple(a.front, v)).map!"a[0]"; }

auto upperBoundBy(alias conv = "a", alias comp = "a<b", R, T)(R a, T v)
{ return a.sortedTuple!(conv, comp).upperBound(tuple(a.front, v)).map!"a[0]"; }

auto sortedTuple(alias conv = "a", alias comp = "a<b", R)(R a)
{
  import std.functional;
  alias convFun = unaryFun!conv, compFun = binaryFun!comp;
  return a.map!(e => tuple(e, convFun(e))).assumeSorted!((a, b) => compFun(a[1], b[1]));
}

pure T isqrt(T)(T n)
{
  static if (is(T == int)) auto max = 46341;
  else static if (is(T == long)) auto max = 3037000500L;
  return iota(T(0), max).lowerBoundBy!("a^^2", "a<=b")(n).back;
}

pure T icbrt(T)(T n)
{
  static if (is(T == int)) auto max = 1291;
  else static if (is(T == long)) auto max = 2097152L;
  return iota(T(0), max).lowerBoundBy!("a^^3", "a<=b")(n).back;
}

pure T powr(alias pred = "a*b", T, U)(T a, U n, T one)
{
  import std.functional;
  alias predFun = binaryFun!pred;
  if (n == 0) return one;
  auto r = one;
  for (; n > 0; n >>= 1) { if (n&1) r = predFun(r, a); a = predFun(a, a); }
  return r;
}
pure T powr(alias pred = "a*b", T, U)(T a, U n) { return powr!(pred, T, U)(a, n, T(1)); }

pure T extGcd(T)(T a, T b, out T x, out T y)
{
  auto g = a; x = 1; y = 0;
  if (b) { g = extGcd(b, a%b, y, x); y -= a/b*x; }
  return g;
}

struct GmpInt
{
  @property pure static init() { return GmpInt(0); }

  @property pure value() { return toLong(); }
  @property value(long v) { __gmpz_set_si(&z, v); }
  alias value this;

  pure this(long v) { __gmpz_init_set_si(&z, v); }
  pure this(string s, int base = 10) { __gmpz_init_set_str(&z, s.toStringz, base); }
  pure this(ref return scope GmpInt v) { __gmpz_init_set(&z, &v.z); }
  pure ~this() { __gmpz_clear(&z); }

  pure long toLong() { return __gmpz_get_si(&z); }
  pure string toString(int base = 10)
  {
    auto sz = __gmpz_sizeinbase(&z, base);
    auto buf = new char[](sz + 2);
    __gmpz_get_str(buf.ptr, base, &z);
    return buf.ptr.fromStringz.to!string;
  }

  size_t fprint(File f, int base = 10) { return __gmpz_out_str(f.getFP, base, &z); }

  pure bool opEquals(GmpInt v) { return __gmpz_cmp(&z, &v.z) == 0; }
  pure bool opEquals(long v) { return __gmpz_cmp_si(&z, v) == 0; }
  pure int opCmp(GmpInt v) { return __gmpz_cmp(&z, &v.z); }
  pure int opCmp(long v) { return __gmpz_cmp_si(&z, v); }

  pure ref GmpInt opAssign(long v) { __gmpz_init_set_si(&z, v); return this; }
  pure ref GmpInt opAssign(GmpInt v) { __gmpz_init_set(&z, &v.z); return this; }

  pure GmpInt opBinary(string op)(GmpInt v) if (op=="+"||op=="-"||op=="*"||op=="/"||op=="%")
  {
    auto r = GmpInt.init;
    static      if (op == "+") __gmpz_add(&r.z, &z, &v.z);
    else static if (op == "-") __gmpz_sub(&r.z, &z, &v.z);
    else static if (op == "*") __gmpz_mul(&r.z, &z, &v.z);
    else static if (op == "/") __gmpz_tdiv_q(&r.z, &z, &v.z);
    else static if (op == "%") __gmpz_tdiv_r(&r.z, &z, &v.z);
    return r;
  }
  ref GmpInt opOpAssign(string op)(GmpInt v) if (op=="+"||op=="-"||op=="*"||op=="/"||op=="%")
  {
    static      if (op == "+") __gmpz_add(&z, &z, &v.z);
    else static if (op == "-") __gmpz_sub(&z, &z, &v.z);
    else static if (op == "*") __gmpz_mul(&z, &z, &v.z);
    else static if (op == "/") __gmpz_tdiv_q(&z, &z, &v.z);
    else static if (op == "%") __gmpz_tdiv_r(&z, &z, &v.z);
    return this;
  }

  pure GmpInt opBinary(string op)(ulong v) if (op=="+"||op=="-"||op=="*"||op=="/"||op=="%"||op=="^^")
  {
    auto r = GmpInt.init;
    static      if (op == "+") __gmpz_add_ui(&r.z, &z, v);
    else static if (op == "-") __gmpz_sub_ui(&r.z, &z, v);
    else static if (op == "*") __gmpz_mul_ui(&r.z, &z, v);
    else static if (op == "/") __gmpz_tdiv_q_ui(&r.z, &z, v);
    else static if (op == "%") __gmpz_tdiv_r_ui(&r.z, &z, v);
    else static if (op == "^^") __gmpz_pow_ui(&r.z, &z, v);
    return r;
  }
  pure ref GmpInt opOpAssign(string op)(ulong v) if (op=="+"||op=="-"||op=="*"||op=="/"||op=="%"||op=="^^")
  {
    static      if (op == "+") __gmpz_add_ui(&z, &z, v);
    else static if (op == "-") __gmpz_sub_ui(&z, &z, v);
    else static if (op == "*") __gmpz_mul_ui(&z, &z, v);
    else static if (op == "/") __gmpz_tdiv_q_ui(&z, &z, v);
    else static if (op == "%") __gmpz_tdiv_r_ui(&z, &z, v);
    else static if (op == "^^") __gmpz_pow_ui(&z, &z, v);
    return this;
  }

  pure GmpInt abs() { auto r = GmpInt.init; __gmpz_abs(&r.z, &z); return r; }
  pure GmpInt sqrt() { auto r = GmpInt.init; __gmpz_sqrt(&r.z, &z); return r; }
  pure size_t popcnt() { return __gmpz_popcount(&z); }
  pure bool probabPrime(int reps = 20) { return __gmpz_probab_prime_p(&z, reps) != 0; }

  private
  {
    import std.conv, std.stdio;
    private __mpz_struct z;
  }
}

extern(C) pragma(inline, false)
{
  import core.stdc.stdio : FILE;
  alias __mp_limb_t = ulong;

  struct __mpz_struct
  {
    int _mp_alloc;
    int _mp_size;
    __mp_limb_t* _mp_d;
  }

  alias mpz_srcptr = const(__mpz_struct)*;
  alias mpz_ptr = __mpz_struct*;

  pure @trusted:

  void __gmpz_init(mpz_ptr);
  void __gmpz_clear(mpz_ptr);

  void __gmpz_init_set(mpz_ptr, mpz_srcptr);
  void __gmpz_init_set_si(mpz_ptr, long);
  int __gmpz_init_set_str(mpz_ptr, const char*, int);

  void __gmpz_set(mpz_ptr, mpz_srcptr);
  void __gmpz_set_si(mpz_ptr, long);

  long __gmpz_get_si(mpz_srcptr);
  char *__gmpz_get_str(char*, int, mpz_srcptr);
  size_t __gmpz_sizeinbase(mpz_srcptr, int);

  size_t __gmpz_out_str(FILE*, int, mpz_ptr);

  int __gmpz_cmp(mpz_srcptr, mpz_srcptr);
  int __gmpz_cmp_si(mpz_srcptr, long);

  void __gmpz_add(mpz_ptr, mpz_srcptr, mpz_srcptr);
  void __gmpz_add_ui(mpz_ptr, mpz_srcptr, ulong);
  void __gmpz_sub(mpz_ptr, mpz_srcptr, mpz_srcptr);
  void __gmpz_sub_ui(mpz_ptr, mpz_srcptr, ulong);
  void __gmpz_mul(mpz_ptr, mpz_srcptr, mpz_srcptr);
  void __gmpz_mul_ui(mpz_ptr, mpz_srcptr, ulong);
  void __gmpz_tdiv_q(mpz_ptr, mpz_srcptr, mpz_srcptr);
  void __gmpz_tdiv_r(mpz_ptr, mpz_srcptr, mpz_srcptr);
  ulong __gmpz_tdiv_q_ui(mpz_ptr, mpz_srcptr, ulong);
  ulong __gmpz_tdiv_r_ui(mpz_ptr, mpz_srcptr, ulong);
  void __gmpz_pow_ui(mpz_ptr, mpz_srcptr, ulong);

  void __gmpz_abs(mpz_ptr, mpz_srcptr);
  void __gmpz_sqrt(mpz_ptr, mpz_srcptr);
  size_t __gmpz_popcount(mpz_srcptr);
  int __gmpz_probab_prime_p(mpz_ptr, int reps);
}
pragma(lib, "gmp");

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits, core.stdc.stdlib;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  { v = new T(r); foreach (ref w; v) getA(c, w); }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    { v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");"); }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  auto put(alias conf = "{}", T...)(T v)
  { mixin("const PutConf c = "~conf~"; putMain!c(v);"); }
  auto putB(alias conf = "{}", S, T)(bool c, S t, T f)
  { if (c) put!conf(t); else put!conf(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i < v.length-1) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    auto putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    auto putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}