#432348 (D) No.194 フィボナッチ数列の理解(1)

• 問題: No.194 フィボナッチ数列の理解(1)
• ユーザー: te-sh
• 提出日時: 2020-02-21 19:57:31
• 言語: D (dmd 2.109.1)
• 結果: CE (最新)
  AC
  (最初)
• 実行時間: -
• コード長: 13,538 bytes
• コンパイル時間: 468 ms
• コンパイル使用メモリ: 149,164 KB
• 最終ジャッジ日時: 2024-11-14 22:07:47
• 合計ジャッジ時間: 841 ms
• ジャッジサーバーID （参考情報）: judge3 / judge5

コンパイルメッセージ

Main.d(575): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", ModInt!(1000000007, false), ModInt!(1000000007, false)).put.putMain!(c, ModInt!(1000000007, false), ModInt!(1000000007, false)).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-545(545):        instantiated from here: `putMain!(c, ModInt!(1000000007, false), ModInt!(1000000007, false))`
Main.d(17):        instantiated from here: `put!("{}", ModInt!(1000000007, false), ModInt!(1000000007, false))`
/home/linuxbrew/.linuxbrew/opt/dmd/include/dlang/dmd/std/format/internal/write.d(143): Error: cannot implicitly convert expression `obj` of type `const(ModInt!(1000000007, false))` to `int`
/home/linuxbrew/.linuxbrew/opt/dmd/include/dlang/dmd/std/format/write.d(1239): Error: template instance `std.format.internal.write.formatValueImpl!(LockingTextWriter, ModInt!(1000000007, false), char)` error instantiating
/home/linuxbrew/.linuxbrew/opt/dmd/include/dlang/dmd/std/format/write.d(632):        instantiated from here: `formatValue!(LockingTextWriter, ModInt!(1000000007, false), char)`
/home/linuxbrew/.linuxbrew/opt/dmd/include/dlang/dmd/std/stdio.d(1759):        instantiated from here: `formattedWrite!(LockingTextWriter, char, ModInt!(1000000007, false))`
Main.d(590):        instantiated from here: `write!(ModInt!(1000000007, false))`
Main.d(578):        ... (1 instantiations, -v to show) ...
Main.d-mixin-545(545):        instantiated from here: `putMain!(c, ModInt!(1000000007, false), ModInt!(1000000007, false))`
Main.d(17):        instantiated from here: `put!("{}", ModInt!(1000000007, false), ModInt!(1000000007, false))`

ソースコード

// URL: https://yukicoder.me/problems/no/194

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  int N; long K; io.getV(N, K);
  int[] A; io.getA(N, A);

  if (K <= 10^^6) {
    auto f = new mint[](K);
    foreach (i, Ai; A) f[i] = Ai;
    f[N] = f[0..N].sum;
    foreach (i; N+1..K) f[i] = f[i-1]*2-f[i-N-1];
    io.put(f[$-1], f.sum);
  } else {
    auto m = Matrix!mint(N+1, N+1);
    foreach (i; 1..N) m[i-1][i] = 1;
    foreach (i; 0..N) { m[N-1][i] = 1; m[N][i] = 1; }
    m[N][N] = 1;
    auto v = Vector!mint(N+1);
    foreach (i, Ai; A) v[i] = Ai;
    v[N] = v[0..N].sum;
    auto r = m^^(K-N)*v;
    io.put(r[N-1], r[N]);
  }
}

pure nothrow @safe
{
  T powr(alias pred = "a*b", T, U)(const T a, U n, T one)
    if (isIntegral!U)
  {
    auto b = T(a);
    alias predFun = binaryFun!pred;
    if (n == 0) return one;
    auto r = one;
    for (; n > 0; n >>= 1) {
      if (n&1) r = predFun(r, b);
      b = predFun(b, b);
    }
    return r;
  }
  T powr(alias pred = "a*b", T, U)(const T a, U n)
    if (isIntegral!U)
  {
    return powr!(pred, T, U)(a, n, T(1));
  }
}

struct Vector(T)
{
  size_t n;
  @property T[] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    this(size_t n, T zero = T(0))
      in { assert(n > 0); }
    do
    {
      this.n = n; this.zero = zero;
      a = new T[](n);
      if (T.init != zero)
        foreach (i; 0..n) a[i] = zero;
    }
    this(U)(U[] b, T zero = T(0))
      in { assert(b.length > 0); }
    do
    {
      n = b.length; this.zero = zero;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[](n);
        foreach (i; 0..n) a[i] = b[i];
      }
    }
    this(ref return scope const Vector!T v)
    {
      n = v.n; zero = v.zero;
      a = new T[](n);
      foreach (i; 0..n) a[i] = v.a[i];
    }

    Vector!T dup() const
    {
      return Vector!T(this);
    }

    Vector!T opBinary(string op)(const Vector!T b) const
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = mixin("a[i]"~op~"b.a[i]");
      return x;
    }
    ref Vector!T opOpAssign(string op)(const Vector!T b)
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      foreach (i; 0..n) mixin("a[i]"~op~"=b.a[i];");
      return this;
    }
    Vector!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!T)
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = a[i]*b;
      return x;
    }
    ref Vector!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!T)
    {
      foreach (i; 0..n) a[i] *= b;
      return this;
    }
    T opBinary(string op: "*")(const Vector!T b) const
      in { assert(n == b.n); }
    do
    {
      auto x = T(zero);
      foreach (i; 0..n) x += a[i]*b.a[i];
      return x;
    }
  }

  private
  {
    T[] a;
    T zero;
  }
}

pure nothrow @safe
{
  auto vector(T)(T[] a, T zero = T(0))
  {
    return Vector!T(a, zero);
  }
  T hypot2(T)(const Vector!T a)
  {
    return a*a;
  }
  pure Vector!T cross(T)(Vector!T a, Vector!T b)
    in { assert(a.n == 3 && b.n == 3); }
  do
  {
    return Vector!T([a[1]*b[2]-a[2]*b[1], a[2]*b[0]-a[0]*b[2], a[0]*b[1]-a[1]*b[0]], a.zero);
  }
}

struct Matrix(T)
{
  size_t r, c;
  @property T[][] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    static Matrix!T unit(size_t n, T zero = T(0), T one = T(1))
      in { assert(n > 0); }
    do
    {
      auto r = Matrix!T(n, n, zero, one);
      foreach (i; 0..n) r[i][i] = one;
      return r;
    }

    this(size_t r, size_t c, T zero = T(0), T one = T(1))
      in { assert(r > 0 && c > 0); }
    do
    {
      this.r = r; this.c = c; this.zero = zero; this.one = one;
      a = new T[][](r, c);
      if (T.init != zero)
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = zero;
    }
    this(U)(U[][] b, T zero = T(0), T one = T(1))
      in { assert(b.length > 0 && b[0].length > 0 && b.all!(l => l.length == b[0].length)); }
    do
    {
      r = b.length; c = b[0].length; this.zero = zero; this.one = one;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[][](r, c);
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = b[i][j];
      }
    }
    this(ref return scope const Matrix!T v)
    {
      r = v.r; c = v.c; zero = v.zero; one = v.one;
      a = new T[][](r, c);
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] = v.a[i][j];
    }

    Matrix!T dup() const
    {
      return Matrix!T(this);
    }

    bool opEquals(Matrix!T b) const
    {
      return r == b.r && c == b.c && zip(a, b.a).all!"a[0]==a[1]";
    }

    Matrix!T opBinary(string op)(const Matrix!T b) const
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = mixin("a[i][j]"~op~"b.a[i][j]");
      return x;
    }
    ref Matrix!T opOpAssign(string op)(const Matrix!T b)
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      foreach (i; 0..r) foreach (j; 0..c) mixin("a[i][j]"~op~"=b.a[i][j];");
      return this;
    }
    Matrix!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!U)
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = a[i][j]*b;
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!U)
    {
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] *= b;
      return this;
    }
    Matrix!T opBinary(string op: "*")(const Matrix!T b) const
      in { assert(c == b.r); }
    do
    {
      auto x = Matrix!T(r, b.c, zero, one);
      foreach (i; 0..r) foreach (j; 0..b.c) foreach (k; 0..c) x[i][j] += a[i][k]*b.a[k][j];
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*")(const Matrix!T b)
      in { assert(c == b.r); }
    do
    {
      auto x = this*b;
      r = x.r; c = x.c; a = x.a;
      return this;
    }
    Vector!T opBinary(string op: "*")(const Vector!T b) const
      in { assert(c == b.n); }
    do
    {
      auto x = Vector!T(r, zero);
      foreach (i; 0..r) foreach (j; 0..c) x[i] += a[i][j]*b.a[j];
      return x;
    }
    Matrix!T opBinary(string op: "^^", U)(U n) const
      if (isIntegral!U)
      in { assert(r == c); }
    do
    {
      return powr(this, n, Matrix!T.unit(r, zero, one));
    }
  }

  private
  {
    T[][] a;
    T zero, one;
  }
}

pure nothrow @safe
{
  auto matrix(T)(T[][] a, T zero = T(0), T one = T(1))
  {
    return Matrix!T(a, zero, one);
  }

  T det(T)(Matrix!T a)
    in { assert(a.r == a.c); }
  do
  {
    auto n = a.r, b = a.dup, d = a.one;

    foreach (i; 0..n) {
      auto p = i;
      foreach (j; i+1..n)
        if (b[p][i].abs < b[j][i].abs) p = j;
      swap(b[p], b[i]);
      foreach (j; i+1..n)
        foreach (k; i+1..n)
          b[j][k] -= b[i][k]*b[j][i]/b[i][i];
      d *= b[i][i];
      if (p != i) d = -d;
    }

    return d;
  }
}

const mod = 10^^9+7;
alias mint = ModInt!mod;

pure nothrow @nogc @safe
{
  auto lowerBoundBy(alias conv = "a", alias comp = "a<b", R, T)(const R a, const T v)
  {
    return a.sortedTuple!(conv, comp).lowerBound(tuple(a.front, v)).map!"a[0]";
  }

  auto upperBoundBy(alias conv = "a", alias comp = "a<b", R, T)(const R a, const T v)
  {
    return a.sortedTuple!(conv, comp).upperBound(tuple(a.front, v)).map!"a[0]";
  }

  auto sortedTuple(alias conv = "a", alias comp = "a<b", R)(const R a)
  {
    alias convFun = unaryFun!conv, compFun = binaryFun!comp;
    return a.map!(e => tuple(e, convFun(e))).assumeSorted!((a, b) => compFun(a[1], b[1]));
  }
}

pure nothrow @nogc @safe
{
  T cdiv(T)(const T a, const T b)
  {
    return (a+b-1)/b;
  }
  T pmod(T)(const T a, const T b)
  {
    return a >= 0 ? a%b : a%b+b;
  }

  ExtGcdResult!T extGcd(T)(const T a, const T b)
  {
    if (a == 0) {
      return ExtGcdResult!T(T(b), T(0), T(1));
    } else {
      auto r = extGcd(b%a, a);
      return ExtGcdResult!T(r.gcd, r.y-(b/a)*r.x, r.x);
    }
  }

  private struct ExtGcdResult(T)
  {
    T gcd, x, y;
  }
}

struct ModInt(int m, bool pos = false)
{
  pure nothrow @nogc @safe
  {
    @property int value() { return i; }
    @property void value(int v) { i = nm(v); }
    alias value this;

    this(T)(T v)
      if (isIntegral!T)
    {
      i = nm(v);
    }
    this(ref return scope const Mint v)
    {
      i = v.i;
    }
    ref Mint opAssign(T)(T v)
      if (isIntegral!T)
    {
      i = nm(v);
      return this;
    }
    ref Mint opAssign(const Mint v)
    {
      i = v.i;
      return this;
    }

    static if (!pos) {
      Mint opUnary(string op: "-")() const
      {
        return Mint(-i);
      }
    }

    static if (m < int.max / 2) {
      Mint opBinary(string op, T)(T r) const
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        return Mint(mixin("i"~op~"r"));
      }
      ref Mint opOpAssign(string op, T)(T r)
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        i = nm(mixin("i"~op~"r"));
        return this;
      }
    } else {
      Mint opBinary(string op, T)(T r) const
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        return Mint(mixin("l"~op~"r"));
      }
      ref Mint opOpAssign(string op, T)(T r)
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        i = nm(mixin("l"~op~"r"));
        return this;
      }
    }
    Mint opBinary(string op: "*", T)(T r) const
      if (isIntegral!T)
    {
      return Mint(l*r);
    }
    ref Mint opOpAssign(string op: "*", T)(T r)
      if (isIntegral!T)
    {
      i = nm(l*r);
      return this;
    }

    Mint opBinary(string op)(const Mint r) const
      if (op == "+" || !pos && op == "-" || op == "*")
    {
      return opBinary!op(r.i);
    }
    ref Mint opOpAssign(string op)(const Mint r)
      if (op == "+"|| !pos && op == "-" || op == "*")
    {
      return opOpAssign!op(r.i);
    }

    Mint opBinary(string op: "^^", T)(T n)
      if (isIntegral!T)
    {
      return powr(this, n, Mint(1));
    }

    static if (!pos) {
      Mint opBinary(string op: "/")(const Mint r) const
      {
        return Mint(l*r.inv.i);
      }
      ref Mint opOpAssign(string op: "/")(const Mint r)
      {
        i = nm(l*r.inv.i);
        return this;
      }

      Mint opBinary(string op: "/", T)(T r) const
        if (isIntegral!T)
      {
        return opBinary!op(Mint(r));
      }
      Mint opOpAssign(string op: "/", T)(T r)
        if (isIntegral!T)
      {
        return opOpAssign!op(Mint(r));
      }

      Mint inv() const
      {
        return Mint(extGcd(i, m).x);
      }
    }
  }

  private
  {
    alias Mint = ModInt!(m, pos);
    version(BigEndian) union { long l; struct { int i2; int i; } }
    else union { long l; int i; }

    pure nothrow @nogc @safe
    {
      int nm(T)(T v) const
        if (isIntegral!T)
      {
        static if (pos) return cast(int)(v%m);
        else return cast(int)pmod(v, m);
      }
    }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}