CELL = { '.' => 0, '@' => 1, '#' => 2 }

def solve(io)
  h, w = io.get2
  u, d, r, l, k, p = io.get6(Int64)
  xs, ys, xt, yt = io.get4; xs -= 1; ys -= 1; xt -= 1; yt -= 1
  c = io.get_c(h, String)

  e = c.map { |ci| ci.chars.map { |cij| CELL[cij] } }
  inf = 10_i64 ** 18
  cost = {
    u: { 0 => u, 1 => p + u, 2 => inf },
    d: { 0 => d, 1 => p + d, 2 => inf },
    r: { 0 => r, 1 => p + r, 2 => inf },
    l: { 0 => l, 1 => p + l, 2 => inf }
  }
  g = GraphW(Int64).new(h * w, inf)
  h.times do |i|
    (w - 1).times do |j|
      g.add_edge(idx(i, j), idx(i, j + 1), cost[:r][e[i][j + 1]])
      g.add_edge(idx(i, j + 1), idx(i, j), cost[:l][e[i][j]])
    end
  end
  w.times do |j|
    (h - 1).times do |i|
      g.add_edge(idx(i, j), idx(i + 1, j), cost[:d][e[i + 1][j]])
      g.add_edge(idx(i + 1, j), idx(i, j), cost[:u][e[i][j]])
    end
  end

  dist = g.dijkstra(idx(xs, ys)).dist
  io.put dist[idx(xt, yt)] <= k ? "Yes" : "No"
end

macro idx(r, c)
  ({{r}}) * w + ({{c}})
end

class ProconIO
  def initialize(@ins : IO = STDIN, @outs : IO = STDOUT)
    @buf = IO::Memory.new("")
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  macro define_get
    {% for i in (2..9) %}
      def get({{ *(1..i).map { |j| "k#{j}".id } }})
        { {{ *(1..i).map { |j| "get(k#{j})".id } }} }
      end
    {% end %}
  end
  define_get

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  macro define_get_c
    {% for i in (2..9) %}
      def get_c(n : Int, {{ *(1..i).map { |j| "k#{j}".id } }})
        a = Array.new(n) { get({{ *(1..i).map { |j| "k#{j}".id } }}) }
        { {{ *(1..i).map { |j| "a.map { |e| e[#{j-1}] }".id } }} }
      end
    {% end %}
  end
  define_get_c

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  macro define_put
    {% for i in (1..9) %}
      def put({{ *(1..i).map { |j| "v#{j}".id } }}, *, delimiter = " ")
        {% for j in (1..i) %}
          print_v(v{{j}}, delimiter)
          {% if j < i %}@outs << delimiter{% end %}
        {% end %}
        @outs.puts
      end
    {% end %}
  end
  define_put

  def put_e(*vs)
    put(*vs)
    exit
  end

  def put_f(*vs)
    put(*vs)
    @outs.flush
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : UInt32.class); get_token.to_u32; end
  private def get_v(k : UInt64.class); get_token.to_u64; end
  private def get_v(k : Float64.class); get_token.to_f64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    loop do
      token = @buf.gets(' ', chomp: true)
      break token unless token.nil?
      @buf = IO::Memory.new(@ins.read_line)
    end
  end

  private def print_v(v, dlimiter)
    @outs << v
  end

  private def print_v(v : Enumerable, delimiter)
    v.each_with_index do |e, i|
      @outs << e
      @outs << delimiter if i < v.size - 1
    end
  end
end

struct Int
  def cdiv(b : Int)
    (self + b - 1) // b
  end

  def bit?(i : Int)
    bit(i) == 1
  end

  def set_bit(i : Int)
    self | (self.class.new(1) << i)
  end

  def reset_bit(i : Int)
    self & ~(self.class.new(1) << i)
  end

  
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.35.0") < 0 %}
    def digits(base = 10)
      raise ArgumentError.new("Invalid base #{base}") if base < 2
      raise ArgumentError.new("Can't request digits of negative number") if self < 0
      return [0] if self == 0

      num = self
      digits_count = (Math.log(self.to_f + 1) / Math.log(base)).ceil.to_i
      ary = Array(Int32).new(digits_count)
      while num != 0
        ary << num.remainder(base).to_i
        num = num.tdiv(base)
      end
      ary
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.34.0") < 0 %}
    def bit_length : Int32
      x = self < 0 ? ~self : self

      if x.is_a?(Int::Primitive)
        Int32.new(sizeof(self) * 8 - x.leading_zeros_count)
      else
        to_s(2).size
      end
    end
  {% end %}
end

struct Float64
  def near?(x)
    (self - x).abs <= (self.abs < x.abs ? x.abs : self.abs) * EPSILON
  end
end

struct Number
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.1.0") < 0 %}
    def zero?
      self == 0
    end

    def positive?
      self > 0
    end

    def negative?
      self < 0
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.36.0") < 0 %}
    def self.additive_identity
      zero
    end

    def self.multiplicative_identity
      new(1)
    end
  {% end %}
end

class Array
  macro new_md(*args, &block)
    {% if !block %}
      {% for arg, i in args[0...-2] %}
        Array.new({{arg}}) {
      {% end %}
      Array.new({{args[-2]}}, {{args[-1]}})
      {% for arg in args[0...-2] %}
        }
      {% end %}
    {% else %}
      {% for arg, i in args %}
        Array.new({{arg}}) { |_i{{i}}|
      {% end %}
      {% for block_arg, i in block.args %}
        {{block_arg}} = _i{{i}}
      {% end %}
      {{block.body}}
      {% for arg in args %}
        }
      {% end %}
    {% end %}
  end
end

module Math
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.2.0") < 0 %}
    def isqrt(value : Int::Primitive)
      raise ArgumentError.new "Input must be non-negative integer" if value < 0
      return value if value < 2
      res = value.class.zero
      bit = res.succ << (res.leading_zeros_count - 2)
      bit >>= value.leading_zeros_count & ~0x3
      while (bit != 0)
        if value >= res + bit
          value -= res + bit
          res = (res >> 1) + bit
        else
          res >>= 1
        end
        bit >>= 2
      end
      res
    end
  {% end %}
end

macro min_u(a, b)
  {{a}} = Math.min({{a}}, {{b}})
end

macro max_u(a, b)
  {{a}} = Math.max({{a}}, {{b}})
end

macro zip(a, *b, &block)
  {{a}}.zip({{*b}}) {{block}}
end

require "bit_array"

class Graph
  alias Node = Int32

  def initialize(@size : Node)
    @g = Array(Array(Node)).new(@size) { [] of Node }
  end

  getter size : Int32

  delegate :[], to: @g

  def add_edge(u : Node, v : Node)
    @g[u] << v
  end

  def add_edge_b(u : Node, v : Node)
    @g[u] << v
    @g[v] << u
  end

  def bfs(u : Node)
    b = BitArray.new(@size)
    yield u, -1
    b[u] = true
    q = Deque.new([u])
    until q.empty?
      v = q.shift
      @g[v].each do |w|
        next if b[w]
        yield w, v
        b[w] = true
        q.push(w)
      end
    end
  end
end

class GraphW(T)
  alias Node = Int32

  struct Edge(T)
    def initialize(@src : Node, @dst : Node, @wt : T)
    end

    getter src : Node, dst : Node

    getter wt : T
  end
      
  def initialize(@size : Node, @inf = 10**9)
    @g = Array(Array(Edge(T))).new(@size) { [] of Edge(T) }
  end

  getter size : Int32

  getter inf : T

  delegate :[], to: @g

  def add_edge(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
  end

  def add_edge_b(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
    @g[v] << Edge.new(v, u, wt)
  end
end

class GraphM(T)
  alias Node = Int32

  def initialize(@size : Int32, @inf = 10**9)
    @g = Array.new_md(@size, @size, @inf)
    @size.times do |i|
      @g[i][i] = T.zero
    end
  end

  getter size : Int32

  getter inf : T

  delegate :[], to: @g

  def add_edge(u : Node, v : Node, wt : T)
    @g[u][v] = wt
  end

  def add_edge_b(u : Node, v : Node, wt : T)
    @g[u][v] = @g[v][u] = wt
  end


  @g : Array(Array(T))
end

class Heap(T)
  def initialize
    initialize { |a, b| a <=> b }
  end

  def initialize(&@cmp : (T, T) -> Int32)
    dummy = uninitialized T
    @b = [dummy]
  end

  def initialize(a : Enumerable(T))
    initialize(a) { |a, b| a <=> b }
  end

  def initialize(a : Enumerable(T), &@cmp : (T, T) -> Int32)
    dummy = uninitialized T
    @b = [dummy]
    a.each do |e|
      push(e)
    end
  end

  def empty?
    @b.size == 1
  end

  def size
    @b.size - 1
  end

  def first
    @b[1]
  end

  def first=(v : T)
    @b[1], i = v, 1
    while @b.size > i << 1
      l, r = i << 1, i << 1 | 1
	  j = @b.size <= r || @cmp.call(@b[l], @b[r]) < 0 ? l : r
      break if @cmp.call(@b[i], @b[j]) < 0
      @b[j], @b[i] = @b[i], @b[j]
      i = j
    end
  end

  def push(v : T)
    @b.push(v)
    i = @b.size - 1
    while i > 1
      j = i >> 1
      break if @cmp.call(@b[j], @b[i]) < 0
      @b[j], @b[i] = @b[i], @b[j]
      i = j
    end
    self
  end

  def pop
    v, w = @b[1], @b.pop
    self.first = w unless empty?
    v
  end


  @b : Array(T)
end

class Dijkstra(T)
  alias Node = GraphW::Node
  alias Edge = GraphW::Edge

  def initialize(@g : GraphW(T), s : Node)
    size = @g.size
    @dist = Array.new(size, @g.inf)
    @dist[s] = T.additive_identity
    @prev = Array.new(size, -1)

    se = Edge.new(-1, s, T.new(0))
    h = Heap.new([se]) { |a, b| a.wt <=> b.wt }
    until h.empty?
      e = h.pop

      next if @prev[e.dst] != -1
      @prev[e.dst] = e.src

      @g[e.dst].each do |f|
        w = e.wt + f.wt
        if w < @dist[f.dst]
          @dist[f.dst] = w
          h.push(Edge.new(f.src, f.dst, w))
        end
      end
    end
  end

  getter dist : Array(T)


  @prev : Array(Node)
end

class GraphW(T)
  def dijkstra(s)
    Dijkstra.new(self, s)
  end
end

solve(ProconIO.new)