module main;

import std;
// https://qiita.com/drken/items/ecd1a472d3a0e7db8dce より
bool[] isPrime, isPrimeSmall;
// K以上N以下の素数とそのハッシュを計算して入れる
int[] primes, hashes;
// [a, b)の整数に対して篩をかける。isPrime[i - a] == true ⇔ iが素数
void segmentSieve(int a, int b)
{
	for (int i = 0; i * i < b; i++) isPrimeSmall[i] = true;
	isPrime[0 .. b - a] = true;

	for (int i = 2; i * i < b; i++) {
		if (!isPrimeSmall[i]) continue;
		// [2, √b)の篩
		for (int j = 2 * i; j * j < b; j += i) isPrimeSmall[j] = false;
		// [a, b)の篩
		for (int j = max(2, (a + i - 1) / i) * i; j < b; j += i) isPrime[j - a] = false;
	}
}
// 整数の各桁を1桁になるまで足す
int calcHash(int x)
{
	while (x >= 10) {
		x = x.to!string.map!"a-'0'".sum;
	}
	return x;
}
void main()
{
	// 入力
	int K = readln.chomp.to!int;
	int N = readln.chomp.to!int;
	isPrime = new bool[](N + 2);
	isPrimeSmall = new bool[](450);	// √200_000 = 447.213…
	// 答えの計算と出力
	segmentSieve(K, N + 1);
	foreach (i; K .. N + 1) {
		if (!isPrime[i - K] || i == 1) continue;
		// iとiのハッシュを配列に追加
		primes ~= i;
		hashes ~= calcHash(i);
	}
	// しゃくとり法
	int r = 0, maxLen = 1, ans, len = cast(int)hashes.length;
	int[int] hashList;
	foreach (l; 0 .. len) {
		while (r < len && (hashes[r] !in hashList || hashList[hashes[r]] <= 0))
			hashList[hashes[r++]]++;
		if (maxLen <= r - l + 1) {
			ans = l;
			maxLen = r - l + 1;
		}
		if (r == l)
			r++;
		else
			hashList[hashes[l]]--;
	}
	writeln(primes[ans]);
}