結果

問題 No.997 Jumping Kangaroo
コンテスト
ユーザー nanae
提出日時 2020-02-22 00:04:04
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 2 ms / 2,000 ms
コード長 6,332 bytes
コンパイル時間 1,488 ms
コンパイル使用メモリ 151,168 KB
実行使用メモリ 6,944 KB
最終ジャッジ日時 2024-06-22 05:29:43
合計ジャッジ時間 2,355 ms
ジャッジサーバーID
（参考情報） 		judge5 / judge2
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 25
権限があれば一括ダウンロードができます

ソースコード

diff # 

import std.stdio, std.string, std.conv, std.range;
import std.algorithm, std.array, std.typecons, std.container;
import std.math, std.numeric, std.random, core.bitop;

enum inf = 1_001_001_001;
enum infl = 1_001_001_001_001_001_001L;
enum mod = 1_000_000_007L;

void main() {
    int N, W; long K;
    scan(N, W, K);
    auto a = readln.split.to!(int[]);

    auto dp = new ModInt[][](2*W + 1, 2);
    dp[0][0] = 1;

    foreach (i ; 0 .. 2*W + 1) {
        foreach (j ; 0 .. 2) {
            foreach (ai ; a) {
                if (i + ai <= 2*W) {
                    dp[i + ai][j | (i + ai == W)] += dp[i][j];
                }
            }
        }
    }

    ModInt x = dp[W][1], y = dp[2*W][0];
    ModInt[][] A = [[x, y], [ModInt(1), ModInt(0)]];
    auto res = mul(powMat(A, K), [[ModInt(1)], [ModInt(0)]]);
    auto ans = res[0][0];
    writeln(ans);
}


T[][] powMat(T)(T[][] A, long x) {
    if (x > 0) {
        auto res = square!T(powMat(A, x>>1));
        if (x & 1) {
            res = mul!T(res, A);
        }
        return res;
    }
    else {
        auto res = new T[][](A.length, A.length);
        foreach (i ; 0 .. A.length) res[i][i] = 1;
        return res;
    }
}

T[][] square(T)(T[][] A) {
    assert(A[0].length == A.length);
    auto B = new T[][](A.length, A.length);

    foreach (i ; 0 .. A.length) {
        foreach (j ; 0 .. A.length) {
            foreach (k ; 0 .. A.length) {
                B[i][j] += A[i][k] * A[k][j];
            }
        }
    }

    return B;
}


auto mul(T)(T[][] A, T[][] B) {
    assert(A[0].length == B.length);
    auto N = A.length;
    auto M = B[0].length;

    auto C = new T[][](N, M);

    foreach (i ; 0 .. N) {
        foreach (j ; 0 .. M) {
            foreach (k ; 0 .. A[i].length) {
                C[i][j] += A[i][k] * B[k][j];
            }
        }
    }

    return C;
}




struct ModInt {
    long value = 0;
    long mod = 1_000_000_007L;

    this(long value, long mod = 1_000_000_007L) {
        this.mod = mod;
        this.value = (value % mod);
        if (this.value < 0) this.value += mod;
    }

    long powmod(long x, long y) {
        return y > 0 ? powmod(x, y >> 1)^^2 % mod * x^^(y & 1) % mod : 1L;
    }

    void opAssign(long x) {
        value = x % mod;
        if (value < 0) value += mod;
    }

    ModInt opBinary(string op)(const ModInt rhs){
        auto lhs = this;

        static if (op == "+") {
            lhs.value += rhs.value;
            if (lhs.value >= mod) lhs.value -= mod;
            return lhs;
        }
        static if (op == "-") {
            lhs.value -= rhs.value;
            if (lhs.value < 0) lhs.value += mod;
            return lhs;
        }
        static if (op == "*") {
            (lhs.value *= rhs.value) %= mod;
            return lhs;
        }
        static if (op == "/") {
            (lhs.value *= powmod(rhs.value, mod - 2)) %= mod;
            return lhs;
        }
    }

    ModInt opBinary(string op)(long rhs){
        auto lhs = this;

        static if (op != "^^") {
            rhs %= mod;
            if (rhs < 0) rhs += mod;
        }

        static if (op == "+") {
            lhs.value += rhs;
            if (lhs.value >= mod) lhs.value -= mod;
            return lhs;
        }
        static if (op == "-") {
            lhs.value -= rhs;
            if (lhs.value < 0) lhs.value += mod;
            return lhs;
        }
        static if (op == "*") {
            (lhs.value *= rhs) %= mod;
            return lhs;
        }
        static if (op == "/") {
            (lhs.value *= powmod(rhs, mod - 2)) %= mod;
            return lhs;
        }
        static if (op == "^^") {
            lhs.value = powmod(lhs.value, rhs);
            return lhs;
        }
    }

    bool opEquals(ModInt a, ModInt b) {
        return a.value == b.value;
    }

    bool opEquals(T)(const T rhs) {
        long x = rhs % mod;
        if (x < 0) x += mod;
        return this.value == x;
    }

    void opOpAssign(string op)(const ModInt rhs) {
        static if (op == "+") {
            this.value += rhs.value;
            if (this.value >= mod) this.value -= mod;
        }
        static if (op == "-") {
            this.value -= rhs.value;
            if (this.value < 0) this.value += mod;
        }
        static if (op == "*") {
            (this.value *= rhs.value) %= mod;
        }
        static if (op == "/") {
            (this.value *= powmod(rhs.value, mod - 2)) %= mod;
        }
    }

    void opOpAssign(string op)(long rhs) {
        rhs %= mod;
        if (rhs < 0) rhs += mod;

        static if (op == "+") {
            this.value += rhs;
            if (this.value >= mod) this.value -= mod;
        }
        static if (op == "-") {
            this.value -= rhs;
            if (this.value < 0) this.value += mod;
        }
        static if (op == "*") {
            (this.value *= rhs) %= mod;
        }
        static if (op == "/") {
            (this.value *= powmod(rhs, mod - 2)) %= mod;
        }
    }

    string toString() {
        import std.conv : to;
        return value.to!string;
    }
}

unittest {
    enum mod = 1_000_000_007L;

    auto a = ModInt(2);
    auto b = ModInt(3);

    assert(a + b == 5);
    assert(a - b == mod - 1);
    assert(a * b == 6);

    assert(a + 8 == 10);
    assert(a - 1 == 1);
    assert(a * 7 == 14);

    ModInt c = 8;
    assert(c == 8);
}



void scan(T...)(ref T args) {
    import std.stdio : readln;
    import std.algorithm : splitter;
    import std.conv : to;
    import std.range.primitives;

    auto line = readln().splitter();
    foreach (ref arg; args) {
        arg = line.front.to!(typeof(arg));
        line.popFront();
    }
    assert(line.empty);
}

void fillAll(R, T)(ref R arr, T value) {
    static if (is(typeof(arr[] = value))) {
        arr[] = value;
    }
    else {
        foreach (ref e; arr) {
            fillAll(e, value);
        }
    }
}

bool chmin(T, U...)(ref T x, U args) {
    bool isChanged;

    foreach (arg; args) {
        if (x > arg) {
            x = arg;
            isChanged = true;
        }
    }

    return isChanged;
}

bool chmax(T, U...)(ref T x, U args) {
    bool isChanged;

    foreach (arg; args) {
        if (x < arg) {
            x = arg;
            isChanged = true;
        }
    }

    return isChanged;
}
0