結果

問題 No.738 平らな農地
ユーザー te-sh
提出日時 2020-01-29 16:43:51
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 190 ms / 2,000 ms
コード長 4,248 bytes
コンパイル時間 1,803 ms
コンパイル使用メモリ 159,456 KB
実行使用メモリ 15,172 KB
最終ジャッジ日時 2024-06-22 04:45:47
合計ジャッジ時間 9,695 ms
ジャッジサーバーID
（参考情報） 		judge1 / judge4
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 5
other AC * 87
権限があれば一括ダウンロードができます

ソースコード

diff # 

// URL: https://yukicoder.me/problems/no/738

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int N, K; io.getV(N, K);
  int[] A; io.getA(N, A);

  auto za = Zaatsu!int(A);
  auto c = za.comp(A).array;

  auto fc = fenwickTree!int(za.n), fs = fenwickTree!long(za.n);
  foreach (i; 0..K) {
    fc[c[i]] += 1;
    fs[c[i]] += za.uncomp(c[i]);
  }

  auto ans = 10L^^18;
  foreach (i; 0..N-K+1) {
    auto s = iota(0, za.n).map!(j => fc[0..j]).assumeSorted;
    if (K%2 == 0) {
      auto j1 = cast(int)s.lowerBound(K/2).length-1, j2 = cast(int)s.lowerBound(K/2+1).length-1;
      auto f1 = fs[j2..$]-cast(long)za.uncomp(j2)*(fc[j2..$]-K/2);
      auto f2 = fs[0..j1+1]-cast(long)za.uncomp(j1)*(fc[0..j1+1]-K/2);
      ans = min(ans, f1-f2);
    } else {
      auto j = cast(int)s.lowerBound(K/2+1).length-1;
      auto f1 = fs[j..$]-cast(long)za.uncomp(j)*(fc[j..$]-K/2);
      auto f2 = fs[0..j+1]-cast(long)za.uncomp(j)*(fc[0..j+1]-K/2);
      ans = min(ans, f1-f2);
    }

    if (i < N-K) {
      fc[c[i]] -= 1;
      fs[c[i]] -= za.uncomp(c[i]);
      fc[c[i+K]] += 1;
      fs[c[i+K]] += za.uncomp(c[i+K]);
    }
  }

  io.put(ans);
}

struct Zaatsu(T)
{
  const size_t n;

  this(U...)(U v)
  {
    T[] d;
    foreach (w; v) d ~= w.array;
    auto u = d.sort.uniq;
    n = u.walkLength;
    c2 = new T[](n);

    foreach (i, ui; u.enumerate(0)) {
      c1[ui] = i;
      c2[i] = ui;
    }
  }

  int comp(T v) { return c1[v]; }
  auto comp(R)(R v) if (isInputRange!R) { return v.map!(w => c1[w]); }

  T uncomp(int v) { return c2[v]; }
  auto uncomp(R)(R v) if (isInputRange!R) { return v.map!(w => c2[w]); }

  private
  {
    int[T] c1;
    T[] c2;
  }
}

class FenwickTree(T)
{
  const size_t n;

  this(size_t n) { this.n = n; this.buf = new T[](n+1); }

  void opIndexOpAssign(string op)(T val, size_t i) if (op=="+"||op=="-")
  { ++i; for (; i <= n; i += i&-i) mixin("buf[i]"~op~"=val;"); }

  void opIndexUnary(string op)(size_t i) if (op=="++"||op=="--")
  { ++i; for (; i <= n; i += i&-i) mixin(op~"buf[i];"); }

  pure T opIndex(size_t i) { return opSlice(i, i+1); }
  pure T opSlice(size_t r, size_t l) { return get(l) - get(r); }
  pure size_t opDollar() { return n; }

  private
  {
    T[] buf;

    pure T get(size_t i)
    {
      auto s = T(0);
      for (; i > 0; i -= i & -i) s += buf[i];
      return s;
    }
  }
}
FenwickTree!T fenwickTree(T)(size_t n) { return new FenwickTree!T(n); }

auto io = IO!()();
import std.stdio;
struct IO(string floatFormat = "%.10f", string delimiter = " ", alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r); foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    {
      v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  auto put(bool flush = false, T...)(T v)
  {
    foreach (i, w; v) { putA(w); if (i < v.length-1) OUT.write(delimiter); }
    OUT.writeln;
    static if (flush) OUT.flush();
  }
  auto putB(S, T)(bool c, S t, T f) { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putR(T)(T v)
    {
      auto w = v;
      while (!w.empty) { putA(w.front); w.popFront(); if (!w.empty) OUT.write(delimiter); }
    }
    auto putA(T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putR(v);
      else if (isFloatingPoint!T) OUT.write(format(floatFormat, v));
      else OUT.write(v);
    }
  }
}
0