def solve(io)
  n, k = io.get2(Int64)

  pf = PrimeFactor.sqrt(k)

  r = 0_i64
  pf.divisors(k).each do |d|
    e = k // d
    m1 = d - 1 <= n ? d - 1 : (n * 2 - d + 1).clamp(0..)
    m2 = e - 1 <= n ? e - 1 : (n * 2 - e + 1).clamp(0..)
    r += m1 * m2
  end

  io.put r
end

class ProconIO
  def initialize(@ins : IO = STDIN, @outs : IO = STDOUT)
    @buf = IO::Memory.new("")
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  macro define_get
    {% for i in (2..9) %}
      def get({{ *(1..i).map { |j| "k#{j}".id } }})
        { {{ *(1..i).map { |j| "get(k#{j})".id } }} }
      end
    {% end %}
  end
  define_get

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  macro define_get_c
    {% for i in (2..9) %}
      def get_c(n : Int, {{ *(1..i).map { |j| "k#{j}".id } }})
        a = Array.new(n) { get({{ *(1..i).map { |j| "k#{j}".id } }}) }
        { {{ *(1..i).map { |j| "a.map { |e| e[#{j-1}] }".id } }} }
      end
    {% end %}
  end
  define_get_c

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  macro define_put
    {% for i in (1..9) %}
      def put({{ *(1..i).map { |j| "v#{j}".id } }}, *, delimiter = " ")
        {% for j in (1..i) %}
          print_v(v{{j}}, delimiter)
          {% if j < i %}@outs << delimiter{% end %}
        {% end %}
        @outs.puts
      end
    {% end %}
  end
  define_put

  def put_e(*vs)
    put(*vs)
    exit
  end

  def put_f(*vs)
    put(*vs)
    @outs.flush
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : UInt32.class); get_token.to_u32; end
  private def get_v(k : UInt64.class); get_token.to_u64; end
  private def get_v(k : Float64.class); get_token.to_f64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    loop do
      token = @buf.gets(' ', chomp: true)
      break token unless token.nil?
      @buf = IO::Memory.new(@ins.read_line)
    end
  end

  private def print_v(v, dlimiter)
    @outs << v
  end

  private def print_v(v : Enumerable, delimiter)
    v.each_with_index do |e, i|
      @outs << e
      @outs << delimiter if i < v.size - 1
    end
  end
end

struct Int
  def cdiv(b : Int)
    (self + b - 1) // b
  end

  def bit?(i : Int)
    bit(i) == 1
  end

  def set_bit(i : Int)
    self | (self.class.new(1) << i)
  end

  def reset_bit(i : Int)
    self & ~(self.class.new(1) << i)
  end

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.34.0") < 0 %}
    def bit_length : Int32
      x = self < 0 ? ~self : self

      if x.is_a?(Int::Primitive)
        Int32.new(sizeof(self) * 8 - x.leading_zeros_count)
      else
        to_s(2).size
      end
    end
  {% end %}
end

struct Float64
  def near_zero?
    self.abs < EPSILON
  end
end

struct Number
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.1.0") < 0 %}
    def zero?
      self == 0
    end

    def positive?
      self > 0
    end

    def negative?
      self < 0
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.36.0") < 0 %}
    def self.additive_identity
      zero
    end

    def self.multiplicative_identity
      new(1)
    end
  {% end %}
end

class Array
  macro new_md(*args, &block)
    {% if !block %}
      {% for arg, i in args[0...-2] %}
        Array.new({{arg}}) {
      {% end %}
      Array.new({{args[-2]}}, {{args[-1]}})
      {% for arg in args[0...-2] %}
        }
      {% end %}
    {% else %}
      {% for arg, i in args %}
        Array.new({{arg}}) { |_i{{i}}|
      {% end %}
      {% for block_arg, i in block.args %}
        {{block_arg}} = _i{{i}}
      {% end %}
      {{block.body}}
      {% for arg in args %}
        }
      {% end %}
    {% end %}
  end
end

module Math
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.2.0") < 0 %}
    def isqrt(value : Int::Primitive)
      raise ArgumentError.new "Input must be non-negative integer" if value < 0
      return value if value < 2
      res = value.class.zero
      bit = res.succ << (res.leading_zeros_count - 2)
      bit >>= value.leading_zeros_count & ~0x3
      while (bit != 0)
        if value >= res + bit
          value -= res + bit
          res = (res >> 1) + bit
        else
          res >>= 1
        end
        bit >>= 2
      end
      res
    end
  {% end %}
end

macro min_u(a, b)
  {{a}} = Math.min({{a}}, {{b}})
end

macro max_u(a, b)
  {{a}} = Math.max({{a}}, {{b}})
end

macro zip(a, *b, &block)
  {{a}}.zip({{*b}}) {{block}}
end


class PrimeFactor
  def initialize(@n : Int32)
    s = (@n + 1) // 2
    sieve = Array.new(s, true)

    if @n < 2
      @primes = [] of Int32
      return
    end

    m = (Math.isqrt(n) - 1) // 2
    (1..m).each do |p|
      if sieve[p]
        (p*3+1...s).step(p*2+1) do |q|
          sieve[q] = false
        end
      end
    end

    @primes = [2]
    (1...s).each do |p|
      @primes << p*2+1 if sieve[p]
    end
  end

  def self.sqrt(n : Int)
    self.new(Math.isqrt(n).to_i32)
  end

  getter primes : Array(Int32)

  record Factor(T), prime : T, exp : Int32

  def div(x : T) forall T
    factors = [] of Factor(T)
    t = Math.isqrt(x)
    @primes.each do |p|
      break if p > t
      c = 0
      while x%p == 0
        c += 1
        x //= p
      end
      factors << Factor.new(T.new(p), c) if c > 0
      break if x == 1
    end
    factors << Factor.new(x, 1) if x > 1
    factors
  end

  def divisors(x : T) forall T
    factors = div(x)
    r = divisors_proc(factors, 0, T.multiplicative_identity)
    r.sort!
  end


  def divisors_proc(factors : Array(Factor(T)), i : Int32, c : T) forall T
    return [c] if i == factors.size
    r = [] of T
    (0..factors[i].exp).each do |j|
      r.concat(divisors_proc(factors, i+1, c * factors[i].prime**j))
    end
    r
  end
end

solve(ProconIO.new)