結果

問題 No.14 最小公倍数ソート
コンテスト
ユーザー te-sh
提出日時 2020-01-24 18:44:49
言語 D
(dmd 2.109.1)
結果
WA  
実行時間 -
コード長 4,758 bytes
コンパイル時間 2,005 ms
コンパイル使用メモリ 182,536 KB
実行使用メモリ 11,340 KB
最終ジャッジ日時 2024-06-22 04:26:20
合計ジャッジ時間 4,130 ms
ジャッジサーバーID
（参考情報） 		judge2 / judge5
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
other AC * 3 WA * 17
権限があれば一括ダウンロードができます
コンパイルメッセージ
/home/linuxbrew/.linuxbrew/opt/dmd/include/dlang/dmd/std/numeric.d(2999): Warning: cannot inline function `std.numeric.gcdImpl!uint.gcdImpl`

ソースコード

diff #
raw source code 

// URL: https://yukicoder.me/problems/no/14

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;
import std.numeric;

version(unittest) {} else
void main()
{
  int N; io.getV(N);
  int[] a; io.getA(N, a);
  auto ma = a.maxElement;

  auto primes = Prime(ma.isqrt);
  auto b = new int[][](ma+1);
  auto c = (ma+1).iota.map!(_ => redBlackTree!true(cast(int[])[])).array;
  foreach (ai; a) {
    auto d = primes.divisors(ai);
    if (b[ai].empty) b[ai] = d;
    foreach (di; d) c[di].insert(ai);
  }

  auto ai = a[0], r = cast(int[])[];
  foreach (i; 0..N-1) {
    r ~= ai;
    foreach (di; b[ai]) c[di].removeKey(ai);
    auto e = c.indexed(b[ai]).
      map!(ci => ci.empty ? -1 : ci.front).
      filter!"a>0".
      minElement!(ei => lcm(ai, ei));
    ai = e;
  }

  io.put(r, ai);
}

pure T lcm(T)(T a, T b) { return a/gcd(a, b)*b; }

pure T isqrt(T)(T n)
{
  static if (is(T == int)) auto max = 46341;
  else static if (is(T == long)) auto max = 3037000500L;
  auto bs = iota(T(0), max).map!(x => tuple(x, x^^2)).assumeSorted!"a[1]<=b[1]";
  return bs.lowerBound(tuple(0, n)).back[0];
}

pure T icbrt(T)(T n)
{
  static if (is(T == int)) auto max = 1291;
  else static if (is(T == long)) auto max = 2097152L;
  auto bs = iota(T(0), max).map!(x => tuple(x, x^^3)).assumeSorted!"a[1]<=b[1]";
  return bs.lowerBound(tuple(0, n)).back[0];
}

pure T powr(alias pred = "a*b", T, U)(T a, U n, T one)
{
  import std.functional;
  alias predFun = binaryFun!pred;
  if (n == 0) return one;
  auto r = one;
  for (; n > 0; n >>= 1) { if (n&1) r = predFun(r, a); a = predFun(a, a); }
  return r;
}
pure T powr(alias pred = "a*b", T, U)(T a, U n) { return powr!(pred, T, U)(a, n, T(1)); }

pure T extGcd(T)(T a, T b, out T x, out T y)
{
  auto g = a; x = 1; y = 0;
  if (b) { g = extGcd(b, a%b, y, x); y -= a/b*x; }
  return g;
}

struct Prime
{
  import std.bitmanip;
  struct Factor { int prime, exp; }

  const int n;
  @property array() { return primes; }
  alias array this;

  this(int n)
  {
    this.n = n;

    auto sieve = BitArray();
    sieve.length((n+1)/2);
    sieve = ~sieve;

    foreach (p; 1..(n.isqrt-1)/2+1)
      if (sieve[p])
        for (auto q = p*3+1; q < (n+1)/2; q += p*2+1)
          sieve[q] = false;

    primes = sieve.bitsSet.map!(p => cast(int)p*2+1).array;
    primes[0] = 2;
  }

  pure Factor[] div(int x) in { assert(x > 0 && x.isqrt <= n); } do
  {
    Factor[] factors;
    auto t = isqrt(x);
    foreach (p; primes) {
      if (p > t) break;
      auto c = 0;
      for (; x%p == 0; x /= p) ++c;
      if (c > 0) factors ~= Factor(p, c);
      if (x == 1) break;
    }
    if (x > 1) factors ~= [Factor(x, 1)];
    return factors;
  }

  pure int[] divisors(int x) in { assert(x > 0 && x.isqrt <= n); } do
  {
    auto factors = div(x);
    auto r = divisorsProc(factors, 0, 1);
    r.sort();
    return r;
  }

  private
  {
    int[] primes;

    pure int[] divisorsProc(Factor[] factors, int i, int c)
    {
      if (i == factors.length) return [c];
      int[] r;
      foreach (j; 0..factors[i].exp+1)
        r ~= divisorsProc(factors, i+1, c*factors[i].prime^^j);
      return r;
    }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(string floatFormat = "%.10f", string delimiter = " ", alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits;
  alias assignable = hasAssignableElements;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (assignable!T) { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v) if (allSatisfy!(assignable, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v) if (assignable!T && assignable!(ElementType!T))
  {
    v = new T(r); foreach (ref w; v) getA(c, w);
  }

  auto put(bool flush = false, T...)(T v)
  {
    foreach (i, w; v) { putA(w); if (i < v.length-1) OUT.write(delimiter); }
    OUT.writeln;
    static if (flush) OUT.flush();
  }
  auto putB(S, T)(bool c, S t, T f) { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putR(T)(T v)
    {
      auto w = v;
      while (!w.empty) { putA(w.front); w.popFront(); if (!w.empty) OUT.write(delimiter); }
    }
    auto putA(T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putR(v);
      else if (isFloatingPoint!T) OUT.write(format(floatFormat, v));
      else OUT.write(v);
    }
  }
}
0