#542855 (D) No.1241 Eternal Tours

提出ソース

結果

問題	No.1241 Eternal Tours
ユーザー	👑 hos.lyric
提出日時	2020-08-29 04:50:20
言語	D (dmd 2.106.1)
結果	AC
実行時間	820 ms / 6,000 ms
コード長	8,785 bytes
コンパイル時間	1,321 ms
コンパイル使用メモリ	153,608 KB
実行使用メモリ	22,820 KB
最終ジャッジ日時	2023-09-04 09:33:22
合計ジャッジ時間	17,305 ms
ジャッジサーバーID （参考情報）	judge12 / judge13

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	4 ms 5,036 KB
testcase_01	AC	5 ms 5,060 KB
testcase_02	AC	203 ms 13,152 KB
testcase_03	AC	7 ms 6,184 KB
testcase_04	AC	5 ms 5,912 KB
testcase_05	AC	5 ms 5,004 KB
testcase_06	AC	5 ms 4,996 KB
testcase_07	AC	5 ms 5,120 KB
testcase_08	AC	5 ms 5,448 KB
testcase_09	AC	5 ms 5,336 KB
testcase_10	AC	5 ms 4,384 KB
testcase_11	AC	5 ms 4,988 KB
testcase_12	AC	5 ms 5,044 KB
testcase_13	AC	5 ms 5,948 KB
testcase_14	AC	397 ms 10,204 KB
testcase_15	AC	5 ms 5,132 KB
testcase_16	AC	99 ms 6,576 KB
testcase_17	AC	817 ms 18,924 KB
testcase_18	AC	815 ms 13,104 KB
testcase_19	AC	756 ms 10,060 KB
testcase_20	AC	7 ms 5,244 KB
testcase_21	AC	16 ms 5,048 KB
testcase_22	AC	787 ms 15,016 KB
testcase_23	AC	28 ms 5,644 KB
testcase_24	AC	5 ms 6,132 KB
testcase_25	AC	5 ms 5,320 KB
testcase_26	AC	6 ms 6,596 KB
testcase_27	AC	6 ms 6,396 KB
testcase_28	AC	377 ms 13,096 KB
testcase_29	AC	385 ms 13,088 KB
testcase_30	AC	546 ms 13,080 KB
testcase_31	AC	388 ms 7,896 KB
testcase_32	AC	818 ms 22,820 KB
testcase_33	AC	763 ms 9,456 KB
testcase_34	AC	803 ms 13,048 KB
testcase_35	AC	799 ms 13,032 KB
testcase_36	AC	5 ms 5,792 KB
testcase_37	AC	4 ms 5,060 KB
testcase_38	AC	791 ms 9,456 KB
testcase_39	AC	788 ms 10,252 KB
testcase_40	AC	820 ms 13,092 KB
testcase_41	AC	577 ms 20,560 KB
testcase_42	AC	530 ms 9,328 KB
testcase_43	AC	558 ms 13,092 KB

権限があれば一括ダウンロードができます

ソースコード

raw source code

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }


struct ModInt(int M_) {
  import std.conv : to;
  alias M = M_;
  int x;
  this(ModInt a) { x = a.x; }
  this(long a) { x = cast(int)(a % M); if (x < 0) x += M; }
  ref ModInt opAssign(long a) { return (this = ModInt(a)); }
  ref ModInt opOpAssign(string op)(ModInt a) {
    static if (op == "+") { x += a.x; if (x >= M) x -= M; }
    else static if (op == "-") { x -= a.x; if (x < 0) x += M; }
    else static if (op == "*") { x = cast(int)((cast(long)(x) * a.x) % M); }
    else static if (op == "/") { this *= a.inv(); }
    else static assert(false);
    return this;
  }
  ref ModInt opOpAssign(string op)(long a) {
    static if (op == "^^") {
      if (a < 0) return (this = inv()^^(-a));
      ModInt t2 = this, te = ModInt(1);
      for (long e = a; e > 0; e >>= 1) {
        if (e & 1) te *= t2;
        t2 *= t2;
      }
      x = cast(int)(te.x);
      return this;
    } else return mixin("this " ~ op ~ "= ModInt(a)");
  }
  ModInt inv() const {
    int a = x, b = M, y = 1, z = 0, t;
    for (; ; ) {
      t = a / b; a -= t * b;
      if (a == 0) {
        assert(b == 1 || b == -1);
        return ModInt(b * z);
      }
      y -= t * z;
      t = b / a; b -= t * a;
      if (b == 0) {
        assert(a == 1 || a == -1);
        return ModInt(a * y);
      }
      z -= t * y;
    }
  }
  ModInt opUnary(string op: "-")() const { return ModInt(-x); }
  ModInt opBinary(string op, T)(T a) const {
    return mixin("ModInt(this) " ~ op ~ "= a");
  }
  ModInt opBinaryRight(string op)(long a) const {
    return mixin("ModInt(a) " ~ op ~ "= this");
  }
  bool opCast(T: bool)() const { return (x != 0); }
  string toString() const { return x.to!string; }
}

enum MO = 998244353;
alias Mint = ModInt!MO;


// M: prime, G: primitive root
class Fft(int M_, int G, int K) {
  import std.algorithm : reverse;
  import std.traits : isIntegral;
  alias M = M_;
  // 1, 1/4, 1/8, 3/8, 1/16, 5/16, 3/16, 7/16, ...
  int[] gs;
  this() {
    static assert(2 <= K && K <= 30, "Fft: 2 <= K <= 30 must hold");
    static assert(!((M - 1) & ((1 << K) - 1)), "Fft: 2^K | M - 1 must hold");
    gs = new int[1 << (K - 1)];
    gs[0] = 1;
    long g2 = G, gg = 1;
    for (int e = (M - 1) >> K; e; e >>= 1) {
      if (e & 1) gg = (gg * g2) % M;
      g2 = (g2 * g2) % M;
    }
    gs[1 << (K - 2)] = cast(int)(gg);
    for (int l = 1 << (K - 2); l >= 2; l >>= 1) {
      gs[l >> 1] = cast(int)((cast(long)(gs[l]) * gs[l]) % M);
    }
    assert((cast(long)(gs[1]) * gs[1]) % M == M - 1,
           "Fft: g^(2^(K-1)) == -1 (mod M) must hold");
    for (int l = 2; l <= 1 << (K - 2); l <<= 1) {
      foreach (i; 1 .. l) {
        gs[l + i] = cast(int)((cast(long)(gs[l]) * gs[i]) % M);
      }
    }
  }
  void fft(int[] xs) const {
    const n = cast(int)(xs.length);
    assert(!(n & (n - 1)), "Fft.fft: |xs| must be a power of two");
    assert(n <= 1 << K, "Fft.fft: |xs| <= 2^K must hold");
    for (int l = n; l >>= 1; ) {
      foreach (i; 0 .. (n >> 1) / l) {
        const(long) g = gs[i];
        foreach (j; (i << 1) * l .. (i << 1 | 1) * l) {
          const t = cast(int)((g * xs[j + l]) % M);
          if ((xs[j + l] = xs[j] - t) < 0) xs[j + l] += M;
          if ((xs[j] += t) >= M) xs[j] -= M;
        }
      }
    }
  }
  void invFft(int[] xs) const {
    const n = cast(int)(xs.length);
    assert(!(n & (n - 1)), "Fft.invFft: |xs| must be a power of two");
    assert(n <= 1 << K, "Fft.invFft: |xs| <= 2^K must hold");
    for (int l = 1; l < n; l <<= 1) reverse(xs[l .. l << 1]);
    for (int l = 1; l < n; l <<= 1) {
      foreach (i; 0 .. (n >> 1) / l) {
        const(long) g = gs[i];
        foreach (j; (i << 1) * l .. (i << 1 | 1) * l) {
          int t = cast(int)((g * (xs[j] - xs[j + l])) % M);
          if (t < 0) t += M;
          if ((xs[j] += xs[j + l]) >= M) xs[j] -= M;
          xs[j + l] = t;
        }
      }
    }
  }
  T[] convolute(T)(inout(T)[] as, inout(T)[] bs) const if (isIntegral!T) {
    const na = cast(int)(as.length), nb = cast(int)(bs.length);
    int n, invN = 1;
    for (n = 1; n < na + nb - 1; n <<= 1) {
      invN = ((invN & 1) ? (invN + M) : invN) >> 1;
    }
    auto xs = new int[n], ys = new int[n];
    foreach (i; 0 .. na) if ((xs[i] = cast(int)(as[i] % M)) < 0) xs[i] += M;
    foreach (i; 0 .. nb) if ((ys[i] = cast(int)(bs[i] % M)) < 0) ys[i] += M;
    fft(xs);
    fft(ys);
    foreach (i; 0 .. n) {
      xs[i] = cast(int)((((cast(long)(xs[i]) * ys[i]) % M) * invN) % M);
    }
    invFft(xs);
    auto cs = new T[na + nb - 1];
    foreach (i; 0 .. na + nb - 1) cs[i] = cast(T)(xs[i]);
    return cs;
  }
  ModInt!M[] convolute(inout(ModInt!M)[] as, inout(ModInt!M)[] bs) const {
    const na = cast(int)(as.length), nb = cast(int)(bs.length);
    int n, invN = 1;
    for (n = 1; n < na + nb - 1; n <<= 1) {
      invN = ((invN & 1) ? (invN + M) : invN) >> 1;
    }
    auto xs = new int[n], ys = new int[n];
    foreach (i; 0 .. na) xs[i] = as[i].x;
    foreach (i; 0 .. nb) ys[i] = bs[i].x;
    fft(xs);
    fft(ys);
    foreach (i; 0 .. n) {
      xs[i] = cast(int)((((cast(long)(xs[i]) * ys[i]) % M) * invN) % M);
    }
    invFft(xs);
    auto cs = new ModInt!M[na + nb - 1];
    foreach (i; 0 .. na + nb - 1) cs[i].x = xs[i];
    return cs;
  }
  int[] convolute(int M1)(inout(ModInt!M1)[] as, inout(ModInt!M1)[] bs) const
      if (M != M1) {
    const na = cast(int)(as.length), nb = cast(int)(bs.length);
    int n, invN = 1;
    for (n = 1; n < na + nb - 1; n <<= 1) {
      invN = ((invN & 1) ? (invN + M) : invN) >> 1;
    }
    auto xs = new int[n], ys = new int[n];
    foreach (i; 0 .. na) xs[i] = as[i].x;
    foreach (i; 0 .. nb) ys[i] = bs[i].x;
    fft(xs);
    fft(ys);
    foreach (i; 0 .. n) {
      xs[i] = cast(int)((((cast(long)(xs[i]) * ys[i]) % M) * invN) % M);
    }
    invFft(xs);
    return xs[0 .. na + nb - 1];
  }
}

alias Fft0 = Fft!(998244353, 3, 20);


void main() {
  const FFT = new Fft0;
  
  try {
    for (; ; ) {
      const X = readInt();
      const Y = readInt();
      const T = readLong();
      const A = readInt();
      const B = readInt();
      const C = readInt();
      const D = readInt();
      
      auto f = new int[][](1 << (X + 1), 1 << (Y + 1));
      f[0][0] = f[1][0] = f[$ - 1][0] = f[0][1] = f[0][$ - 1] = 1;
      
      auto work = new int[1 << (X + 1)];
      
      foreach (i; 0 .. 1 << (X + 1)) {
        FFT.fft(f[i]);
      }
      foreach (j; 0 .. 1 << (Y + 1)) {
        foreach (i; 0 .. 1 << (X + 1)) {
          work[i] = f[i][j];
        }
        FFT.fft(work);
        foreach (i; 0 .. 1 << (X + 1)) {
          f[i][j] = work[i];
        }
      }
      
      foreach (i; 0 .. 1 << (X + 1)) foreach (j; 0 .. 1 << (Y + 1)) {
        f[i][j] = (Mint(f[i][j])^^T).x;
      }
      
      foreach (i; 0 .. 1 << (X + 1)) {
        FFT.invFft(f[i]);
      }
      foreach (j; 0 .. 1 << (Y + 1)) {
        foreach (i; 0 .. 1 << (X + 1)) {
          work[i] = f[i][j];
        }
        FFT.invFft(work);
        foreach (i; 0 .. 1 << (X + 1)) {
          f[i][j] = work[i];
        }
      }
      
      debug {
        if (X + Y <= 4) {
          foreach (i; 0 .. 1 << (X + 1)) {
            writeln(i, ": ", f[i]);
          }
        }
      }
      
      Mint ans;
      foreach (s; 0 .. 2) foreach (t; 0 .. 2) {
        const i = ((-1)^^s * C - A) & ((1 << (X + 1)) - 1);
        const j = ((-1)^^t * D - B) & ((1 << (Y + 1)) - 1);
        debug {
          writefln("%s %s: %s %s", s, t, i, j);
        }
        ans += (-1)^^(s ^ t) * f[i][j];
      }
      ans /= (1 << ((X + 1) + (Y + 1)));
      writeln(ans);
    }
  } catch (EOFException e) {
  }
}

yukicoder

結果

テストケース

ソースコード