import std;

void main() {
    int n; scan(n);
    int[] a;
    foreach (_; 0..n) a ~= read!int;

    auto ans = countInversion(a);
    writeln(ans);
}

void scan(T...)(ref T a) {
    string[] ss = readln.split;
    foreach (i, t; T) a[i] = ss[i].to!t;
}
T read(T=string)() { return readln.chomp.to!T; }
T[] reads(T)() { return readln.split.to!(T[]); }
alias readints = reads!int;

class BIT(T) {
    private T[] _data;

    /// [1, n]
    this(int n) {
        _data = new T[n + 10];
    }

    /// [1, p] の和(1 based)
    T sum(int p) const {
        T s = 0;
        while (p > 0) {
            s += _data[p];
            p -= p & -p;
        }
        return s;
    }

    /// p 番目に x を加える(1 based)
    void add(int p, T x) {
        while (p < _data.length) {
            _data[p] += x;
            p += p & -p;
        }
    }
}

// 転倒数を求める
// a の要素の最大値サイズの BIT を作成する
long countInversion(int[] a) {
    int n = a.reduce!max;

    auto bit = new BIT!int(n);
    long ans = 0;
    foreach (x; a) {
        bit.add(x, 1);
        // x より左側に x より大きな数がいくつあるか
        ans += bit.sum(n) - bit.sum(x);
    }
    return ans;
}