#432350 (D) No.196 典型DP (1)

• 問題: No.196 典型DP (1)
• ユーザー: te-sh
• 提出日時: 2020-02-21 19:59:55
• 言語: D (dmd 2.107.1)
• 結果: CE (最新)
  AC
  (最初)
• 実行時間: -
• コード長: 10,277 bytes
• コンパイル時間: 384 ms
• コンパイル使用メモリ: 135,364 KB
• 最終ジャッジ日時: 2023-09-04 06:00:57
• 合計ジャッジ時間: 760 ms
• ジャッジサーバーID （参考情報）: judge12 / judge15

コンパイルメッセージ

Main.d(472): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", ModInt!(1000000007, false)).put.putMain!(c, ModInt!(1000000007, false)).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-442(442):        instantiated from here: `putMain!(c, ModInt!(1000000007, false))`
Main.d(33):        instantiated from here: `put!("{}", ModInt!(1000000007, false))`
/dmd2/linux/bin64/../../src/phobos/std/format/internal/write.d(164): Error: cannot implicitly convert expression `obj` of type `const(ModInt!(1000000007, false))` to `int`
/dmd2/linux/bin64/../../src/phobos/std/format/write.d(1239): Error: template instance `std.format.internal.write.formatValueImpl!(LockingTextWriter, ModInt!(1000000007, false), char)` error instantiating
/dmd2/linux/bin64/../../src/phobos/std/format/write.d(632):        instantiated from here: `formatValue!(LockingTextWriter, ModInt!(1000000007, false), char)`
/dmd2/linux/bin64/../../src/phobos/std/stdio.d(1722):        instantiated from here: `formattedWrite!(LockingTextWriter, char, ModInt!(1000000007, false))`
Main.d(487):        instantiated from here: `write!(ModInt!(1000000007, false))`
Main.d(475):        ... (1 instantiations, -v to show) ...
Main.d-mixin-442(442):        instantiated from here: `putMain!(c, ModInt!(1000000007, false))`
Main.d(33):        instantiated from here: `put!("{}", ModInt!(1000000007, false))`

ソースコード

// URL: https://yukicoder.me/problems/no/196

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  int N, K; io.getV(N, K);

  auto g = Graph(N);
  foreach (_; 0..N-1) {
    int a, b; io.getV(a, b);
    g.addEdgeB(a, b);
  }
  auto t = g.tree(0);

  auto c = new mint[][](N);
  foreach_reverse (u; t.dfsOrder) {
    auto children = t.children(u).array, nv = children.length;
    auto ss = 0, dp = new mint[][](nv+1); dp[0] = [mint(1)];
    foreach (i, v; children) {
      auto s = t.size[v], pss = ss; ss += s;
      dp[i+1] = new mint[](ss+1);
      foreach (j; 0..ss+1)
        foreach (k; max(0, j-pss)..min(s, j)+1)
          dp[i+1][j] += dp[i][j-k] * c[v][k];
    }
    c[u] = dp[$-1];
    c[u] ~= mint(1);
  }

  io.put(c[0][K]);
}

struct Graph
{
  alias Node = int;
  Node n;
  Node[][] g;
  alias g this;

  pure nothrow @safe
  {
    this(Node n)
    {
      this.n = n;
      g = new Node[][](n);
    }
    void addEdge(Node u, Node v)
      in { assert(0 <= u && u < n && 0 <= v && v < n); }
    do
    {
      g[u] ~= v;
    }
    void addEdgeB(Node u, Node v)
      in { assert(0 <= u && u < n && 0 <= v && v < n); }
    do
    {
      g[u] ~= v;
      g[v] ~= u;
    }
  }
}

struct GraphW(W = int, W i = 10^^9)
{
  alias Node = int, Wt = W, inf = i;
  struct Edge
  {
    Node src, dst;
    Wt wt;
    alias cap = wt;
  }
  Node n;
  Edge[][] g;
  alias g this;

  pure nothrow @safe
  {
    this(Node n)
    {
      this.n = n;
      g = new Edge[][](n);
    }
    void addEdge(Node u, Node v, Wt w)
      in { assert(0 <= u && u < n && 0 <= v && v < n); }
    do
    {
      g[u] ~= Edge(u, v, w);
    }
    void addEdgeB(Node u, Node v, Wt w)
      in { assert(0 <= u && u < n && 0 <= v && v < n); }
    do
    {
      g[u] ~= Edge(u, v, w);
      g[v] ~= Edge(v, u, w);
    }
  }
}

struct GraphM(W = int, W i = 10^^9)
{
  alias Node = int, Wt = W, inf = i;
  Node n;
  Wt[][] g;
  alias g this;

  pure nothrow @safe
  {
    this(int n)
    {
      this.n = n;
      g = new Wt[][](n, n);
    }
    static GraphM!(W, i) init(Node n)
    {
      auto g = GraphM!(W, i)(n);
      foreach (i; 0..n) { g[i][] = inf; g[i][i] = 0; }
      return g;
    }
  }
}

struct Tree(Graph)
{
  alias Node = Graph.Node;
  Graph g;
  alias g this;
  Node root;
  Node[] parent, dfsOrder;
  int[] size, depth;

  pure nothrow @safe
  {
    this(Graph g, Node r)
      in { assert(0 <= r && r < g.n); }
    do
    {
      this.g = g;
      this.root = r;

      parent = new Node[](n);
      depth = new int[](n);
      depth[] = -1;

      auto st = SList!UP(UP(r, r));
      while (!st.empty) {
        auto up = st.front; st.removeFront();

        parent[up.u] = up.p;
        depth[up.u] = depth[up.p] + 1;
        dfsOrder ~= up.u;

        foreach (v; g[up.u])
          if (v != up.p) st.insertFront(UP(v, up.u));
      }

      size = new int[](n);
      size[] = 1;
      foreach_reverse (u; dfsOrder.drop(1))
        size[parent[u]] += size[u];
    }

    auto children(Node u) const
      in { assert(0 <= u && u < g.n); }
    do
    {
      return g[u].filter!(v => v != parent[u]);
    }
  }

  private
  {
    struct UP { Node u, p; }
  }
}

pure nothrow @safe
{
  auto tree(Graph, Node)(Graph g, Node r)
    in { assert(0 <= r && r < g.n); }
  do
  {
    return Tree!Graph(g, r);
  }
}

const mod = 10^^9+7;
alias mint = ModInt!mod;
pure nothrow @safe
{
  T powr(alias pred = "a*b", T, U)(const T a, U n, T one)
    if (isIntegral!U)
  {
    auto b = T(a);
    alias predFun = binaryFun!pred;
    if (n == 0) return one;
    auto r = one;
    for (; n > 0; n >>= 1) {
      if (n&1) r = predFun(r, b);
      b = predFun(b, b);
    }
    return r;
  }
  T powr(alias pred = "a*b", T, U)(const T a, U n)
    if (isIntegral!U)
  {
    return powr!(pred, T, U)(a, n, T(1));
  }
}

pure nothrow @nogc @safe
{
  auto lowerBoundBy(alias conv = "a", alias comp = "a<b", R, T)(const R a, const T v)
  {
    return a.sortedTuple!(conv, comp).lowerBound(tuple(a.front, v)).map!"a[0]";
  }

  auto upperBoundBy(alias conv = "a", alias comp = "a<b", R, T)(const R a, const T v)
  {
    return a.sortedTuple!(conv, comp).upperBound(tuple(a.front, v)).map!"a[0]";
  }

  auto sortedTuple(alias conv = "a", alias comp = "a<b", R)(const R a)
  {
    alias convFun = unaryFun!conv, compFun = binaryFun!comp;
    return a.map!(e => tuple(e, convFun(e))).assumeSorted!((a, b) => compFun(a[1], b[1]));
  }
}

pure nothrow @nogc @safe
{
  T cdiv(T)(const T a, const T b)
  {
    return (a+b-1)/b;
  }
  T pmod(T)(const T a, const T b)
  {
    return a >= 0 ? a%b : a%b+b;
  }

  ExtGcdResult!T extGcd(T)(const T a, const T b)
  {
    if (a == 0) {
      return ExtGcdResult!T(T(b), T(0), T(1));
    } else {
      auto r = extGcd(b%a, a);
      return ExtGcdResult!T(r.gcd, r.y-(b/a)*r.x, r.x);
    }
  }

  private struct ExtGcdResult(T)
  {
    T gcd, x, y;
  }
}

struct ModInt(int m, bool pos = false)
{
  pure nothrow @nogc @safe
  {
    @property int value() { return i; }
    @property void value(int v) { i = nm(v); }
    alias value this;

    this(T)(T v)
      if (isIntegral!T)
    {
      i = nm(v);
    }
    this(ref return scope const Mint v)
    {
      i = v.i;
    }
    ref Mint opAssign(T)(T v)
      if (isIntegral!T)
    {
      i = nm(v);
      return this;
    }
    ref Mint opAssign(const Mint v)
    {
      i = v.i;
      return this;
    }

    static if (!pos) {
      Mint opUnary(string op: "-")() const
      {
        return Mint(-i);
      }
    }

    static if (m < int.max / 2) {
      Mint opBinary(string op, T)(T r) const
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        return Mint(mixin("i"~op~"r"));
      }
      ref Mint opOpAssign(string op, T)(T r)
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        i = nm(mixin("i"~op~"r"));
        return this;
      }
    } else {
      Mint opBinary(string op, T)(T r) const
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        return Mint(mixin("l"~op~"r"));
      }
      ref Mint opOpAssign(string op, T)(T r)
        if ((op == "+" || (!pos && op == "-")) && isIntegral!T)
      {
        i = nm(mixin("l"~op~"r"));
        return this;
      }
    }
    Mint opBinary(string op: "*", T)(T r) const
      if (isIntegral!T)
    {
      return Mint(l*r);
    }
    ref Mint opOpAssign(string op: "*", T)(T r)
      if (isIntegral!T)
    {
      i = nm(l*r);
      return this;
    }

    Mint opBinary(string op)(const Mint r) const
      if (op == "+" || !pos && op == "-" || op == "*")
    {
      return opBinary!op(r.i);
    }
    ref Mint opOpAssign(string op)(const Mint r)
      if (op == "+"|| !pos && op == "-" || op == "*")
    {
      return opOpAssign!op(r.i);
    }

    Mint opBinary(string op: "^^", T)(T n)
      if (isIntegral!T)
    {
      return powr(this, n, Mint(1));
    }

    static if (!pos) {
      Mint opBinary(string op: "/")(const Mint r) const
      {
        return Mint(l*r.inv.i);
      }
      ref Mint opOpAssign(string op: "/")(const Mint r)
      {
        i = nm(l*r.inv.i);
        return this;
      }

      Mint opBinary(string op: "/", T)(T r) const
        if (isIntegral!T)
      {
        return opBinary!op(Mint(r));
      }
      Mint opOpAssign(string op: "/", T)(T r)
        if (isIntegral!T)
      {
        return opOpAssign!op(Mint(r));
      }

      Mint inv() const
      {
        return Mint(extGcd(i, m).x);
      }
    }
  }

  private
  {
    alias Mint = ModInt!(m, pos);
    version(BigEndian) union { long l; struct { int i2; int i; } }
    else union { long l; int i; }

    pure nothrow @nogc @safe
    {
      int nm(T)(T v) const
        if (isIntegral!T)
      {
        static if (pos) return cast(int)(v%m);
        else return cast(int)pmod(v, m);
      }
    }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}