#432267 (D) No.151 セグメントフィッシング

• 問題: No.151 セグメントフィッシング
• ユーザー: te-sh
• 提出日時: 2020-02-21 17:12:23
• 言語: D (dmd 2.106.1)
• 結果: AC
• 実行時間: 26 ms / 5,000 ms
• コード長: 4,344 bytes
• コンパイル時間: 839 ms
• コンパイル使用メモリ: 108,288 KB
• 実行使用メモリ: 6,944 KB
• 最終ジャッジ日時: 2024-06-22 05:19:00
• 合計ジャッジ時間: 2,073 ms
• ジャッジサーバーID （参考情報）: judge4 / judge1

入力	結果	実行時間; 実行使用メモリ
testcase_00	AC	1 ms; 6,812 KB
testcase_01	AC	1 ms; 6,940 KB
testcase_02	AC	1 ms; 6,940 KB
testcase_03	AC	1 ms; 6,940 KB
testcase_04	AC	1 ms; 6,944 KB
testcase_05	AC	1 ms; 6,944 KB
testcase_06	AC	1 ms; 6,940 KB
testcase_07	AC	1 ms; 6,944 KB
testcase_08	AC	5 ms; 6,944 KB
testcase_09	AC	6 ms; 6,944 KB
testcase_10	AC	5 ms; 6,940 KB
testcase_11	AC	5 ms; 6,940 KB
testcase_12	AC	22 ms; 6,944 KB
testcase_13	AC	21 ms; 6,940 KB
testcase_14	AC	20 ms; 6,940 KB
testcase_15	AC	20 ms; 6,944 KB
testcase_16	AC	21 ms; 6,944 KB
testcase_17	AC	15 ms; 6,940 KB
testcase_18	AC	16 ms; 6,944 KB
testcase_19	AC	26 ms; 6,940 KB
testcase_20	AC	25 ms; 6,940 KB
testcase_21	AC	18 ms; 6,940 KB
testcase_22	AC	17 ms; 6,944 KB
testcase_23	AC	17 ms; 6,940 KB

コンパイルメッセージ

Main.d(186): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", long).put.putMain!(c, long).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-156(156):        instantiated from here: `putMain!(c, long)`
Main.d(27):        instantiated from here: `put!("{}", long)`

ソースコード

// URL: https://yukicoder.me/problems/no/151

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  int N, Q; io.getV(N, Q);

  auto n = N*2, ft = new FenwickTree!long(n);
  foreach (t; 0..Q) {
    string x; int y, z; io.getV(x, y, z);
    switch (x) {
    case "L":
      ft[(y+t)%n] += z;
      break;
    case "R":
      ft[(n-1-y+t)%n] += z;
      break;
    case "C":
      auto r = 0L;
      auto u1 = (y+t)%n, v1 = (z-1+t)%n+1;
      r += u1 < v1 ? ft[u1..v1] : ft[0..v1]+ft[u1..n];
      auto u2 = (n-y+t-1)%n+1, v2 = (n-z+t)%n;
      r += v2 < u2 ? ft[v2..u2] : ft[0..u2]+ft[v2..n];
      io.put(r);
      break;
    default:
      assert(0);
    }
  }
}

class FenwickTree(T)
{
  const size_t n;

  pure nothrow @safe
  {
    this(size_t n)
    {
      this.n = n;
      this.buf = new T[](n+1);
    }
  }

  pure nothrow @nogc @safe
  {
    void opIndexOpAssign(string op)(T val, size_t i)
      if (op == "+" || op == "-")
      in { assert(0 <= i && i < n); }
    do
    {
      ++i;
      for (; i <= n; i += i&-i) mixin("buf[i]"~op~"=val;");
    }

    void opIndexUnary(string op)(size_t i)
      if (op == "++" || op == "--")
      in { assert(0 <= i && i < n); }
    do
    {
      ++i;
      for (; i <= n; i += i&-i) mixin(op~"buf[i];");
    }

    T opIndex(size_t i) const
      in { assert(0 <= i && i < n); }
    do
    {
      return opSlice(i, i+1);
    }
    T opSlice(size_t l, size_t r) const
      in { assert(0 <= l && l <= r && r <= n); }
    do
    {
      return get(r) - get(l);
    }
    size_t opDollar() const
    {
      return n;
    }
  }

  private
  {
    T[] buf;

    pure nothrow @nogc @safe
    {
      T get(size_t i) const
      {
        auto s = T(0);
        for (; i > 0; i -= i & -i) s += buf[i];
        return s;
      }
    }
  }
}

pure nothrow @safe
{
  auto fenwickTree(T)(size_t n)
  {
    return new FenwickTree!T(n);
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}