def solve(io)
  n, m = io.get(Int64, Int32)
  a = io.get_a(m, Int64)

  b = [{0_i64, 0}] + a.map_with_index { |ai, i| {ai, i+1} }
  st = SegmentTree.new(b, :max, {0_i64, 0})

  q = io.get
  q.times do
    ti, xi, yi = io.get(Int32, Int32, Int64)
    case ti
    when 1
      c = st[xi]
      st[xi] = {c[0]+yi, c[1]}
    when 2
      c = st[xi]
      st[xi] = {c[0]-yi, c[1]}
    when 3
      c = st[0..-1]
      io.put c[1]
    end
  end
end

record Pair, v : Int32, a : Int64

class ProconIO
  def initialize(@ins : IO = STDIN, @outs : IO = STDOUT)
    @buf = IO::Memory.new("")
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  macro define_get
    {% for i in (2..9) %}
      def get({{ *(1..i).map { |j| "k#{j}".id } }})
        { {{ *(1..i).map { |j| "get(k#{j})".id } }} }
      end
    {% end %}
  end
  define_get

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  macro define_get_t
    {% for i in (2..9) %}
      def get_t(n : Int, {{ *(1..i).map { |j| "k#{j}".id } }})
        Array.new(n) { get({{ *(1..i).map { |j| "k#{j}".id } }}) }
      end
    {% end %}
  end
  define_get_t

  macro define_getn_t
    {% for i in (2..9) %}
      def get{{i}}_t(n : Int, k : T.class = Int32) forall T
        get_t(n, {{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn_t

  macro define_get_c
    {% for i in (2..9) %}
      def get_c(n : Int, {{ *(1..i).map { |j| "k#{j}".id } }})
        a = get_t(n, {{ *(1..i).map { |j| "k#{j}".id } }})
        { {{ *(1..i).map { |j| "a.map { |e| e[#{j-1}] }".id } }} }
      end
    {% end %}
  end
  define_get_c

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {{ *(1..i).map { "k".id } }})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  def put(*v)
    @outs.puts(*v)
  end

  def put_e(*v)
    put(*v)
    exit
  end

  def put_a(*v)
    put_d(*v, delimiter: ' ')
  end

  def put_ae(*v)
    put_a(*v)
    exit
  end

  def put_c(*v)
    put_d(*v, delimiter: '\n')
  end

  def put_ce(*v)
    put_c(*v)
    exit
  end

  def put_d(*v, delimiter)
    v.each_with_index do |vi, i|
      vi.each_with_index do |vij, j|
        @outs.print vij
        @outs.print delimiter if j < vi.size - 1
      end
      @outs.print delimiter if i < v.size - 1
    end
    @outs.puts
  end


  private def get_v(k : String.class); get_token; end
  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end

  private def get_token
    loop do
      token = @buf.gets(' ', chomp: true)
      break token unless token.nil?
      @buf = IO::Memory.new(@ins.read_line)
    end
  end
end
macro min_u(a, b)
  {{a}} = { {{a}}, {{b}} }.min
end

macro max_u(a, b)
  {{a}} = { {{a}}, {{b}} }.max
end

macro records(rec, a)
  {{a}}.map { |v| {{rec}}.new(*v) }
end
struct Number
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.1.0") < 0 %}
    def zero?
      self == 0
    end

    def positive?
      self > 0
    end

    def negative?
      self < 0
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.36.0") < 0 %}
    def self.additive_identity
      zero
    end

    def self.multiplicative_identity
      new(1)
    end
  {% end %}
end
struct Int
  def cdiv(b : Int)
    (self + b - 1) // b
  end

  def bit?(i : Int)
    bit(i) == 1
  end

  def set_bit(i : Int)
    self | (self.class.new(1) << i)
  end

  def reset_bit(i : Int)
    self & ~(self.class.new(1) << i)
  end

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.35.0") < 0 %}
    def digits(base = 10)
      raise ArgumentError.new("Invalid base #{base}") if base < 2
      raise ArgumentError.new("Can't request digits of negative number") if self < 0
      return [0] if self == 0

      num = self
      digits_count = (Math.log(self.to_f + 1) / Math.log(base)).ceil.to_i
      ary = Array(Int32).new(digits_count)
      while num != 0
        ary << num.remainder(base).to_i
        num = num.tdiv(base)
      end
      ary
    end
  {% end %}

  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "0.34.0") < 0 %}
    def bit_length : Int32
      x = self < 0 ? ~self : self

      if x.is_a?(Int::Primitive)
        Int32.new(sizeof(self) * 8 - x.leading_zeros_count)
      else
        to_s(2).size
      end
    end
  {% end %}
end
class Array
  macro new_md(*args, &block)
    {% if !block %}
      {% for arg, i in args[0...-2] %}
        Array.new({{arg}}) {
      {% end %}
      Array.new({{args[-2]}}, {{args[-1]}})
      {% for arg in args[0...-2] %}
        }
      {% end %}
    {% else %}
      {% for arg, i in args %}
        Array.new({{arg}}) { |_i{{i}}|
      {% end %}
      {% for block_arg, i in block.args %}
        {{block_arg}} = _i{{i}}
      {% end %}
      {{block.body}}
      {% for arg in args %}
        }
      {% end %}
    {% end %}
  end
end
module Math
  {% if compare_versions(env("CRYSTAL_VERSION") || "0.0.0", "1.2.0") < 0 %}
    def isqrt(value : Int::Primitive)
      raise ArgumentError.new "Input must be non-negative integer" if value < 0
      return value if value < 2
      res = value.class.zero
      bit = res.succ << (res.leading_zeros_count - 2)
      bit >>= value.leading_zeros_count & ~0x3
      while (bit != 0)
        if value >= res + bit
          value -= res + bit
          res = (res >> 1) + bit
        else
          res >>= 1
        end
        bit >>= 2
      end
      res
    end
  {% end %}
end

module Binary(T)
  extend self

  def get(op : Symbol) : (T, T) -> T
    case op
    when :+   then return ->add(T, T)
    when :*   then return ->mul(T, T)
    when :min then return ->min(T, T)
    when :max then return ->max(T, T)
    end
    raise ArgumentError.new("not supported operator")
  end

  def add(a : T, b : T) : T
    if a.responds_to?(:+)
      r = a + b
      return r if r.is_a?(T)
    end
    raise NotImplementedError.new("this type does not support '+'")
  end

  def mul(a : T, b : T) : T
    if a.responds_to?(:*)
      r = a * b
      return r if r.is_a?(T)
    end
    raise NotImplementedError.new("this type does not support '*'")
  end

  def min(a : T, b : T) : T
    if a.responds_to?(:<=>)
      r = Math.min(a, b)
      return r if r.is_a?(T)
    end
    raise NotImplementedError.new("this type does not support 'min'")
  end

  def max(a : T, b : T) : T
    if a.responds_to?(:<=>)
      r = Math.max(a, b)
      return r if r.is_a?(T)
    end
    raise NotImplementedError.new("this type does not support 'max'")
  end
end

class SegmentTree(T)
  def initialize(@n : Int32, @init : T = T.zero, &@compose : (T, T) -> T)
    @an = 1 << (@n - 1).bit_length
    @buf = Array.new(@an << 1, @init)
    init_propagate
  end

  def initialize(b : Array(T), @init : T = T.zero, &@compose : (T, T) -> T)
    @n = b.size
    @an = 1 << (@n - 1).bit_length
    @buf = Array.new(@an << 1, @init)
    @buf[@an, @n] = b
    init_propagate
  end

  def initialize(@n : Int32, op : Symbol, @init : T = T.zero)
    initialize(@n, @init, &Binary(T).get(op))
  end

  def initialize(b : Array(T), op : Symbol, @init : T = T.zero)
    initialize(b, @init, &Binary(T).get(op))
  end

  def [](i : Int)
    @buf[i + @an]
  end

  def [](start : Int, count : Int)
    l, r = start + @an, start + count + @an
    r1 = r2 = @init
    while l != r
      if l.odd?
        r1 = @compose.call(r1, @buf[l])
        l += 1
      end
      if r.odd?
        r -= 1
        r2 = @compose.call(@buf[r], r2)
      end
      l >>= 1
      r >>= 1
    end
    @compose.call(r1, r2)
  end

  def [](r : Range)
    sc = Indexable.range_to_index_and_count(r, @n)
    raise ArgumentError.new("Invalid range") if sc.nil?
    self[*sc]
  end

  def []=(i : Int, v : T)
    @buf[i + @an] = v
    propagate(i + @an)
  end


  @an : Int32
  @buf : Array(T)

  private def init_propagate
    (1...@an).reverse_each do |i|
      @buf[i] = @compose.call(@buf[i << 1], @buf[i << 1 | 1])
    end
  end

  private def propagate(i : Int)
    while (i >>= 1) > 0
      @buf[i] = @compose.call(@buf[i << 1], @buf[i << 1 | 1])
    end
  end
end

solve(ProconIO.new)