def solve(io)
  n, q = io.get2
  c = io.get_a(n)

  g = Graph.new(n)
  (n - 1).times do
    ai, bi = io.get2; ai -= 1; bi -= 1;
    g.add_edge_b(ai, bi)
  end
  t = g.tree(0)
  et = t.euler_tour

  st = SegmentTree(Int32).new(et.path.size) { |a, b| a ^ b }
  n.times do |i|
    st[et.in_time[i]] = c[i]
  end

  q.times do
    ti, xi, yi = io.get3; xi -= 1
    case ti
    when 1
      st[et.in_time[xi]] ^= yi
    when 2
      io.put st[et.in_time[xi]..et.out_time[xi]]
    end
  end
end

class ProconIO
  def initialize(@ins : IO = STDIN, @outs : IO = STDOUT)
    @buf = IO::Memory.new("")
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  macro define_get
    {% for i in (2..9) %}
      def get({{ *(1..i).map { |j| "k#{j}".id } }})
        { {{ *(1..i).map { |j| "get(k#{j})".id } }} }
      end
    {% end %}
  end
  define_get

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  macro define_get_c
    {% for i in (2..9) %}
      def get_c(n : Int, {{ *(1..i).map { |j| "k#{j}".id } }})
        a = Array.new(n) { get({{ *(1..i).map { |j| "k#{j}".id } }}) }
        { {{ *(1..i).map { |j| "a.map { |e| e[#{j-1}] }".id } }} }
      end
    {% end %}
  end
  define_get_c

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  macro define_put
    {% for i in (1..9) %}
      def put({{ *(1..i).map { |j| "v#{j}".id } }}, *, delimiter = " ")
        {% for j in (1..i) %}
          print_v(v{{j}}, delimiter)
          {% if j < i %}@outs << delimiter{% end %}
        {% end %}
        @outs.puts
      end
    {% end %}
  end
  define_put

  def put_e(*vs)
    put(*vs)
    exit
  end

  def put_f(*vs)
    put(*vs)
    @outs.flush
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : UInt32.class); get_token.to_u32; end
  private def get_v(k : UInt64.class); get_token.to_u64; end
  private def get_v(k : Float64.class); get_token.to_f64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    loop do
      token = @buf.gets(' ', chomp: true)
      break token unless token.nil?
      @buf = IO::Memory.new(@ins.read_line)
    end
  end

  private def print_v(v, dlimiter)
    @outs << v
  end

  private def print_v(v : Enumerable, delimiter)
    v.each_with_index do |e, i|
      @outs << e
      @outs << delimiter if i < v.size - 1
    end
  end
end

struct Int
  def cdiv(b : Int)
    (self + b - 1) // b
  end

  def bit?(i : Int)
    bit(i) == 1
  end

  def set_bit(i : Int)
    self | (self.class.new(1) << i)
  end

  def reset_bit(i : Int)
    self & ~(self.class.new(1) << i)
  end

  
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.35.0") < 0 %}
    def digits(base = 10)
      raise ArgumentError.new("Invalid base #{base}") if base < 2
      raise ArgumentError.new("Can't request digits of negative number") if self < 0
      return [0] if self == 0

      num = self
      digits_count = (Math.log(self.to_f + 1) / Math.log(base)).ceil.to_i
      ary = Array(Int32).new(digits_count)
      while num != 0
        ary << num.remainder(base).to_i
        num = num.tdiv(base)
      end
      ary
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.34.0") < 0 %}
    def bit_length : Int32
      x = self < 0 ? ~self : self

      if x.is_a?(Int::Primitive)
        Int32.new(sizeof(self) * 8 - x.leading_zeros_count)
      else
        to_s(2).size
      end
    end
  {% end %}
end

struct Float64
  def near?(x)
    (self - x).abs <= (self.abs < x.abs ? x.abs : self.abs) * EPSILON
  end
end

struct Number
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.1.0") < 0 %}
    def zero?
      self == 0
    end

    def positive?
      self > 0
    end

    def negative?
      self < 0
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.36.0") < 0 %}
    def self.additive_identity
      zero
    end

    def self.multiplicative_identity
      new(1)
    end
  {% end %}
end

class Array
  macro new_md(*args, &block)
    {% if !block %}
      {% for arg, i in args[0...-2] %}
        Array.new({{arg}}) {
      {% end %}
      Array.new({{args[-2]}}, {{args[-1]}})
      {% for arg in args[0...-2] %}
        }
      {% end %}
    {% else %}
      {% for arg, i in args %}
        Array.new({{arg}}) { |_i{{i}}|
      {% end %}
      {% for block_arg, i in block.args %}
        {{block_arg}} = _i{{i}}
      {% end %}
      {{block.body}}
      {% for arg in args %}
        }
      {% end %}
    {% end %}
  end
end

module Math
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.2.0") < 0 %}
    def isqrt(value : Int::Primitive)
      raise ArgumentError.new "Input must be non-negative integer" if value < 0
      return value if value < 2
      res = value.class.zero
      bit = res.succ << (res.leading_zeros_count - 2)
      bit >>= value.leading_zeros_count & ~0x3
      while (bit != 0)
        if value >= res + bit
          value -= res + bit
          res = (res >> 1) + bit
        else
          res >>= 1
        end
        bit >>= 2
      end
      res
    end
  {% end %}
end

macro min_u(a, b)
  {{a}} = Math.min({{a}}, {{b}})
end

macro max_u(a, b)
  {{a}} = Math.max({{a}}, {{b}})
end

macro zip(a, *b, &block)
  {{a}}.zip({{*b}}) {{block}}
end

class SegmentTree(T)
  def initialize(@n : Int32, @init : T = T.zero, &@compose : (T, T) -> T)
    @an = 1 << (@n - 1).bit_length
    @buf = Array.new(@an << 1, @init)
    init_propagate
  end

  def initialize(b : Array(T), @init : T = T.zero, &@compose : (T, T) -> T)
    @n = b.size
    @an = 1 << (@n - 1).bit_length
    @buf = Array.new(@an << 1, @init)
    @buf[@an, @n] = b
    init_propagate
  end

  def [](i : Int)
    @buf[i + @an]
  end

  def [](start : Int, count : Int)
    l, r = start + @an, start + count + @an
    r1 = r2 = @init
    while l != r
      if l.odd?
        r1 = @compose.call(r1, @buf[l])
        l += 1
      end
      if r.odd?
        r -= 1
        r2 = @compose.call(@buf[r], r2)
      end
      l >>= 1
      r >>= 1
    end
    @compose.call(r1, r2)
  end

  def [](r : Range)
    sc = Indexable.range_to_index_and_count(r, @n)
    raise ArgumentError.new("Invalid range") if sc.nil?
    self[*sc]
  end

  def []=(i : Int, v : T)
    @buf[i + @an] = v
    propagate(i + @an)
  end


  @an : Int32
  @buf : Array(T)

  private def init_propagate
    (1...@an).reverse_each do |i|
      @buf[i] = @compose.call(@buf[i << 1], @buf[i << 1 | 1])
    end
  end

  private def propagate(i : Int)
    while (i >>= 1) > 0
      @buf[i] = @compose.call(@buf[i << 1], @buf[i << 1 | 1])
    end
  end
end

require "bit_array"

class Graph
  alias Node = Int32

  def initialize(@size : Node)
    @g = Array(Array(Node)).new(@size) { [] of Node }
  end

  getter size : Int32

  delegate :[], to: @g

  def add_edge(u : Node, v : Node)
    @g[u] << v
  end

  def add_edge_b(u : Node, v : Node)
    @g[u] << v
    @g[v] << u
  end

  def bfs(u : Node)
    b = BitArray.new(@size)
    yield u, -1
    b[u] = true
    q = Deque.new([u])
    until q.empty?
      v = q.shift
      @g[v].each do |w|
        next if b[w]
        yield w, v
        b[w] = true
        q.push(w)
      end
    end
  end
end

class GraphW(T)
  alias Node = Int32

  struct Edge(T)
    def initialize(@src : Node, @dst : Node, @wt : T)
    end

    getter src : Node, dst : Node

    getter wt : T
  end
      
  def initialize(@size : Node, @inf = 10**9)
    @g = Array(Array(Edge(T))).new(@size) { [] of Edge(T) }
  end

  getter size : Int32

  getter inf : T

  delegate :[], to: @g

  def add_edge(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
  end

  def add_edge_b(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
    @g[v] << Edge.new(v, u, wt)
  end
end

class GraphM(T)
  alias Node = Int32

  def initialize(@size : Int32, @inf = 10**9)
    @g = Array.new_md(@size, @size, @inf)
    @size.times do |i|
      @g[i][i] = T.zero
    end
  end

  getter size : Int32

  getter inf : T

  delegate :[], to: @g

  def add_edge(u : Node, v : Node, wt : T)
    @g[u][v] = wt
  end

  def add_edge_b(u : Node, v : Node, wt : T)
    @g[u][v] = @g[v][u] = wt
  end


  @g : Array(Array(T))
end

class Tree
  alias Node = Graph::Node

  def initialize(@g : Graph, @root : Node)
    size = @g.size
    @parent = Array.new(size, 0)
    @children = Array.new(size) { [] of Node }
    @depth = Array.new(size, -1)
    @dfs_order = [] of Node

    s = [{@root, @root}]
    until s.empty?
      u, p = s.pop

      @parent[u] = p
      @depth[u] = @depth[p] + 1
      @dfs_order << u

      @g[u].each do |v|
        if v != p
          @children[u] << v
          s.push({v, u})
        end
      end
    end

    @descendant_size = Array.new(size, 1)
    @dfs_order.reverse_each do |u|
      @descendant_size[@parent[u]] += @descendant_size[u] if u != @root
    end
  end

  delegate size, to: @g

  getter root : Node

  getter dfs_order : Array(Node)

  getter parent : Array(Node)

  getter children : Array(Array(Node))

  getter depth : Array(Int32)

  getter descendant_size : Array(Int32)
end

class Graph
  def tree(root)
    Tree.new(self, root)
  end
end

class EulerTour
  alias Node = Graph::Node

  def initialize(t : Tree)
    @path = [] of Node
    @in_time = Array.new(t.size, 0)
    @out_time = Array.new(t.size, 0)
    s = [~t.root, t.root]
    c = -1
    until s.empty?
      u = s.pop
      c += 1
      if u < 0
        @path << ~u
        @out_time[~u] = c
      else
        @path << u
        @in_time[u] = c
        children = t.children[u]
        children.each_with_index do |v, i|
          s.push(~v)
          s.push(v)
          s.push(~u) if i < children.size - 1
        end
      end
    end
  end

  getter path : Array(Node)

  getter in_time : Array(Int32)

  getter out_time : Array(Int32)
end

class Tree
  def euler_tour
    EulerTour.new(self)
  end
end

solve(ProconIO.new)