// URL: https://yukicoder.me/problems/no/165

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  int N, B; io.getV(N, B);

  struct P { int x, y, p; }
  P[] p; io.getS!("x", "y", "p")(N, p);

  p.sort!"a.y<b.y";
  auto za = new Zaatsu!int(p.map!"a.x");
  foreach (ref pi; p) pi.x = za.comp(pi.x);

  auto calc(P[] p)
  {
    auto n = p.length, s = 0;

    auto nextL(int l)
    {
      auto y = p[l].y;
      while (l < n && p[l].y == y) s -= p[l++].p;
      return l;
    }

    auto nextR(int r)
    {
      auto y = p[r].y;
      while (r < n && p[r].y == y) s += p[r++].p;
      return r;
    }

    auto l = 0, r = 0, c = 0;
    while (l < n) {
      while (s <= B) {
        c = max(c, r-l);
        if (r < n) r = nextR(r);
        else       break;
      }
      l = nextL(l);
    }

    return c;
  }

  auto r = 0;
  foreach (i; 0..za.n)
    foreach (j; i..za.n)
      r = max(r, calc(p.filter!(pi => i <= pi.x && pi.x <= j).array));

  io.put(r);
}

struct Zaatsu(T)
{
  const size_t n;

  pure nothrow @safe
  {
    this(U...)(U v)
    {
      T[] d;
      foreach (w; v) d ~= w.array;
      auto u = d.sort.uniq;
      n = u.walkLength;
      c2 = new T[](n);

      foreach (i, ui; u.enumerate(0)) {
        c1[ui] = i;
        c2[i] = ui;
      }
    }

    int comp(T v) const
    {
      return c1[v];
    }
    auto comp(R)(R v) const
      if (isInputRange!R)
    {
      return v.map!(w => c1[w]);
    }

    T uncomp(int v) const
    {
      return c2[v];
    }
    auto uncomp(R)(R v) const
      if (isInputRange!R)
    {
      return v.map!(w => c2[w]);
    }
  }

  private
  {
    int[T] c1;
    T[] c2;
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}