import std;

void main () {
    int N = readln.chomp.to!int;
    auto A = readln.split.to!(int[]);

    // 解説AC
    // 各項寄与を考える。以降1-indexed
    // A[i]を採用し、A[i]の左からl項、右からr項抜いてきた部分列はcomb(i - 1, l) * comb(N - i, r)通り
    // そのような部分列の中からA[i]を含む連続部分列は(l + 1) * (r + 1)通りとれる。(左、右から0 ~ 項採用する感じ)
    // したがって、(0 <= l <= i - 1), (0 <= r <= N - i) comb(i - 1, l) * comb(N - i, r) * (l + 1) * (r + 1)がある程度の速度で計算できればOK
    // lとrを分離すると、次のようになる。 { (0 <= l <= i - 1) comb(i - 1, l) * (l + 1) } * { (0 <= r <= N - i) comb(N - i, r) * (r + 1) }
    // これをうまく変形する。
    // wolfram alphaに投げるなり調べるなりすると、
    // { (0 <= l <= i - 1) (i - 1) * comb(i - 2, l - 1) + comb(i - 1, l) } * { (0 <= r <= N - i) (N - i) * comb(N - i - 1, r - 1) + comb(N - i, r) }
    // = { (i - 1) * 2^(i - 2) + 2^(i - 1) } * { (N - i) * 2^(N - i - 1) + 2^(N - i) }
    // = { (i - 1) * 2^(i - 2) + 2 * 2^(i - 2) } * { (N - i) * 2^(N - i - 1) + 2 * 2^(N - i - 1) }
    // = (i + 1) * 2^(i - 2) * (N - i + 2) * 2^(N - i - 1)
    // = (i + 1) * (N - i + 2) * 2^(N - 3)
    // クエリO(1)になり、これで解ける。

    solve(N, A);
}

void solve (int N, int[] A) {
    const long MOD = 998244353;
    long prod;
    if (0 <= N - 3) {
        prod = mod_pow(2, N - 3, MOD);
    }
    else {
        prod = mod_pow(mod_inv(2, MOD), abs(N - 3), MOD);
    }

    long ans = 0;
    foreach (i; 0..N) {
        ans += 1L * A[i] * (i + 2) % MOD * (N - i + 1) % MOD * prod % MOD;

        ans %= MOD;
    }

    writeln(ans);
}


long mod_pow (long a, long x, const long MOD)
in {
    assert(0 <= x, "x must satisfy 0 <= x");
    assert(1 <= MOD, "MOD must satisfy 1 <= MOD");
    assert(MOD <= int.max, "MOD must satisfy MOD*MOD <= long.max");
}
do {
    // normalize
    a %= MOD; a += MOD; a %= MOD;

    long res = 1L;
    long base = a;
    while (0 < x) {
        if (0 < (x&1)) (res *= base) %= MOD;
        (base *= base) %= MOD;
        x >>= 1;
    }

    return res % MOD;
}

// check mod_pow
static assert(__traits(compiles, mod_pow(2, 10, 998244353)));

long mod_inv (const long x, const long MOD)
in {
    import std.format : format;
    assert(1 <= MOD, format("MOD must satisfy 1 <= MOD. Now MOD =  %s.", MOD));
    assert(MOD <= int.max, format("MOD must satisfy MOD*MOD <= long.max. Now MOD = %s.", MOD));
}
do {
    return mod_pow(x, MOD-2, MOD);
}