require "bit_array"

def main(io)
  n, p = io.get2

  uf = UnionFind.new(n+1)
  b = BitArray.new(n+1)

  (2..n).each do |i|
    next if b[i]
    j = i*2
    while j <= n
      b[j] = true
      uf.unite(i, j)
      j += i
    end
  end

  io.put uf.count_nodes_of(p)
end

class UnionFind
  def initialize(@n : Int32)
    @s = @n
    @p = Array(Int32).new(@n, @s)
    @cf = @n
    @cn = Array(Int32).new(@n, 1)
  end

  def unite(u : Int, v : Int)
    pu, pv = subst(u), subst(v)
    if pu != pv
      @p[pv] = pu
      @cf -= 1
      @cn[pu] += @cn[pv]
    end
    pu != pv
  end

  def subst(u : Int) : Int32
    @p[u] == @s ? u.to_i32 : (@p[u] = subst(@p[u]))
  end

  def same?(u : Int, v : Int)
    subst(u) == subst(v)
  end

  def count_forests
    @cf
  end

  def count_nodes_of(u : Int)
    @cn[subst(u)]
  end
end

class ProconIO
  def initialize
    @buf = [] of String
    @index = 0
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  def get(*ks : T.class) forall T
    ks.map { |k| get_v(k) }
  end

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({% for j in (1..i) %}k{% if j < i %}, {% end %}{% end %})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  def get_c(n : Int, *ks : T.class) forall T
    a = Array.new(n) { get(*ks) }
    ks.map_with_index { |_, i| a.map { |e| e[i] } }
  end

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {% for j in (1..i) %}k{% if j < i %}, {% end %}{% end %})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  def put(*vs)
    vs.each.with_index do |v, i|
      put_v(v)
      print i < vs.size - 1 ? " " : "\n"
    end
  end

  def put_e(*vs)
    put(*vs)
    exit
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    if @buf.size == @index
      @buf = read_line.split
      @index = 0
    end
    v = @buf[@index]
    @index += 1
    v
  end

  private def put_v(vs : Enumerable)
    vs.each_with_index do |v, i|
      print v
      print " " if i < vs.size - 1
    end
  end

  private def put_v(v)
    print v
  end
end

main(ProconIO.new)