#429437 (D) No.13 囲みたい！

• 問題: No.13 囲みたい！
• ユーザー: te-sh
• 提出日時: 2020-02-14 21:04:16
• 言語: D (dmd 2.106.1)
• 結果: AC
• 実行時間: 13 ms / 5,000 ms
• コード長: 5,789 bytes
• コンパイル時間: 1,994 ms
• コンパイル使用メモリ: 162,424 KB
• 実行使用メモリ: 6,944 KB
• 最終ジャッジ日時: 2024-06-22 05:04:59
• 合計ジャッジ時間: 2,108 ms
• ジャッジサーバーID （参考情報）: judge2 / judge4

入力	結果	実行時間; 実行使用メモリ
testcase_00	AC	1 ms; 6,816 KB
testcase_01	AC	1 ms; 6,940 KB
testcase_02	AC	1 ms; 6,940 KB
testcase_03	AC	7 ms; 6,940 KB
testcase_04	AC	2 ms; 6,940 KB
testcase_05	AC	11 ms; 6,940 KB
testcase_06	AC	2 ms; 6,940 KB
testcase_07	AC	12 ms; 6,940 KB
testcase_08	AC	13 ms; 6,944 KB
testcase_09	AC	11 ms; 6,944 KB
testcase_10	AC	4 ms; 6,944 KB
testcase_11	AC	9 ms; 6,940 KB
testcase_12	AC	2 ms; 6,940 KB
testcase_13	AC	4 ms; 6,944 KB
testcase_14	AC	5 ms; 6,940 KB
testcase_15	AC	1 ms; 6,940 KB

コンパイルメッセージ

Main.d(153): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{exit: true}", string).put.putMain!(c, string).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-141(141):        instantiated from here: `putMain!(c, string)`
Main.d(31):        instantiated from here: `put!("{exit: true}", string)`
Main.d(153): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", string).put.putMain!(c, string).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-141(141):        instantiated from here: `putMain!(c, string)`
Main.d(33):        instantiated from here: `put!("{}", string)`

ソースコード

// URL: https://yukicoder.me/problems/no/13

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int W, H; io.getV(W, H);
  int[][] M; io.getM(H, W, M);

  auto g = grid(M), v = grid!bool(H, W);
  alias Pos = g.Pos;

  auto hasCycle(Pos p)
  {
    struct Pos2 { Pos curr, prev; }
    auto q = DList!Pos2(Pos2(p, p)); v[p] = true;

    while (!q.empty) {
      auto e = q.front; q.removeFront();
      foreach (d; e.curr.around4.filter!(d => d != e.prev && g[d] == g[p])) {
	if (v[d]) return true;
	q.insertBack(Pos2(d, e.curr)); v[d] = true;
      }
    }

    return false;
  }

  foreach (p; g.walk)
    if (!v[p] && hasCycle(p)) io.put!"{exit: true}"("possible");

  io.put("impossible");
}

class Grid(T)
{
  import std.format, std.traits;

  class Pos
  {
    int r, c;
    this(int r, int c) { this.r = r; this.c = c; }
    pure override string toString() { return format("(%d, %d)", r, c); }
    pure override bool opEquals(Object q) { return r == (cast(Pos)q).r && c == (cast(Pos)q).c; }
    pure bool inGrid() { return 0 <= r && r < h && 0 <= c && c < w; }
    pure int p2i() { return cast(int)w*r+c; }

    pure Pos opBinary(string op, U)(U q) if (op=="+"||op=="-")
    { return mixin("pos(r"~op~"q.r, c"~op~"q.c)"); }
    Pos opOpAssign(string op, U)(U q) if (op=="+"||op=="-")
    { mixin("r"~op~"=q.r; c"~op~"=q.c;"); return this; }
    pure Pos opBinary(string op, U)(U a) if ((op=="*"||op=="/") && isNumeric!U)
    { return mixin("pos(r"~op~"a, c"~op~"a)"); }
    Pos opOpAssign(string op, U)(U a) if ((op=="*"||op=="/") && isNumeric!U)
    { mixin("r"~op~"=a; c"~op~"=a;"); return this; }
    pure int opBinary(string op: "*", U)(U q) if (!isNumeric!U)
    { return r*q.r+c*q.c; }

    pure auto around4() { return d4.map!(d => this+d).filter!(p => p.inGrid); }
    pure auto around8() { return d8.map!(d => this+d).filter!(p => p.inGrid); }
  }

  size_t h, w;
  T[][] data;

  this(size_t h, size_t w) { this.h = h; this.w = w; data = new T[][](h, w); }
  this(T[][] data) { h = data.length; w = data[0].length; this.data = data; }
  pure Grid!T dup() { return new Grid!T(data.map!"a.dup".array); }

  pure Pos pos(int r, int c) { return new Pos(r, c); }

  pure T opIndex(size_t r, size_t c) { return data[r][c]; }
  pure T opIndex(U)(U p) { return data[p.r][p.c]; }
  Grid!T opIndexAssign(T v, size_t r, size_t c) { data[r][c] = v; return this; }
  Grid!T opIndexAssign(U)(T v, U p) { data[p.r][p.c] = v; return this; }
  Grid!T opIndexOpAssign(string op)(T v, size_t r, size_t c)
  { mixin("data[r][c]"~op~"=v;"); return this; }
  Grid!T opIndexOpAssign(string op, U)(T v, U p)
  { mixin("data[p.r][p.c]"~op~"=v;"); return this; }
  Grid!T opIndexUnary(string op)(size_t r, size_t c) if (op=="++"||op=="--")
  { mixin(op~"data[r][c];"); return this; }
  Grid!T opIndexUnary(string op, U)(U p) if (op=="++"||op=="--")
  { mixin(op~"data[p.r][p.c];"); return this; }

  auto walk()
  { return WalkRange(this); }
  auto d4 = [D(-1, 0), D(0, -1), D(1, 0), D(0, 1)];
  auto d8 = [D(-1, 0), D(-1, -1), D(0, -1), D(1, -1), D(1, 0), D(1, 1), D(0, 1), D(-1, 1)];

  private
  {
    struct D { int r, c; }
    struct WalkRange
    {
      Grid!T g;
      int r, c;
      this(Grid!T g) { this.g = g; r = 0; c = 0; }
      @property pure Pos front() { return g.pos(r, c); }
      void popFront() { if (++c >= g.w) { c = 0; ++r; } }
      pure bool empty() { return r >= g.h; }
    }
  }
}
Grid!T grid(T)(size_t h, size_t w) { return new Grid!T(h, w); }
Grid!T grid(T)(T[][] data) { return new Grid!T(data); }

pure int distManhattan(T)(T p1, T p2) { return abs(p1.r-p2.r) + abs(p1.c-p2.c); }

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits, core.stdc.stdlib;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  { v = new T(r); foreach (ref w; v) getA(c, w); }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    { v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");"); }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  auto put(alias conf = "{}", T...)(T v)
  { mixin("const PutConf c = "~conf~"; putMain!c(v);"); }
  auto putB(alias conf = "{}", S, T)(bool c, S t, T f)
  { if (c) put!conf(t); else put!conf(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i < v.length-1) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    auto putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else OUT.write(v);
    }
    auto putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}