#432349 (D) No.195 フィボナッチ数列の理解(2)

提出ソース

結果

問題	No.195 フィボナッチ数列の理解(2)
ユーザー	te-sh
提出日時	2020-02-21 19:59:16
言語	D (dmd 2.107.1)
結果	AC
実行時間	2 ms / 5,000 ms
コード長	12,512 bytes
コンパイル時間	1,509 ms
コンパイル使用メモリ	162,604 KB
実行使用メモリ	4,380 KB
最終ジャッジ日時	2023-09-04 06:00:55
合計ジャッジ時間	2,716 ms
ジャッジサーバーID （参考情報）	judge13 / judge15

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	2 ms 4,380 KB
testcase_01	AC	2 ms 4,376 KB
testcase_02	AC	2 ms 4,376 KB
testcase_03	AC	2 ms 4,376 KB
testcase_04	AC	2 ms 4,380 KB
testcase_05	AC	2 ms 4,376 KB
testcase_06	AC	2 ms 4,376 KB
testcase_07	AC	2 ms 4,376 KB
testcase_08	AC	2 ms 4,376 KB
testcase_09	AC	2 ms 4,376 KB
testcase_10	AC	2 ms 4,380 KB
testcase_11	AC	2 ms 4,376 KB
testcase_12	AC	2 ms 4,380 KB
testcase_13	AC	2 ms 4,380 KB
testcase_14	AC	2 ms 4,376 KB
testcase_15	AC	2 ms 4,380 KB
testcase_16	AC	2 ms 4,376 KB
testcase_17	AC	2 ms 4,380 KB
testcase_18	AC	2 ms 4,380 KB
testcase_19	AC	2 ms 4,380 KB
testcase_20	AC	2 ms 4,380 KB
testcase_21	AC	2 ms 4,376 KB
testcase_22	AC	2 ms 4,376 KB
testcase_23	AC	2 ms 4,376 KB
testcase_24	AC	2 ms 4,376 KB

権限があれば一括ダウンロードができます

コンパイルメッセージ

Main.d(525): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{exit: true}", int, int).put.putMain!(c, int, int).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-495(495):        instantiated from here: `putMain!(c, int, int)`
Main.d(24):        instantiated from here: `put!("{exit: true}", int, int)`
Main.d(525): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", long[]).put.putMain!(c, long[]).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-495(495):        instantiated from here: `putMain!(c, long[])`
Main.d(499):        instantiated from here: `put!("{}", long[])`
Main.d(53):        instantiated from here: `putB!("{}", long[], int)`
Main.d(525): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", int).put.putMain!(c, int).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-495(495):        instantiated from here: `putMain!(c, int)`
Main.d(500):        instantiated from here: `put!("{}", int)`
Main.d(53):        instantiated from here: `putB!("{}", long[], int)`
/dmd2/linux/bin64/../../src/phobos/std/numeric.d(2999): Warning: cannot inline function `std.numeric.gcdImpl!ulong.gcdImpl`

ソースコード

raw source code

// URL: https://yukicoder.me/problems/no/195

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  long[] X; io.getA(3, X);
  X = X.sort.uniq.array;

  auto n = 41, c = new long[](n), d = new long[](n);
  c[0] = 1; d[0] = 0;

  auto m = matrix([[0, 1], [1, 1]]);
  foreach (i; 1..n) {
    auto mi = m^^(i-1);
    c[i] = mi[1][0]; d[i] = mi[1][1];
  }

  auto r = [10L^^18, 10L^^18];

  if (X.length == 1) {
    if (X[0] == 1) io.put!"{exit: true}"(1, 1);
    auto A = 1L;
    foreach (i; 1..n) {
      auto B = frac(X[0]-A*c[i], d[i]);
      if (B.b == 1 && B.a > 0)
        r.minU([A, B.a]);
    }
  } else if (X.length == 2) {
    foreach (i; 0..n)
      foreach (j; i+1..n) {
        auto A = frac(d[j]*X[0]-d[i]*X[1], c[i]*d[j]-d[i]*c[j]);
        auto B = frac(c[i]*X[1]-c[j]*X[0], c[i]*d[j]-d[i]*c[j]);
        if (A.b == 1 && A.a > 0 && B.b == 1 && B.a > 0)
          r.minU([A.a, B.a]);
      }
  } else {
    foreach (i; 0..n)
      foreach (j; i+1..n) {
        auto A = frac(d[j]*X[0]-d[i]*X[1], c[i]*d[j]-d[i]*c[j]);
        auto B = frac(c[i]*X[1]-c[j]*X[0], c[i]*d[j]-d[i]*c[j]);
        if (A.b == 1 && A.a > 0 && B.b == 1 && B.a > 0) {
          auto a = A.a, b = B.a;
          foreach (k; j+1..n)
            if (c[k]*a+d[k]*b == X[2])
              r.minU([a, b]);
        }
      }
  }

  io.putB(r[0] < 10L^^18 && r[1] < 10L^^18, r, -1);
}

pragma(inline)
{
  pure nothrow @nogc @safe
  {
    T minU(T, U)(ref T a, U b)
    { return a = min(a, b); }
    T maxU(T, U)(ref T a, U b)
    { return a = max(a, b); }
  }
}

struct Frac(T)
{
  import std.numeric : gcd;

  T a, b;

  pure nothrow @nogc @safe
  {
    this(T a, T b)
      in { assert(b != 0); }
    do
    {
      this.a = a; this.b = b;
    }

    bool opEquals(Frac!T r) const
    {
      return (a == 0 && r.a == 0) || (a == r.a && b == r.b);
    }
    int opCmp(Frac!T r) const
    {
      return a*r.b<r.a*b ? -1 : a*r.b>r.a*b ? 1 : 0;
    }

    Frac!T inv()
      in { assert(a != 0); }
    do
    {
      return Frac!T(b, a).normalizeSign;
    }
    Frac!T opUnary(string op: "-")()
    {
      return Frac!T(-a, b);
    }

    Frac!T opBinary(string op)(Frac!T r)
      if (op == "+" || op == "-")
    {
      auto g = gcd(b, r.b);
      return Frac!T(mixin("r.b/g*a"~op~"b/g*r.a"), b/g*r.b).reduction();
    }
    Frac!T opOpAssign(string op)(Frac!T r)
      if (op == "+" || op == "-")
    {
      auto g = gcd(b, r.b);
      a = mixin("r.b/g*a"~op~"b/g*r.a"); b = b/g*r.b;
      return reduction();
    }

    Frac!T opBinary(string op: "*")(Frac!T r)
    {
      auto g1 = gcd(a.abs, r.b), g2 = gcd(r.a.abs, b);
      return Frac!T((a/g1)*(r.a/g2), (b/g2)*(r.b/g1));
    }
    ref Frac!T opOpAssign(string op: "*")(Frac!T r)
    {
      auto g1 = gcd(a.abs, r.b), g2 = gcd(r.a.abs, b);
      a = (a/g1)*(r.a/g2); b = (b/g2)*(r.b/g1); return this;
    }

    Frac!T opBinary(string op: "/")(Frac!T r)
      in { assert(r.b != 0); }
    do
    {
      auto g1 = gcd(a.abs, r.a.abs), g2 = gcd(b, r.b);
      return Frac!T((a/g1)*(r.b/g2), (b/g2)*(r.a/g1)).normalizeSign();
    }
    ref Frac!T opOpAssign(string op: "/")(Frac!T r)
      in { assert(r.b != 0); }
    do
    {
      auto g1 = gcd(a.abs, r.a.abs), g2 = gcd(b, r.b);
      a = (a/g1)*(r.b/g2); b = (b/g2)*(r.a/g1);
      return normalizeSign();
    }

    private
    {
      ref Frac!T reduction()
      {
        auto g = gcd(a.abs, b);
        a /= g; b /= g;
        return this;
      }
      ref Frac!T normalizeSign()
      {
        if (b < 0) { a = -a; b = -b; }
        return this;
      }
    }
  }
}
pure nothrow @nogc @safe
{
  Frac!T frac(T)(T a, T b)
  {
    return Frac!T(a, b).normalizeSign().reduction();
  }
}

pure nothrow @safe
{
  T powr(alias pred = "a*b", T, U)(const T a, U n, T one)
    if (isIntegral!U)
  {
    auto b = T(a);
    alias predFun = binaryFun!pred;
    if (n == 0) return one;
    auto r = one;
    for (; n > 0; n >>= 1) {
      if (n&1) r = predFun(r, b);
      b = predFun(b, b);
    }
    return r;
  }
  T powr(alias pred = "a*b", T, U)(const T a, U n)
    if (isIntegral!U)
  {
    return powr!(pred, T, U)(a, n, T(1));
  }
}

struct Vector(T)
{
  size_t n;
  @property T[] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    this(size_t n, T zero = T(0))
      in { assert(n > 0); }
    do
    {
      this.n = n; this.zero = zero;
      a = new T[](n);
      if (T.init != zero)
        foreach (i; 0..n) a[i] = zero;
    }
    this(U)(U[] b, T zero = T(0))
      in { assert(b.length > 0); }
    do
    {
      n = b.length; this.zero = zero;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[](n);
        foreach (i; 0..n) a[i] = b[i];
      }
    }
    this(ref return scope const Vector!T v)
    {
      n = v.n; zero = v.zero;
      a = new T[](n);
      foreach (i; 0..n) a[i] = v.a[i];
    }

    Vector!T dup() const
    {
      return Vector!T(this);
    }

    Vector!T opBinary(string op)(const Vector!T b) const
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = mixin("a[i]"~op~"b.a[i]");
      return x;
    }
    ref Vector!T opOpAssign(string op)(const Vector!T b)
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      foreach (i; 0..n) mixin("a[i]"~op~"=b.a[i];");
      return this;
    }
    Vector!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!T)
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = a[i]*b;
      return x;
    }
    ref Vector!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!T)
    {
      foreach (i; 0..n) a[i] *= b;
      return this;
    }
    T opBinary(string op: "*")(const Vector!T b) const
      in { assert(n == b.n); }
    do
    {
      auto x = T(zero);
      foreach (i; 0..n) x += a[i]*b.a[i];
      return x;
    }
  }

  private
  {
    T[] a;
    T zero;
  }
}

pure nothrow @safe
{
  auto vector(T)(T[] a, T zero = T(0))
  {
    return Vector!T(a, zero);
  }
  T hypot2(T)(const Vector!T a)
  {
    return a*a;
  }
  pure Vector!T cross(T)(Vector!T a, Vector!T b)
    in { assert(a.n == 3 && b.n == 3); }
  do
  {
    return Vector!T([a[1]*b[2]-a[2]*b[1], a[2]*b[0]-a[0]*b[2], a[0]*b[1]-a[1]*b[0]], a.zero);
  }
}

struct Matrix(T)
{
  size_t r, c;
  @property T[][] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    static Matrix!T unit(size_t n, T zero = T(0), T one = T(1))
      in { assert(n > 0); }
    do
    {
      auto r = Matrix!T(n, n, zero, one);
      foreach (i; 0..n) r[i][i] = one;
      return r;
    }

    this(size_t r, size_t c, T zero = T(0), T one = T(1))
      in { assert(r > 0 && c > 0); }
    do
    {
      this.r = r; this.c = c; this.zero = zero; this.one = one;
      a = new T[][](r, c);
      if (T.init != zero)
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = zero;
    }
    this(U)(U[][] b, T zero = T(0), T one = T(1))
      in { assert(b.length > 0 && b[0].length > 0 && b.all!(l => l.length == b[0].length)); }
    do
    {
      r = b.length; c = b[0].length; this.zero = zero; this.one = one;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[][](r, c);
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = b[i][j];
      }
    }
    this(ref return scope const Matrix!T v)
    {
      r = v.r; c = v.c; zero = v.zero; one = v.one;
      a = new T[][](r, c);
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] = v.a[i][j];
    }

    Matrix!T dup() const
    {
      return Matrix!T(this);
    }

    bool opEquals(Matrix!T b) const
    {
      return r == b.r && c == b.c && zip(a, b.a).all!"a[0]==a[1]";
    }

    Matrix!T opBinary(string op)(const Matrix!T b) const
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = mixin("a[i][j]"~op~"b.a[i][j]");
      return x;
    }
    ref Matrix!T opOpAssign(string op)(const Matrix!T b)
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      foreach (i; 0..r) foreach (j; 0..c) mixin("a[i][j]"~op~"=b.a[i][j];");
      return this;
    }
    Matrix!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!U)
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = a[i][j]*b;
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!U)
    {
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] *= b;
      return this;
    }
    Matrix!T opBinary(string op: "*")(const Matrix!T b) const
      in { assert(c == b.r); }
    do
    {
      auto x = Matrix!T(r, b.c, zero, one);
      foreach (i; 0..r) foreach (j; 0..b.c) foreach (k; 0..c) x[i][j] += a[i][k]*b.a[k][j];
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*")(const Matrix!T b)
      in { assert(c == b.r); }
    do
    {
      auto x = this*b;
      r = x.r; c = x.c; a = x.a;
      return this;
    }
    Vector!T opBinary(string op: "*")(const Vector!T b) const
      in { assert(c == b.n); }
    do
    {
      auto x = Vector!T(r, zero);
      foreach (i; 0..r) foreach (j; 0..c) x[i] += a[i][j]*b.a[j];
      return x;
    }
    Matrix!T opBinary(string op: "^^", U)(U n) const
      if (isIntegral!U)
      in { assert(r == c); }
    do
    {
      return powr(this, n, Matrix!T.unit(r, zero, one));
    }
  }

  private
  {
    T[][] a;
    T zero, one;
  }
}

pure nothrow @safe
{
  auto matrix(T)(T[][] a, T zero = T(0), T one = T(1))
  {
    return Matrix!T(a, zero, one);
  }

  T det(T)(Matrix!T a)
    in { assert(a.r == a.c); }
  do
  {
    auto n = a.r, b = a.dup, d = a.one;

    foreach (i; 0..n) {
      auto p = i;
      foreach (j; i+1..n)
        if (b[p][i].abs < b[j][i].abs) p = j;
      swap(b[p], b[i]);
      foreach (j; i+1..n)
        foreach (k; i+1..n)
          b[j][k] -= b[i][k]*b[j][i]/b[i][i];
      d *= b[i][i];
      if (p != i) d = -d;
    }

    return d;
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}