def solve(io)
  n, m = io.get2
  s = io.get(String)

  g = Graph.new(n)
  m.times do
    u, v = io.get2; u -= 1; v -= 1
    g.add_edge_b(u, v)
  end

  p = Array.new(n, Mint.zero)
  d = Array.new(n, Mint.zero)
  c = Array.new(n, Mint.zero)
  a = Array.new(n, Mint.zero)

  n.times do |i|
    if s[i] == 'P'
      p[i] = Mint.new(1)
    end
  end

  n.times do |i|
    if s[i] == 'P'
      g[i].each do |j|
        d[j] += p[i] if s[j] == 'D'
      end
    end
  end

  n.times do |i|
    if s[i] == 'D'
      g[i].each do |j|
        c[j] += d[i] if s[j] == 'C'
      end
    end
  end

  n.times do |i|
    if s[i] == 'C'
      g[i].each do |j|
        a[j] += c[i] if s[j] == 'A'
      end
    end
  end

  io.put a.sum
end

struct Int
  def cdiv(b : Int)
    (self + b - 1) // b
  end

  def bit?(i : Int)
    bit(i) == 1
  end

  def set_bit(i : Int)
    self | (self.class.new(1) << i)
  end

  def reset_bit(i : Int)
    self & ~(self.class.new(1) << i)
  end

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.34.0") < 0 %}
    def bit_length : Int32
      x = self < 0 ? ~self : self

      if x.is_a?(Int::Primitive)
        Int32.new(sizeof(self) * 8 - x.leading_zeros_count)
      else
        to_s(2).size
      end
    end
  {% end %}
end

struct Int32
  SQRT_MAX = 46_340_i32

  def isqrt
    m = SQRT_MAX
    r = (1_i32..SQRT_MAX).bsearch { |i| i**2 > self }
    r.nil? ? SQRT_MAX : r - 1
  end
end

struct Int64
  SQRT_MAX = 3_037_000_499_i64

  def isqrt
    r = (1_i64..SQRT_MAX).bsearch { |i| i**2 > self }
    r.nil? ? SQRT_MAX : r - 1
  end
end

struct Number
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.1.0") < 0 %}
    def zero?
      self == 0
    end

    def positive?
      self > 0
    end

    def negative?
      self < 0
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.36.0") < 0 %}
    def self.additive_identity
      zero
    end

    def self.multiplicative_identity
      new(1)
    end
  {% end %}
end

class Array
  macro new_md(*args, &block)
    {% if !block %}
      {% for arg, i in args[0...-2] %}
        Array.new({{arg}}) {
      {% end %}
      Array.new({{args[-2]}}, {{args[-1]}})
      {% for arg in args[0...-2] %}
        }
      {% end %}
    {% else %}
      {% for arg, i in args %}
        Array.new({{arg}}) { |_i{{i}}|
      {% end %}
      {% for block_arg, i in block.args %}
        {{block_arg}} = _i{{i}}
      {% end %}
      {{block.body}}
      {% for arg in args %}
        }
      {% end %}
    {% end %}
  end
end

class ProconIO
  def initialize(@ins : IO = STDIN, @outs : IO = STDOUT)
    @buf = [] of String
    @index = 0
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  macro define_get
    {% for i in (2..9) %}
      def get(
            {% for j in (1..i) %}
              k{{j}}{% if j < i %},{% end %}
            {% end %}
          )
        {
          {% for j in (1..i) %}
            get(k{{j}}){% if j < i %},{% end %}
          {% end %}
        }
      end
    {% end %}
  end
  define_get

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get(
          {% for j in (1..i) %}
            k{% if j < i %}, {% end %}
          {% end %}
        )
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  macro define_get_c
    {% for i in (2..9) %}
      def get_c(
            n : Int,
            {% for j in (1..i) %}
              k{{j}}{% if j < i %},{% end %}
            {% end %}
          )
        a = Array.new(n) do
          get(
            {% for j in (1..i) %}
              k{{j}}{% if j < i %},{% end %}
            {% end %}
          )
        end
        {
          {% for j in (1..i) %}
            a.map { |e| e[{{j-1}}] }{% if j < i %},{% end %}
          {% end %}
        }
      end
    {% end %}
  end
  define_get_c

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(
          n,
          {% for j in (1..i) %}
            k{% if j < i %}, {% end %}
          {% end %}
        )
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  def put(*vs)
    vs.each.with_index do |v, i|
      put_v(v)
      @outs.print i < vs.size - 1 ? " " : "\n"
    end
  end

  def put_e(*vs)
    put(*vs)
    exit
  end

  def put_f(*vs)
    put(*vs)
    @outs.flush
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : UInt32.class); get_token.to_u32; end
  private def get_v(k : UInt64.class); get_token.to_u64; end
  private def get_v(k : Float64.class); get_token.to_f64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    if @buf.size == @index
      str = @ins.read_line
      @buf = str.split
      @index = 0
    end
    v = @buf[@index]
    @index += 1
    v
  end

  private def put_v(vs : Enumerable)
    vs.each_with_index do |v, i|
      @outs.print v
      @outs.print " " if i < vs.size - 1
    end
  end

  private def put_v(v)
    @outs.print v
  end
end

macro min_u(a, b)
  {{a}} = Math.min({{a}}, {{b}})
end

macro max_u(a, b)
  {{a}} = Math.max({{a}}, {{b}})
end

macro zip(a, *b, &block)
  {{a}}.zip({{*b}}) {{block}}
end

def powr(a : T, n : Int, i : T = T.multiplicative_identity) forall T
  powr(a, n, i) { |a, b| a * b }
end

def powr(a : T, n : Int, i : T = T.multiplicative_identity, &block) forall T
  return i if n == 0
  r, b = i, a
  while n > 0
    r = yield r, b if n.bit(0) == 1
    b = yield b, b
    n >>= 1
  end
  r
end

def ext_gcd(a : T, b : T) forall T
  if a == 0
    {b, T.new(0), T.new(1)}
  else
    g, x, y = ext_gcd(b%a, a)
    {g, y-(b//a)*x, x}
  end
end

abstract struct ModInt < Number
  macro new_type(name, mod)
    struct {{name}} < ModInt
      @@mod : Int32 = {{mod}}
    end
  end

  def initialize(v : Int)
    @v = (v % @@mod).to_i64
  end

  def_hash @@mod, @v

  def to_s
    @v.to_s
  end

  def to_s(io : IO) : Nil
    @v.to_s(io)
  end

  getter v : Int64

  delegate to_i, to: @v

  def ==(r : self)
    @v == r.v
  end

  def ==(r : Int)
    @v == (r % @@mod)
  end

  def - : self
    m(-@v)
  end

  def +(r : self)
    m(@v + r.v)
  end

  def +(r : Int)
    self + m(r)
  end

  def -(r : self)
    m(@v - r.v)
  end

  def -(r : Int)
    self - m(r)
  end

  def *(r : self)
    m(@v * r.v)
  end

  def *(r : Int)
    self * m(r)
  end

  def //(r : self)
    self * r.inv
  end

  def //(r : Int)
    self // m(r)
  end

  def **(n : Int)
    powr(self, n)
  end

  def inv
    m(ext_gcd(@v.to_i32, @@mod)[1])
  end


  private def m(v : Int)
    self.class.new(v)
  end
end
ModInt.new_type(Mint, 10**9+7)

require "bit_array"

class Graph
  alias Node = Int32

  def initialize(@size : Node)
    @g = Array(Array(Node)).new(@size) { [] of Node }
  end

  getter size : Int32

  delegate :[], to: @g

  def add_edge(u : Node, v : Node)
    @g[u] << v
  end

  def add_edge_b(u : Node, v : Node)
    @g[u] << v
    @g[v] << u
  end

  def bfs(u : Node)
    b = BitArray.new(@size)
    yield u, -1
    b[u] = true
    q = Deque.new([u])
    until q.empty?
      v = q.shift
      @g[v].each do |w|
        next if b[w]
        yield w, v
        b[w] = true
        q.push(w)
      end
    end
  end
end

class GraphW(T)
  alias Node = Int32

  struct Edge(T)
    def initialize(@src : Node, @dst : Node, @wt : T)
    end

    getter src : Node, dst : Node

    getter wt : T
  end
      
  def initialize(@size : Node, @inf = 10**9)
    @g = Array(Array(Edge(T))).new(@size) { [] of Edge(T) }
  end

  getter size : Int32

  getter inf : T

  delegate :[], to: @g

  def add_edge(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
  end

  def add_edge_b(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
    @g[v] << Edge.new(v, u, wt)
  end
end

solve(ProconIO.new)