結果
| 問題 |
No.1188 レベルX門松列
|
| コンテスト | |
| ユーザー |
 sansaqua
|
| 提出日時 | 2020-08-22 18:21:55 |
| 言語 | Common Lisp (sbcl 2.5.0) |
| 結果 |
AC
|
| 実行時間 | 75 ms / 2,000 ms |
| コード長 | 15,846 bytes |
| コンパイル時間 | 600 ms |
| コンパイル使用メモリ | 89,472 KB |
| 実行使用メモリ | 30,208 KB |
| 最終ジャッジ日時 | 2024-10-15 12:02:46 |
| 合計ジャッジ時間 | 2,294 ms |
|
ジャッジサーバーID （参考情報） |
judge4 / judge2 |
（要ログイン）
| ファイルパターン | 結果 |
|---|---|
| sample | AC * 3 |
| other | AC * 21 |
コンパイルメッセージ
; compiling file "/home/judge/data/code/Main.lisp" (written 15 OCT 2024 12:02:42 PM): ; wrote /home/judge/data/code/Main.fasl ; compilation finished in 0:00:00.412
ソースコード
(in-package :cl-user)
(eval-when (:compile-toplevel :load-toplevel :execute)
(sb-int:defconstant-eqx opt
#+swank '(optimize (speed 3) (safety 2))
#-swank '(optimize (speed 3) (safety 0) (debug 0))
#'equal)
#+swank (ql:quickload '(:cl-debug-print :fiveam) :silent t)
#-swank (set-dispatch-macro-character
#\# #\> (lambda (s c p) (declare (ignore c p)) `(values ,(read s nil nil t)))))
#+swank (cl-syntax:use-syntax cl-debug-print:debug-print-syntax)
(defmacro define-int-types (&rest bits)
`(progn
,@(mapcar (lambda (b) `(deftype ,(intern (format nil "UINT~A" b)) () '(unsigned-byte ,b))) bits)
,@(mapcar (lambda (b) `(deftype ,(intern (format nil "INT~A" b)) () '(signed-byte ,b))) bits)))
(define-int-types 2 4 7 8 15 16 31 32 62 63 64)
(defconstant +mod+ 1000000007)
(defmacro dbg (&rest forms)
#+swank (if (= (length forms) 1)
`(format *error-output* "~A => ~A~%" ',(car forms) ,(car forms))
`(format *error-output* "~A => ~A~%" ',forms `(,,@forms)))
#-swank (declare (ignore forms)))
(declaim (inline println))
(defun println (obj &optional (stream *standard-output*))
(let ((*read-default-float-format* 'double-float))
(prog1 (princ obj stream) (terpri stream))))
;; BEGIN_INSERTED_CONTENTS
(defpackage :cp/read-fixnum
(:use :cl)
(:export #:read-fixnum))
(in-package :cp/read-fixnum)
(declaim (ftype (function * (values fixnum &optional)) read-fixnum))
(defun read-fixnum (&optional (in *standard-input*))
"NOTE: cannot read -2^62"
(declare #.cl-user::opt)
(macrolet ((%read-byte ()
`(the (unsigned-byte 8)
#+swank (char-code (read-char in nil #\Nul))
#-swank (sb-impl::ansi-stream-read-byte in nil #.(char-code #\Nul) nil))))
(let* ((minus nil)
(result (loop (let ((byte (%read-byte)))
(cond ((<= 48 byte 57)
(return (- byte 48)))
((zerop byte) ; #\Nul
(error "Read EOF or #\Nul."))
((= byte #.(char-code #\-))
(setq minus t)))))))
(declare ((integer 0 #.most-positive-fixnum) result))
(loop
(let* ((byte (%read-byte)))
(if (<= 48 byte 57)
(setq result (+ (- byte 48)
(* 10 (the (integer 0 #.(floor most-positive-fixnum 10))
result))))
(return (if minus (- result) result))))))))
(defpackage :cp/inverse-table
(:use :cl)
(:export #:make-inverse-table #:make-monotone-inverse-table!))
(in-package :cp/inverse-table)
(declaim (inline make-reverse-inverse-table))
(defun make-inverse-table (vector &key (test #'eql))
"Returns a hash-table that assigns each value of the (usually sorted) VECTOR
of length n to the integers 0, ..., n-1."
(let ((table (make-hash-table :test test :size (length vector))))
(dotimes (i (length vector) table)
(setf (gethash (aref vector i) table) i))))
(declaim (inline make-monotone-inverse-table!))
(defun make-monotone-inverse-table! (vector &key (test #'eql) (order #'<))
"Sorts VECTOR, deletes all adjacent duplicates, and returns a hash-table that
assigns each value of the vector to the integers 0, 1, ..."
(declare (function test order)
(vector vector)
(inline sort))
(setq vector (sort vector order))
(let ((table (make-hash-table :test test :size (length vector)))
(index 0))
(declare ((integer 0 #.most-positive-fixnum) index))
(dotimes (pos (length vector))
(when (or (zerop pos)
(not (funcall test (aref vector pos) (aref vector (- pos 1)))))
(setf (gethash (aref vector pos) table) index)
(incf index)))
(values table index)))
(defpackage :cp/modify-macro
(:use :cl)
(:export #:minf #:maxf #:mulf #:divf #:iorf #:xorf #:andf))
(in-package :cp/modify-macro)
(macrolet ((def (name fname)
`(define-modify-macro ,name (new-value) ,fname)))
(def minf min)
(def maxf max)
(def mulf *)
(def divf /)
(def iorf logior)
(def xorf logxor)
(def andf logand))
;;;
;;; 1-dimensional binary indexed tree on arbitrary commutative monoid
;;;
(defpackage :cp/abstract-bit
(:use :cl)
(:export #:define-bitree))
(in-package :cp/abstract-bit)
(defmacro define-bitree (name &key (operator '#'+) (identity 0) sum-type (order '#'<))
"OPERATOR := binary operator (comprising a commutative monoid)
IDENTITY := object (identity element of the monoid)
ORDER := nil | strict comparison operator on the monoid
SUM-TYPE := nil | type specifier
Defines no structure; BIT is just a vector. This macro defines the three
functions: <NAME>-UPDATE!, point-update function, <NAME>-FOLD, query function for
prefix sum, and COERCE-TO-<NAME>!, constructor. If ORDER is specified, this
macro in addition defines <NAME>-BISECT-LEFT and <NAME>-BISECT-RIGHT, the
bisection functions for prefix sums. (Note that these functions work only when
the sequence of prefix sums (VECTOR[0], VECTOR[0]+VECTOR[1], ...) is monotone.)
SUM-TYPE is used only for the type declaration: each sum
VECTOR[i]+VECTOR[i+1]...+VECTOR[i+k] is declared to be this type. When SUM-TYPE
is NIL, type declaration is omitted. (The array-element-type of vector itself
doesn't need to be identical to SUM-TYPE.)"
(let* ((name (string name))
(fname-update (intern (format nil "~A-UPDATE!" name)))
(fname-fold (intern (format nil "~A-FOLD" name)))
(fname-coerce (intern (format nil "COERCE-TO-~A!" name)))
(fname-bisect-left (intern (format nil "~A-BISECT-LEFT" name)))
(fname-bisect-right (intern (format nil "~A-BISECT-RIGHT" name))))
`(progn
(declaim (inline ,fname-update))
(defun ,fname-update (bitree index delta)
"Destructively increments the vector: vector[INDEX] = vector[INDEX] +
DELTA"
(let ((len (length bitree)))
(do ((i index (logior i (+ i 1))))
((>= i len) bitree)
(declare ((integer 0 #.most-positive-fixnum) i))
(setf (aref bitree i)
(funcall ,operator (aref bitree i) delta)))))
(declaim (inline ,fname-fold))
(defun ,fname-fold (bitree end)
"Returns the sum of the prefix: vector[0] + ... + vector[END-1]."
(declare ((integer 0 #.most-positive-fixnum) end))
(let ((res ,identity))
,@(when sum-type `((declare (type ,sum-type res))))
(do ((i (- end 1) (- (logand i (+ i 1)) 1)))
((< i 0) res)
(declare ((integer -1 #.most-positive-fixnum) i))
(setf res (funcall ,operator res (aref bitree i))))))
(declaim (inline ,fname-coerce))
(defun ,fname-coerce (vector)
"Destructively constructs BIT from VECTOR. (You doesn't need to call
this constructor if what you need is a `zero-filled' BIT, because a vector
filled with the identity element is a valid BIT as it is.)"
(loop with len = (length vector)
for i below len
for dest-i = (logior i (+ i 1))
when (< dest-i len)
do (setf (aref vector dest-i)
(funcall ,operator (aref vector dest-i) (aref vector i)))
finally (return vector)))
,@(when order
`((declaim (inline ,fname-bisect-left))
(defun ,fname-bisect-left (bitree value)
"Returns the smallest index that satisfies VECTOR[0]+ ... +
VECTOR[index] >= VALUE. Returns the length of VECTOR if VECTOR[0]+
... +VECTOR[length-1] < VALUE. Note that this function deals with a **closed**
interval."
(declare (vector bitree))
(if (not (funcall ,order ,identity value))
0
(let ((len (length bitree))
(index+1 0)
(cumul ,identity))
(declare ((integer 0 #.most-positive-fixnum) index+1)
,@(when sum-type
`((type ,sum-type cumul))))
(do ((delta (ash 1 (- (integer-length len) 1))
(ash delta -1)))
((zerop delta) index+1)
(declare ((integer 0 #.most-positive-fixnum) delta))
(let ((next-index (+ index+1 delta -1)))
(when (< next-index len)
(let ((next-cumul (funcall ,operator cumul (aref bitree next-index))))
,@(when sum-type
`((declare (type ,sum-type next-cumul))))
(when (funcall ,order next-cumul value)
(setf cumul next-cumul)
(incf index+1 delta)))))))))
(declaim (inline ,fname-bisect-right))
(defun ,fname-bisect-right (bitree value)
"Returns the smallest index that satisfies VECTOR[0]+ ... +
VECTOR[index] > VALUE. Returns the length of VECTOR if VECTOR[0]+
... +VECTOR[length-1] <= VALUE. Note that this function deals with a **closed**
interval."
(declare (vector bitree))
(if (funcall ,order value ,identity)
0
(let ((len (length bitree))
(index+1 0)
(cumul ,identity))
(declare ((integer 0 #.most-positive-fixnum) index+1)
,@(when sum-type
`((type ,sum-type cumul))))
(do ((delta (ash 1 (- (integer-length len) 1))
(ash delta -1)))
((zerop delta) index+1)
(declare ((integer 0 #.most-positive-fixnum) delta))
(let ((next-index (+ index+1 delta -1)))
(when (< next-index len)
(let ((next-cumul (funcall ,operator cumul (aref bitree next-index))))
,@(when sum-type
`((declare (type ,sum-type next-cumul))))
(unless (funcall ,order value next-cumul)
(setf cumul next-cumul)
(incf index+1 delta))))))))))))))
#|
(define-bitree bitree
:operator #'+
:identity 0
:sum-type fixnum
:order #'<)
;|# ;
;; Example: compute the number of inversions in a sequence
#|
(declaim (inline make-inverse-lookup-table))
(defun make-inverse-lookup-table (vector &key (test #'eql))
"Assigns each value of the (usually sorted) VECTOR of length n to the integers
0, ..., n-1."
(let ((table (make-hash-table :test test :size (length vector))))
(dotimes (i (length vector) table)
(setf (gethash (aref vector i) table) i))))
(defun count-inversions (vector &key (order #'<))
(declare (vector vector))
(let* ((len (length vector))
(inv-lookup-table (make-inverse-lookup-table (sort (copy-seq vector) order)))
(bitree (make-array len :element-type '(integer 0 #.most-positive-fixnum)))
(inversion-number 0))
(declare (integer inversion-number))
(loop for j below len
for element = (aref vector j)
for compressed = (gethash element inv-lookup-table)
for delta of-type integer = (- j (bitree-fold bitree (1+ compressed)))
do (incf inversion-number delta)
(bitree-update! bitree compressed 1))
inversion-number))
(progn
(assert (= 3 (count-inversions #(2 4 1 3 5))))
(assert (zerop (count-inversions #(0))))
(assert (zerop (count-inversions #())))
(assert (zerop (count-inversions #(1 2))))
(assert (= 1 (count-inversions #(2 1)))))
;|#
;; BEGIN_USE_PACKAGE
(eval-when (:compile-toplevel :load-toplevel :execute)
(use-package :cp/abstract-bit :cl-user))
(eval-when (:compile-toplevel :load-toplevel :execute)
(use-package :cp/modify-macro :cl-user))
(eval-when (:compile-toplevel :load-toplevel :execute)
(use-package :cp/inverse-table :cl-user))
(eval-when (:compile-toplevel :load-toplevel :execute)
(use-package :cp/read-fixnum :cl-user))
(in-package :cl-user)
;;;
;;; Body
;;;
(define-bitree bitree
:operator #'max
:identity 0
:sum-type fixnum)
(declaim (ftype (function * (values (simple-array uint31 (*)) &optional)) calc-lis))
(defun calc-lis (as)
(declare #.opt
((simple-array uint31 (*)) as))
(let* ((n (length as))
(dp (make-array n :element-type 'uint31 :initial-element 0))
(res (make-array n :element-type 'uint31 :initial-element 0)))
(dotimes (i n)
(let* ((a (aref as i))
(max (bitree-fold dp a)))
(setf (aref res i) (+ max 1))
(bitree-update! dp a (+ max 1))))
res))
(defun main ()
(declare #.cl-user::opt)
(let* ((n (read))
(as (make-array n :element-type 'uint31 :initial-element 0)))
(dotimes (i n)
(setf (aref as i) (read-fixnum)))
(let ((inv-table (make-monotone-inverse-table! (copy-seq as) :test #'eq)))
(dotimes (i n)
(setf (aref as i) (gethash (aref as i) inv-table)))
(let ((max-a (reduce #'max as))
(lis-left (calc-lis as))
(lis-right (nreverse (calc-lis (reverse as)))))
(declare (uint31 max-a))
(dotimes (i n)
(setf (aref as i) (- max-a (aref as i))))
(let ((lds-left (calc-lis as))
(lds-right (nreverse (calc-lis (reverse as))))
(res 0))
(declare (uint31 res))
(loop for l across lis-left
for r across lis-right
do (maxf res (- (min l r) 1)))
(loop for l across lds-left
for r across lds-right
do (maxf res (- (min l r) 1)))
(println res))))))
#-swank (main)
;;;
;;; Test and benchmark
;;;
#+swank
(defun get-clipbrd ()
(with-output-to-string (out)
#+os-windows (run-program "powershell.exe" '("-Command" "Get-Clipboard") :output out :search t)
#+os-unix (run-program "xsel" '("-b" "-o") :output out :search t)))
#+swank (defparameter *this-pathname* (uiop:current-lisp-file-pathname))
#+swank (defparameter *dat-pathname* (uiop:merge-pathnames* "test.dat" *this-pathname*))
#+swank
(defun run (&optional thing (out *standard-output*))
"THING := null | string | symbol | pathname
null: run #'MAIN using the text on clipboard as input.
string: run #'MAIN using the string as input.
symbol: alias of FIVEAM:RUN!.
pathname: run #'MAIN using the text file as input."
(let* ((*standard-output* (or out (make-string-output-stream)))
(res (etypecase thing
(null
(with-input-from-string (*standard-input* (delete #\Return (get-clipbrd)))
(main)))
(string
(with-input-from-string (*standard-input* (delete #\Return thing))
(main)))
(symbol (5am:run! thing))
(pathname
(with-open-file (*standard-input* thing)
(main))))))
(if out res (get-output-stream-string *standard-output*))))
#+swank
(defun gen-dat ()
(uiop:with-output-file (out *dat-pathname* :if-exists :supersede)
(format out "")))
#+swank
(defun bench (&optional (out (make-broadcast-stream)))
(time (run *dat-pathname* out)))
;; To run: (5am:run! :sample)
#+swank
(it.bese.fiveam:test :sample
(it.bese.fiveam:is
(equal "1
"
(run "3
1 3 2
" nil)))
(it.bese.fiveam:is
(equal "0
"
(run "1
1
" nil)))
(it.bese.fiveam:is
(equal "2
"
(run "6
5 3 1 2 4 2
" nil))))