import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }


struct ModInt(int M_) {
  import std.conv : to;
  alias M = M_;
  int x;
  this(ModInt a) { x = a.x; }
  this(long a) { x = cast(int)(a % M); if (x < 0) x += M; }
  ref ModInt opAssign(long a) { return (this = ModInt(a)); }
  ref ModInt opOpAssign(string op)(ModInt a) {
    static if (op == "+") { x += a.x; if (x >= M) x -= M; }
    else static if (op == "-") { x -= a.x; if (x < 0) x += M; }
    else static if (op == "*") { x = cast(int)((cast(long)(x) * a.x) % M); }
    else static if (op == "/") { this *= a.inv(); }
    else static assert(false);
    return this;
  }
  ref ModInt opOpAssign(string op)(long a) {
    static if (op == "^^") {
      if (a < 0) return (this = inv()^^(-a));
      ModInt t2 = this, te = ModInt(1);
      for (long e = a; e > 0; e >>= 1) {
        if (e & 1) te *= t2;
        t2 *= t2;
      }
      x = cast(int)(te.x);
      return this;
    } else return mixin("this " ~ op ~ "= ModInt(a)");
  }
  ModInt inv() const {
    int a = x, b = M, y = 1, z = 0, t;
    for (; ; ) {
      t = a / b; a -= t * b;
      if (a == 0) {
        assert(b == 1 || b == -1);
        return ModInt(b * z);
      }
      y -= t * z;
      t = b / a; b -= t * a;
      if (b == 0) {
        assert(a == 1 || a == -1);
        return ModInt(a * y);
      }
      z -= t * y;
    }
  }
  ModInt opUnary(string op: "-")() const { return ModInt(-x); }
  ModInt opBinary(string op, T)(T a) const {
    return mixin("ModInt(this) " ~ op ~ "= a");
  }
  ModInt opBinaryRight(string op)(long a) const {
    return mixin("ModInt(a) " ~ op ~ "= this");
  }
  bool opCast(T: bool)() const { return (x != 0); }
  string toString() const { return x.to!string; }
}

enum MO = 998244353;
alias Mint = ModInt!MO;

enum LIM = 10^^5 + 10;
Mint[] inv, fac, invFac;
void prepare() {
  inv = new Mint[LIM];
  fac = new Mint[LIM];
  invFac = new Mint[LIM];
  inv[1] = 1;
  foreach (i; 2 .. LIM) {
    inv[i] = -(Mint.M / i) * inv[cast(size_t)(Mint.M % i)];
  }
  fac[0] = invFac[0] = 1;
  foreach (i; 1 .. LIM) {
    fac[i] = fac[i - 1] * i;
    invFac[i] = invFac[i - 1] * inv[i];
  }
}
Mint binom(long n, long k) {
  if (0 <= k && k <= n) {
    assert(n < LIM);
    return fac[cast(size_t)(n)] * invFac[cast(size_t)(k)] * invFac[cast(size_t)(n - k)];
  } else {
    return Mint(0);
  }
}


class Fft(int M_, int G, int K) {
  import std.algorithm : reverse;
  import std.traits : isIntegral;
  alias M = M_;
  // 1, 1/4, 1/8, 3/8, 1/16, 5/16, 3/16, 7/16, ...
  int[] gs;
  this() {
    static assert(2 <= K && K <= 30, "Fft: 2 <= K <= 30 must hold");
    static assert(!((M - 1) & ((1 << K) - 1)), "Fft: 2^K | M - 1 must hold");
    gs = new int[1 << (K - 1)];
    gs[0] = 1;
    long g2 = G, gg = 1;
    for (int e = (M - 1) >> K; e; e >>= 1) {
      if (e & 1) gg = (gg * g2) % M;
      g2 = (g2 * g2) % M;
    }
    gs[1 << (K - 2)] = cast(int)(gg);
    for (int l = 1 << (K - 2); l >= 2; l >>= 1) {
      gs[l >> 1] = cast(int)((cast(long)(gs[l]) * gs[l]) % M);
    }
    assert((cast(long)(gs[1]) * gs[1]) % M == M - 1,
           "Fft: g^(2^(K-1)) == -1 (mod M) must hold");
    for (int l = 2; l <= 1 << (K - 2); l <<= 1) {
      foreach (i; 1 .. l) {
        gs[l + i] = cast(int)((cast(long)(gs[l]) * gs[i]) % M);
      }
    }
  }
  void fft(int[] xs) const {
    const n = cast(int)(xs.length);
    assert(!(n & (n - 1)), "Fft.fft: |xs| must be a power of two");
    assert(n <= 1 << K, "Fft.fft: |xs| <= 2^K must hold");
    for (int l = n; l >>= 1; ) {
      foreach (i; 0 .. (n >> 1) / l) {
        const(long) g = gs[i];
        foreach (j; (i << 1) * l .. (i << 1 | 1) * l) {
          const t = cast(int)((g * xs[j + l]) % M);
          if ((xs[j + l] = xs[j] - t) < 0) xs[j + l] += M;
          if ((xs[j] += t) >= M) xs[j] -= M;
        }
      }
    }
  }
  void invFft(int[] xs) const {
    const n = cast(int)(xs.length);
    assert(!(n & (n - 1)), "Fft.invFft: |xs| must be a power of two");
    assert(n <= 1 << K, "Fft.invFft: |xs| <= 2^K must hold");
    for (int l = 1; l < n; l <<= 1) reverse(xs[l .. l << 1]);
    for (int l = 1; l < n; l <<= 1) {
      foreach (i; 0 .. (n >> 1) / l) {
        const(long) g = gs[i];
        foreach (j; (i << 1) * l .. (i << 1 | 1) * l) {
          int t = cast(int)((g * (xs[j] - xs[j + l])) % M);
          if (t < 0) t += M;
          if ((xs[j] += xs[j + l]) >= M) xs[j] -= M;
          xs[j + l] = t;
        }
      }
    }
  }
  T[] convolute(T)(inout(T)[] as, inout(T)[] bs) const if (isIntegral!T) {
    const na = cast(int)(as.length), nb = cast(int)(bs.length);
    int n, invN = 1;
    for (n = 1; n < na + nb - 1; n <<= 1) {
      invN = ((invN & 1) ? (invN + M) : invN) >> 1;
    }
    auto xs = new int[n], ys = new int[n];
    foreach (i; 0 .. na) if ((xs[i] = cast(int)(as[i] % M)) < 0) xs[i] += M;
    foreach (i; 0 .. nb) if ((ys[i] = cast(int)(bs[i] % M)) < 0) ys[i] += M;
    fft(xs);
    fft(ys);
    foreach (i; 0 .. n) {
      xs[i] = cast(int)((((cast(long)(xs[i]) * ys[i]) % M) * invN) % M);
    }
    invFft(xs);
    auto cs = new T[na + nb - 1];
    foreach (i; 0 .. na + nb - 1) cs[i] = cast(T)(xs[i]);
    return cs;
  }
  ModInt!M[] convolute(inout(ModInt!M)[] as, inout(ModInt!M)[] bs) const {
    const na = cast(int)(as.length), nb = cast(int)(bs.length);
    int n, invN = 1;
    for (n = 1; n < na + nb - 1; n <<= 1) {
      invN = ((invN & 1) ? (invN + M) : invN) >> 1;
    }
    auto xs = new int[n], ys = new int[n];
    foreach (i; 0 .. na) xs[i] = as[i].x;
    foreach (i; 0 .. nb) ys[i] = bs[i].x;
    fft(xs);
    fft(ys);
    foreach (i; 0 .. n) {
      xs[i] = cast(int)((((cast(long)(xs[i]) * ys[i]) % M) * invN) % M);
    }
    invFft(xs);
    auto cs = new ModInt!M[na + nb - 1];
    foreach (i; 0 .. na + nb - 1) cs[i].x = xs[i];
    return cs;
  }
  int[] convolute(int M1)(inout(ModInt!M1)[] as, inout(ModInt!M1)[] bs) const
      if (M != M1) {
    const na = cast(int)(as.length), nb = cast(int)(bs.length);
    int n, invN = 1;
    for (n = 1; n < na + nb - 1; n <<= 1) {
      invN = ((invN & 1) ? (invN + M) : invN) >> 1;
    }
    auto xs = new int[n], ys = new int[n];
    foreach (i; 0 .. na) xs[i] = as[i].x;
    foreach (i; 0 .. nb) ys[i] = bs[i].x;
    fft(xs);
    fft(ys);
    foreach (i; 0 .. n) {
      xs[i] = cast(int)((((cast(long)(xs[i]) * ys[i]) % M) * invN) % M);
    }
    invFft(xs);
    return xs[0 .. na + nb - 1];
  }
}

alias Fft0 = Fft!(998244353, 3, 20);

Fft0 FFT;

struct Poly {
  Mint[] x;
  this(Poly f) {
    x = f.x.dup;
  }
  this(const(Poly) f) {
    x = f.x.dup;
  }
  this(int n) {
    x = new Mint[n];
  }
  this(const(Mint)[] x) {
    this.x = x.dup;
  }
  this(const(long)[] x) {
    this.x.length = x.length;
    foreach (i; 0 .. x.length) this.x[i] = Mint(x[i]);
  }
  int size() const {
    return cast(int)(x.length);
  }
  Poly take(int n) const {
    return Poly(x[0 .. min(max(n, 1), $)]);
  }

  ref Poly opAssign(const(Mint)[] x) {
    this.x = x.dup;
    return this;
  }
  ref Poly opAssign(const(long)[] x) {
    this.x.length = x.length;
    foreach (i; 0 .. x.length) this.x[i] = Mint(x[i]);
    return this;
  }
  Mint opIndex(int i) const {
    return x[i];
  }
  ref Mint opIndex(int i) {
    return x[i];
  }
  ref Poly opOpAssign(string op)(const(Poly) f) {
    static if (op == "+") {
      if (size() < f.size()) x.length = f.size();
      foreach (i; 0 .. f.size()) this[i] += f[i];
      return this;
    } else static if (op == "-") {
      if (size() < f.size()) x.length = f.size();
      foreach (i; 0 .. f.size()) this[i] -= f[i];
      return this;
    } else static if (op == "*") {
      // TODO: FFT
      /*
      Poly g = Poly(size() + f.size() - 1);
      foreach (i; 0 .. size()) foreach (j; 0 .. f.size()) {
        g[i + j] += this[i] * f[j];
      }
      this = g;
      return this;
      */
      x = FFT.convolute(x, f.x);
      return this;
    } else {
      static assert(false);
    }
  }
  ref Poly opOpAssign(string op)(Mint a) if (op == "*") {
    foreach (i; 0 .. size()) this[i] *= a;
    return this;
  }
  Poly opBinary(string op, T)(T a) const {
    return mixin("Poly(this) " ~ op ~ "= a");
    // Poly f = Poly(this);
    // mixin("f " ~ op ~ "= a;");
    // return f;
  }
  Poly opBinaryRight(string op)(Mint a) const if (op == "*") {
    return this * a;
  }
  Poly opUnary(string op)() const if (op == "-") {
    return this * Mint(-1);
  }

  Poly square(int n) const {
    // TODO: FFT
    /*
    Poly f = Poly(n);
    foreach (i; 0 .. min(size(), (n + 1) / 2)) {
      f[i + i] += this[i] * this[i];
      foreach (j; i + 1 .. min(size(), n - i)) {
        f[i + j] += Mint(2) * this[i] * this[j];
      }
    }
    return f;
    */
    Poly f;
    f.x = x.dup;
    // f.x = FFT.square(f.x);
    f.x = FFT.convolute(f.x, f.x);
    return f.take(n);
  }
  Poly inv(int n) const {
    // TODO: fft
    /*
    assert(this[0].x != 0);
    Poly f = Poly(n);
    f[0] = this[0].inv();
    foreach (i; 1 .. n) {
      foreach (j; 1 .. min(size(), i + 1)) {
        f[i] -= this[j] * f[i - j];
      }
      f[i] *= f[0];
    }
    return f;
    */
    Poly f = Poly([this[0].inv()]);
    for (int m = 1; m < n; m <<= 1) {
      f = (f + f - f.square(m << 1) * this.take(m << 1)).take(m << 1);
    }
    return f.take(n);
  }
  Poly differential() const {
    Poly f = Poly(max(size() - 1, 1));
    foreach (i; 1 .. size()) f[i - 1] = Mint(i) * this[i];
    return f;
  }
  Poly integral() const {
    Poly f = Poly(size() + 1);
    foreach (i; 0 .. size()) f[i + 1] = Mint(i + 1).inv() * this[i];
    return f;
  }
  Poly exp(int n) const {
    assert(this[0].x == 0);
    const d = differential();
    Poly f = [1], g = [1];
    for (int m = 1; m < n; m <<= 1) {
      g = g + g - (f * g.square(m)).take(m);
      Poly h = d.take(m - 1);
      h += (g * (f.differential() - f * h)).take(2 * m - 1);
      f += (f * (take(2 * m) - h.integral())).take(2 * m);
    }
    return f.take(n);
  }
  Poly log(int n) const {
    assert(this[0].x == 1);
    return (differential() * inv(n)).take(n).integral().take(n);
  }
}
enum Poly1 = Poly([1]);
enum PolyQ = Poly([0, 1]);


void main() {
  prepare;
  FFT = new Fft0;
  
  debug {
    foreach (n; 1 .. 10 + 1) {
      int cnt;
      void dfs(int num, int rem) {
        foreach (i; 0 .. n) {
          if (rem & 1 << i) {
            const rr = rem ^ (1 << i);
            if (rr == (((1 << (num - 1)) - 1) << bsf(rr))) {
              ++cnt;
            } else {
              dfs(num - 1, rr);
            }
          }
        }
      }
      dfs(n, (1 << n) - 1);
      writeln(n, ": ", cnt);
      stdout.flush;
    }
  }
  debug {
    enum lim = 2021;
    auto dp = new Mint[lim + 1];
    foreach (n; 1 .. lim + 1) {
      foreach (l; 1 .. n) {
        dp[n] += Mint(n + 1 - l) * fac[n - l];
        dp[n] -= Mint(n + 1 - l) * fac[n - l] * dp[l];
      }
    }
    writeln(dp[0 .. 20]);
    writeln(dp[2021]);
  }
  
  /*
    f(n) = \sum_{l=1}^{n-1} (n + 1 - l)! (1 - f(l))
    
    (1 + 2! x + 3! x^2 + ...) ((1 + x + x^2 + ...) - F(x))
    = 1 + (2! + 1) x + (3! + 1) x^2 + ...
  */
  try {
    for (; ; ) {
      const N = readInt();
      
      auto gs = Poly(N + 1);
      auto hs = Poly(N + 1);
      gs[0] = hs[0] = 1;
      foreach (i; 1 .. N + 1) {
        gs[i] = fac[i + 1] + 1;
        hs[i] = fac[i + 1];
      }
      const fs = gs * hs.inv(N + 1);
      writeln(1 - fs[N]);
    }
  } catch (EOFException e) {
  }
}