#429836 (D) No.157 2つの空洞

提出ソース

結果

問題	No.157 2つの空洞
ユーザー	te-sh
提出日時	2020-02-14 21:46:55
言語	D (dmd 2.106.1)
結果	AC
実行時間	1 ms / 2,000 ms
コード長	7,373 bytes
コンパイル時間	1,406 ms
コンパイル使用メモリ	157,216 KB
実行使用メモリ	6,948 KB
最終ジャッジ日時	2024-06-22 05:08:49
合計ジャッジ時間	2,051 ms
ジャッジサーバーID （参考情報）	judge4 / judge3

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	1 ms 6,812 KB
testcase_01	AC	1 ms 6,944 KB
testcase_02	AC	1 ms 6,944 KB
testcase_03	AC	1 ms 6,940 KB
testcase_04	AC	1 ms 6,940 KB
testcase_05	AC	1 ms 6,948 KB
testcase_06	AC	1 ms 6,940 KB
testcase_07	AC	1 ms 6,944 KB
testcase_08	AC	1 ms 6,940 KB
testcase_09	AC	1 ms 6,940 KB
testcase_10	AC	1 ms 6,940 KB
testcase_11	AC	1 ms 6,940 KB
testcase_12	AC	1 ms 6,944 KB
testcase_13	AC	1 ms 6,944 KB
testcase_14	AC	1 ms 6,944 KB
testcase_15	AC	1 ms 6,944 KB
testcase_16	AC	1 ms 6,940 KB
testcase_17	AC	1 ms 6,944 KB
testcase_18	AC	1 ms 6,940 KB
testcase_19	AC	1 ms 6,944 KB

権限があれば一括ダウンロードができます

コンパイルメッセージ

Main.d(204): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", int).put.putMain!(c, int).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-192(192):        instantiated from here: `putMain!(c, int)`
Main.d(40):        instantiated from here: `put!("{}", int)`

ソースコード

raw source code

// URL: https://yukicoder.me/problems/no/157

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int W, H; io.getV(W, H);
  string[] C; io.getC(H, C);

  auto c = grid(cast(char[][])C), b = grid!bool(H, W);

  auto findSpace()
  {
    foreach (p; c.walk)
      if (c[p] == '.' && !b[p]) {
        auto r = [p];
        b[p] = true;
        auto q = DList!(c.Pos)(p);
        while (!q.empty) {
          auto u = q.front; q.removeFront();
          foreach (v; u.around4) {
            if (c[v] == '.' && !b[v]) {
              r ~= v;
              b[v] = true;
              q.insertBack(v);
            }
          }
        }
        return r;
      }
    assert(0);
  }

  auto s1 = findSpace(), s2 = findSpace(), r = 1000;
  foreach (p1; s1)
    foreach (p2; s2)
      r = min(r, distManhattan(p1, p2));

  io.put(r-1);
}

struct Point2(T)
{
  alias P = Point2!T, Op = string;
  T x, y;
  pure P opBinary(Op o)(P r) if (o=="+"||o=="-")
  { return mixin("P(x"~o~"r.x, y"~o~"r.y)"); }
  P opOpAssign(Op o)(P r) if (o=="+"||o=="-")
  { mixin("x"~o~"=r.x; y"~o~"=r.y;"); return this; }
  pure P opBinary(Op o)(T a) if (o=="*"||o=="/")
  { return mixin("P(x"~o~"a, y"~o~"a)"); }
  P opOpAssign(Op o)(T a) if (o=="*"||o=="/")
  { mixin("x"~o~"=a; y"~o~"=a;"); return this; }
  pure T opBinary(Op o: "*")(P r) { return x*r.x+y*r.y; }
  pure T hypot2() { return x^^2+y^^2; }
}

pure T distManhattan(T)(Point2!T p1, Point2!T p2)
{ return (p1.x-p2.x).abs + (p1.y-p2.y).abs; }

pure T cross(T)(Point2!T p1, Point2!T p2)
{ return p1.x*p2.y - p1.y*p2.x; }

struct Point3(T)
{
  alias P = Point3!T, Op = string;
  T x, y, z;
  pure P opBinary(Op o)(P r) if (o=="+"||o=="-")
  { return mixin("P(x"~o~"r.x, y"~o~"r.y, z"~o~"r.z)"); }
  P opOpAssign(Op o)(P r) if (o=="+"||o=="-")
  { mixin("x"~o~"=r.x; y"~o~"=r.y; z"~o~"=r.z;"); return this; }
  pure P opBinary(Op o)(T a) if (o=="*"||o=="/")
  { return mixin("P(x"~o~"a, y"~o~"a, z"~o~"a)"); }
  P opOpAssign(Op o)(T a) if (o=="*"||o=="/")
  { mixin("x"~o~"=a; y"~o~"=a; z"~o~"=a;"); return this; }
  pure T opBinary(Op o: "*")(P r) { return x*r.x+y*r.y+z*r.z; }
  pure T hypot2() { return x^^2+y^^2+z^^2; }
}

pure Point3!T cross(T)(Point3!T p1, Point3!T p2)
{ return Point3!T(p1.y*p2.z - p1.z*p2.y, p1.z*p2.x - p1.x*p2.z, p1.x*p2.y - p1.y*p2.x); }

class Grid(T)
{
  import std.format, std.traits;

  class Pos
  {
    int r, c;
    this(int r, int c) { this.r = r; this.c = c; }
    pure override string toString() { return format("(%d, %d)", r, c); }
    pure override bool opEquals(Object q) { return r == (cast(Pos)q).r && c == (cast(Pos)q).c; }
    pure bool inGrid() { return 0 <= r && r < h && 0 <= c && c < w; }
    pure int p2i() { return cast(int)w*r+c; }

    pure Pos opBinary(string op, U)(U q) if (op=="+"||op=="-")
    { return mixin("pos(r"~op~"q.r, c"~op~"q.c)"); }
    Pos opOpAssign(string op, U)(U q) if (op=="+"||op=="-")
    { mixin("r"~op~"=q.r; c"~op~"=q.c;"); return this; }
    pure Pos opBinary(string op, U)(U a) if ((op=="*"||op=="/") && isNumeric!U)
    { return mixin("pos(r"~op~"a, c"~op~"a)"); }
    Pos opOpAssign(string op, U)(U a) if ((op=="*"||op=="/") && isNumeric!U)
    { mixin("r"~op~"=a; c"~op~"=a;"); return this; }
    pure int opBinary(string op: "*", U)(U q) if (!isNumeric!U)
    { return r*q.r+c*q.c; }

    pure auto around4()
    {
      return [pos(r-1, c), pos(r, c+1), pos(r+1, c), pos(r, c-1)]
        .filter!(p => p.inGrid);
    }
    pure auto around8()
    {
      return [pos(r-1, c), pos(r-1, c+1), pos(r, c+1), pos(r+1, c+1),
              pos(r+1, c), pos(r+1, c-1), pos(r, c-1), pos(r-1, c-1)]
        .filter!(p => p.inGrid);
    }
  }

  size_t h, w;
  T[][] data;

  this(size_t h, size_t w) { this.h = h; this.w = w; data = new T[][](h, w); }
  this(T[][] data) { h = data.length; w = data[0].length; this.data = data; }
  pure Grid!T dup() { return new Grid!T(data.map!"a.dup".array); }

  pure Pos pos(int r, int c) { return new Pos(r, c); }

  pure T opIndex(size_t r, size_t c) { return data[r][c]; }
  pure T opIndex(U)(U p) { return data[p.r][p.c]; }
  Grid!T opIndexAssign(T v, size_t r, size_t c) { data[r][c] = v; return this; }
  Grid!T opIndexAssign(U)(T v, U p) { data[p.r][p.c] = v; return this; }
  Grid!T opIndexOpAssign(string op)(T v, size_t r, size_t c)
  { mixin("data[r][c]"~op~"=v;"); return this; }
  Grid!T opIndexOpAssign(string op, U)(T v, U p)
  { mixin("data[p.r][p.c]"~op~"=v;"); return this; }
  Grid!T opIndexUnary(string op)(size_t r, size_t c) if (op=="++"||op=="--")
  { mixin(op~"data[r][c];"); return this; }
  Grid!T opIndexUnary(string op, U)(U p) if (op=="++"||op=="--")
  { mixin(op~"data[p.r][p.c];"); return this; }

  auto walk()
  { return WalkRange(this); }

  private struct WalkRange
  {
    Grid!T g;
    int r, c;
    this(Grid!T g) { this.g = g; r = 0; c = 0; }
    @property pure Pos front() { return g.pos(r, c); }
    void popFront() { if (++c >= g.w) { c = 0; ++r; } }
    pure bool empty() { return r >= g.h; }
  }
}
Grid!T grid(T)(size_t h, size_t w) { return new Grid!T(h, w); }
Grid!T grid(T)(T[][] data) { return new Grid!T(data); }

pure int distManhattan(T)(T p1, T p2) { return abs(p1.r-p2.r) + abs(p1.c-p2.c); }

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits, core.stdc.stdlib;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  { v = new T(r); foreach (ref w; v) getA(c, w); }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    { v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");"); }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  auto put(alias conf = "{}", T...)(T v)
  { mixin("const PutConf c = "~conf~"; putMain!c(v);"); }
  auto putB(alias conf = "{}", S, T)(bool c, S t, T f)
  { if (c) put!conf(t); else put!conf(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i < v.length-1) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    auto putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else OUT.write(v);
    }
    auto putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}