// URL: https://yukicoder.me/problems/no/306

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  double xa, ya; io.getV(xa, ya);
  double xb, yb; io.getV(xb, yb);

  auto a = Point(xa, ya), b = Point(-xb, yb);
  auto l1 = geom.line(a, b), l2 = Line(1, 0, 0);
  io.put(geom.intersect(l1, l2).y);
}

alias geom = Geom!double, Point = geom.Point, Line = geom.Line;
template Geom(T, T eps = 1e-10)
  if (isFloatingPoint!T)
{
  struct Point
  {
    T x, y;
    auto isNaN() { return x.isNaN || y.isNaN; }
  }

  struct Line
  {
    T a, b, c;
    auto isNaN() { return a.isNaN || b.isNaN || c.isNaN; }
  }

  pure nothrow @nogc @safe
  {
    Line line(const Point p1, const Point p2)
    {
      auto x = p2.x-p1.x;
      auto y = p2.y-p1.y;
      return Line(y, -x, p2.y*x-p2.x*y);
    }

    T dist(const Point p1, const Point p2)
    {
      return ((p1.x-p2.x)^^2 + (p1.y-p2.y)^^2).sqrt;
    }

    T dist(const Point p, const Line l)
    {
      return (l.a*p.x + l.b*p.y + l.c).abs / (l.a^^2 + l.b^^2).sqrt;
    }

    Point intersect(const Line l1, const Line l2)
    {
      auto det = l1.a*l2.b - l1.b*l2.a;
      if (approxEqual(det, 0, eps)) return Point(T.nan, T.nan);
      auto x = (l1.b*l2.c - l2.b*l1.c) / det;
      auto y = (l2.a*l1.c - l1.a*l2.c) / det;
      return Point(x, y);
    }

    Line bisector(const Point p1, const Point p2)
    {
      auto a = p2.x-p1.x;
      auto b = p2.y-p1.y;
      auto c = (p1.x^^2 - p2.x^^2 + p1.y^^2 - p2.y^^2) / 2;
      if (approxEqual(a, 0, eps) && approxEqual(b, 0, eps))
        return Line(T.nan, T.nan, T.nan);
      return Line(a, b, c);
    }
  }

  pure nothrow @safe
  {
    Line[] bisector(const Line l1, const Line l2)
    {
      auto d1 = (l1.a^^2 + l1.b^^2).sqrt;
      auto d2 = (l2.a^^2 + l2.b^^2).sqrt;

      Line[] r;

      auto a3 = l1.a*d2 - l2.a*d1;
      auto b3 = l1.b*d2 - l2.b*d1;
      auto c3 = l1.c*d2 - l2.c*d1;
      if (!approxEqual(a3, 0, eps) || !approxEqual(b3, 0, eps)) r ~= Line(a3, b3, c3);

      auto a4 = l1.a*d2 + l2.a*d1;
      auto b4 = l1.b*d2 + l2.b*d1;
      auto c4 = l1.c*d2 + l2.c*d1;
      if (!approxEqual(a4, 0, eps) || !approxEqual(b4, 0, eps)) r ~= Line(a4, b4, c4);

      return r;
    }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}