#489183 (Common Lisp) No.1067 #いろいろな色 / Red and Blue and more various colors (Middle)

提出ソース

結果

問題	No.1067 #いろいろな色 / Red and Blue and more various colors (Middle)
ユーザー	sansaqua
提出日時	2020-05-29 23:30:03
言語	Common Lisp (sbcl 2.3.8)
結果	AC
実行時間	1,102 ms / 2,000 ms
コード長	12,078 bytes
コンパイル時間	1,488 ms
コンパイル使用メモリ	91,616 KB
実行使用メモリ	205,856 KB
最終ジャッジ日時	2024-11-06 08:22:26
合計ジャッジ時間	10,081 ms
ジャッジサーバーID （参考情報）	judge5 / judge1

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	11 ms 26,792 KB
testcase_01	AC	11 ms 26,920 KB
testcase_02	AC	12 ms 29,004 KB
testcase_03	AC	12 ms 30,908 KB
testcase_04	AC	12 ms 27,304 KB
testcase_05	AC	13 ms 31,140 KB
testcase_06	AC	11 ms 27,052 KB
testcase_07	AC	12 ms 27,044 KB
testcase_08	AC	11 ms 26,924 KB
testcase_09	AC	11 ms 26,792 KB
testcase_10	AC	11 ms 29,004 KB
testcase_11	AC	662 ms 126,148 KB
testcase_12	AC	429 ms 95,416 KB
testcase_13	AC	884 ms 156,872 KB
testcase_14	AC	489 ms 97,440 KB
testcase_15	AC	206 ms 60,292 KB
testcase_16	AC	182 ms 56,204 KB
testcase_17	AC	42 ms 33,536 KB
testcase_18	AC	524 ms 105,392 KB
testcase_19	AC	540 ms 105,404 KB
testcase_20	AC	261 ms 72,424 KB
testcase_21	AC	1,102 ms 200,244 KB
testcase_22	AC	1,100 ms 205,856 KB
testcase_23	AC	1,098 ms 201,944 KB
testcase_24	AC	11 ms 28,872 KB
testcase_25	AC	12 ms 30,888 KB

権限があれば一括ダウンロードができます

コンパイルメッセージ

; compiling file "/home/judge/data/code/Main.lisp" (written 06 NOV 2024 08:22:15 AM):

; file: /home/judge/data/code/Main.lisp
; in: DEFUN MAIN
;     (DESTRUCTURING-BIND
;         (OP POS INDEX P)
;         (CAR EVENTS)
;       (ASSERT (EQ :ADD OP))
;       (SETQ STD POS))
; ==>
;   (LET* ((#:G33 (SB-C::CHECK-DS-LIST (CAR EVENTS) 4 4 '(OP POS INDEX P)))
;          (OP (POP #:G33))
;          (POS (POP #:G33))
;          (INDEX (POP #:G33))
;          (P (POP #:G33)))
;     (ASSERT (EQ :ADD OP))
;     (SETQ STD POS))
; 
; caught STYLE-WARNING:
;   The variable INDEX is defined but never used.
; 
; caught STYLE-WARNING:
;   The variable P is defined but never used.
; 
; compilation unit finished
;   caught 2 STYLE-WARNING conditions


; wrote /home/judge/data/code/Main.fasl
; compilation finished in 0:00:00.328

ソースコード

raw source code

(eval-when (:compile-toplevel :load-toplevel :execute)
  (sb-int:defconstant-eqx opt
    #+swank '(optimize (speed 3) (safety 2))
    #-swank '(optimize (speed 3) (safety 0) (debug 0))
    #'equal)
  #+swank (ql:quickload '(:cl-debug-print :fiveam) :silent t)
  #-swank (set-dispatch-macro-character
           #\# #\> (lambda (s c p) (declare (ignore c p)) `(values ,(read s nil nil t)))))
#+swank (cl-syntax:use-syntax cl-debug-print:debug-print-syntax)
#-swank (disable-debugger) ; for CS Academy

;; BEGIN_INSERTED_CONTENTS
(macrolet ((def (name fname)
             `(define-modify-macro ,name (new-value) ,fname)))
  (def minf min)
  (def maxf max)
  (def mulf *)
  (def divf /)
  (def iorf logior)
  (def xorf logxor)
  (def andf logand))

(declaim (inline bisect-left))
(defun bisect-left (target value &key (start 0) end (order #'<) (key #'identity))
  "TARGET := vector | function (taking an integer argument)
ORDER := strict order

Analogue of lower_bound() of C++ or bisect_left() of Python: Returns the
smallest index (or input) i that fulfills TARGET[i] >= VALUE, where '>=' is the
complement of ORDER. In other words, this function returns the leftmost index at
which VALUE can be inserted with keeping the order. Therefore, TARGET must be
monotonically non-decreasing with respect to ORDER.

- This function returns END if VALUE exceeds TARGET[END-1]. 
- The range [START, END) is half-open.
- END must be explicitly specified if TARGET is function.
- KEY is applied to each element of TARGET before comparison."
  (declare (function key order)
           (integer start)
           ((or null integer) end))
  (macrolet
      ((frob (accessor &optional declaration)
         `(labels
              ((%bisect-left (ng ok)
                 ;; TARGET[OK] >= VALUE always holds (assuming
                 ;; TARGET[END] = +infinity)
                 ,@(when declaration (list declaration))
                 (if (<= (- ok ng) 1)
                     ok
                     (let ((mid (ash (+ ng ok) -1)))
                       (if (funcall order (funcall key (,accessor target mid)) value)
                           (%bisect-left mid ok)
                           (%bisect-left ng mid))))))
            (assert (<= start end))
            (%bisect-left (- start 1) end))))
    (etypecase target
      (vector
       (let ((end (or end (length target))))
         (frob aref (declare ((integer -1 (#.most-positive-fixnum)) ng ok)))))
      (function
       (assert end () "Requires END argument if TARGET is a function.")
       (frob funcall)))))

(declaim (inline bisect-right))
(defun bisect-right (target value &key (start 0) end (order #'<) (key #'identity))
  "TARGET := vector | function (taking an integer argument)
ORDER := strict order

Analogue of upper_bound() of C++ or bisect_right() of Python: Returns the
smallest index (or input) i that fulfills TARGET[i] > VALUE. In other words,
this function returns the rightmost index at which VALUE can be inserted with
keeping the order. Therefore, TARGET must be monotonically non-decreasing with
respect to ORDER.

- This function returns END if VALUE >= TARGET[END-1].
- The range [START, END) is half-open.
- END must be explicitly specified if TARGET is function.
- KEY is applied to each element of TARGET before comparison."
  (declare (function key order)
           (integer start)
           ((or null integer) end))
  (macrolet
      ((frob (accessor &optional declaration)
         `(labels
              ((%bisect-right (ng ok)
                 ;; TARGET[OK] > VALUE always holds (assuming
                 ;; TARGET[END] = +infinity)
                 ,@(when declaration (list declaration))
                 (if (<= (- ok ng) 1)
                     ok
                     (let ((mid (ash (+ ng ok) -1)))
                       (if (funcall order value (funcall key (,accessor target mid)))
                           (%bisect-right ng mid)
                           (%bisect-right mid ok))))))
            (assert (<= start end))
            (%bisect-right (- start 1) end))))
    (etypecase target
      (vector
       (let ((end (or end (length target))))
         (frob aref (declare ((integer -1 (#.array-total-size-limit)) ng ok)))))
      (function
       (assert end () "Requires END argument if TARGET is a function.")
       (frob funcall)))))

;;;
;;; Arithmetic operations with static modulus
;;;

;; FIXME: Currently MOD* and MOD+ doesn't apply MOD when the number of
;; parameters is one.
(defmacro define-mod-operations (divisor)
  `(progn
     (defun mod* (&rest args)
       (reduce (lambda (x y) (mod (* x y) ,divisor)) args))

     (defun mod+ (&rest args)
       (reduce (lambda (x y) (mod (+ x y) ,divisor)) args))

     #+sbcl
     (eval-when (:compile-toplevel :load-toplevel :execute)
       (locally (declare (muffle-conditions warning))
         (sb-c:define-source-transform mod* (&rest args)
           (if (null args)
               1
               (reduce (lambda (x y) `(mod (* ,x ,y) ,',divisor)) args)))
         (sb-c:define-source-transform mod+ (&rest args)
           (if (null args)
               0
               (reduce (lambda (x y) `(mod (+ ,x ,y) ,',divisor)) args)))))

     (define-modify-macro incfmod (delta)
       (lambda (x y) (mod (+ x y) ,divisor)))

     (define-modify-macro decfmod (delta)
       (lambda (x y) (mod (- x y) ,divisor)))

     (define-modify-macro mulfmod (multiplier)
       (lambda (x y) (mod (* x y) ,divisor)))))


(declaim (ftype (function * (values fixnum &optional)) read-fixnum))
(defun read-fixnum (&optional (in *standard-input*))
  "NOTE: cannot read -2^62"
  (macrolet ((%read-byte ()
               `(the (unsigned-byte 8)
                     #+swank (char-code (read-char in nil #\Nul))
                     #-swank (sb-impl::ansi-stream-read-byte in nil #.(char-code #\Nul) nil))))
    (let* ((minus nil)
           (result (loop (let ((byte (%read-byte)))
                           (cond ((<= 48 byte 57)
                                  (return (- byte 48)))
                                 ((zerop byte) ; #\Nul
                                  (error "Read EOF or #\Nul."))
                                 ((= byte #.(char-code #\-))
                                  (setq minus t)))))))
      (declare ((integer 0 #.most-positive-fixnum) result))
      (loop
        (let* ((byte (%read-byte)))
          (if (<= 48 byte 57)
              (setq result (+ (- byte 48)
                              (* 10 (the (integer 0 #.(floor most-positive-fixnum 10))
                                         result))))
              (return (if minus (- result) result))))))))

(in-package :cl-user)

(defmacro dbg (&rest forms)
  #+swank
  (if (= (length forms) 1)
      `(format *error-output* "~A => ~A~%" ',(car forms) ,(car forms))
      `(format *error-output* "~A => ~A~%" ',forms `(,,@forms)))
  #-swank (declare (ignore forms)))

(defmacro define-int-types (&rest bits)
  `(progn
     ,@(mapcar (lambda (b) `(deftype ,(intern (format nil "UINT~A" b)) () '(unsigned-byte ,b))) bits)
     ,@(mapcar (lambda (b) `(deftype ,(intern (format nil "INT~A" b)) () '(signed-byte ,b))) bits)))
(define-int-types 2 4 7 8 15 16 31 32 62 63 64)

(declaim (inline println))
(defun println (obj &optional (stream *standard-output*))
  (let ((*read-default-float-format* 'double-float))
    (prog1 (princ obj stream) (terpri stream))))

(defconstant +mod+ 998244353)

;;;
;;; Body
;;;

(define-mod-operations +mod+)
(defun main ()
  (let* ((n (read))
         (q (read))
         (as (make-array n :element-type 'uint31 :initial-element 0))
         events
         (table (make-hash-table :test #'eq))
         (dp (make-array (list (+ n 1) (+ n 1)) :element-type 'uint31 :initial-element 0))
         (res (make-array q :element-type 'uint31 :initial-element 0)))
    (dotimes (i n)
      (setf (aref as i) (read-fixnum)))
    (setq as (sort as #'>))
    (setf (aref dp 0 0) 1)
    (loop for x from 1 to n
          do (setf (aref dp x 0)
                   (aref dp (- x 1) 0))
             (loop for y from 1 to n
                   do (setf (aref dp x y)
                            (mod+ (mod* (aref dp (- x 1) (- y 1))
                                        (- (aref as (- x 1)) 1))
                                  (aref dp (- x 1) y)))))
    (dotimes (i q)
      (let ((l (read-fixnum))
            (r (read-fixnum))
            (p (read-fixnum)))
        (push (list :del (- l 1) i p) events)
        (push (list :add r i p) events)))
    (setq events (sort events #'> :key #'second))
    (let ((prods (make-array (+ n 1) :element-type 'uint31))
          (std 1000000001))
      (setf (aref prods n) 1)
      (loop for i from (- n 1) downto 0
            do (setf (aref prods i)
                     (mod* (aref as i) (aref prods (+ i 1)))))
      #>prods
      (loop while events
            do (when (zerop (hash-table-count table))
                 (destructuring-bind (op pos index p) (car events)
                   (assert (eq :add op))
                   (setq std pos)))
               #>std
               #>(sb-int:%hash-table-alist table)
               (progn
                 (loop while events
                       for (op pos index p) = (car events)
                       when (= pos std)
                       do (pop events)
                          (if (eq op :add)
                              (setf (gethash index table) p)
                              (remhash index table))
                       else do (return))
                 (let ((x (bisect-right as std :order #'>)))
                   (maphash (lambda (index p)
                              (let ((base (if (< x p) 0 (aref dp x (- x p)))))
                                (dbg std x index p base)
                                (xorf (aref res index)
                                      (mod* base (aref prods x)))))
                            table))
                 (decf std)))
      (map () #'println res))))

#-swank (main)

;;;
;;; Test and benchmark
;;;

#+swank
(defun io-equal (in-string out-string &key (function #'main) (test #'equal))
  "Passes IN-STRING to *STANDARD-INPUT*, executes FUNCTION, and returns true if
the string output to *STANDARD-OUTPUT* is equal to OUT-STRING."
  (labels ((ensure-last-lf (s)
             (if (eql (uiop:last-char s) #\Linefeed)
                 s
                 (uiop:strcat s uiop:+lf+))))
    (funcall test
             (ensure-last-lf out-string)
             (with-output-to-string (out)
               (let ((*standard-output* out))
                 (with-input-from-string (*standard-input* (ensure-last-lf in-string))
                   (funcall function)))))))

#+swank
(defun get-clipbrd ()
  (with-output-to-string (out)
    (run-program "powershell.exe" '("-Command" "Get-Clipboard") :output out :search t)))

#+swank (defparameter *this-pathname* (uiop:current-lisp-file-pathname))
#+swank (defparameter *dat-pathname* (uiop:merge-pathnames* "test.dat" *this-pathname*))

#+swank
(defun run (&optional thing (out *standard-output*))
  "THING := null | string | symbol | pathname

null: run #'MAIN using the text on clipboard as input.
string: run #'MAIN using the string as input.
symbol: alias of FIVEAM:RUN!.
pathname: run #'MAIN using the text file as input."
  (let ((*standard-output* out))
    (etypecase thing
      (null
       (with-input-from-string (*standard-input* (delete #\Return (get-clipbrd)))
         (main)))
      (string
       (with-input-from-string (*standard-input* (delete #\Return thing))
         (main)))
      (symbol (5am:run! thing))
      (pathname
       (with-open-file (*standard-input* thing)
         (main))))))

#+swank
(defun gen-dat ()
  (uiop:with-output-file (out *dat-pathname* :if-exists :supersede)
    (format out "")))

#+swank
(defun bench (&optional (out (make-broadcast-stream)))
  (time (run *dat-pathname* out)))

;; To run: (5am:run! :sample)
#+swank
(it.bese.fiveam:test :sample
  (it.bese.fiveam:is
   (common-lisp-user::io-equal "3 4
3 4 5
1 5 0
1 5 1
1 5 2
1 5 3
"
    "12
3
10
1
")))

yukicoder

結果

テストケース

コンパイルメッセージ

ソースコード