// URL: https://yukicoder.me/problems/no/1512

import std;

version(unittest) {} else
void main()
{
  int N; io.getV(N);
  string[] S; io.getC(N, S);

  struct C { dchar s, e; int l; }
  C[] c;

  foreach (i, Si; S)
    if (Si.to!(dchar[]).sort.to!string == Si)
      c ~= C(Si[0], Si[$-1], Si.length.to!int);
  auto n = c.length;

  auto dp = new int[][](n+1, 26);
  dp[0][0] = 1;
  foreach (i; 0..n)
    foreach (j; 0..26) {
      dp[i+1][j].maxU(dp[i][j]);
      if (c[i].s-'a' >= j)
        dp[i+1][c[i].e-'a'].maxU(dp[i][j]+c[i].l);
    }

  io.put(dp[$-1].maxElement-1);
}

pragma(inline) pure nothrow @nogc @safe
{
  T minU(T, U)(ref T a, U b)
  { return a = min(a, b); }
  T maxU(T, U)(ref T a, U b)
  { return a = max(a, b); }
}

auto io = IO!()();
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    putMain!conf(v);
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(alias conf, T...)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      foreach (i, w; v) {
        putOne!conf(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(alias conf, T)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      static if (isInputRange!T && !isSomeString!T) putRange!conf(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(alias conf, T)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      auto w = v;
      while (!w.empty) {
        putOne!conf(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}