結果

問題 No.1062 素敵なスコア
コンテスト
ユーザー hos.lyric
提出日時 2020-08-02 19:48:30
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 7 ms / 2,000 ms
コード長 7,142 bytes
コンパイル時間 1,413 ms
コンパイル使用メモリ 160,080 KB
実行使用メモリ 6,948 KB
最終ジャッジ日時 2024-06-22 07:58:19
合計ジャッジ時間 2,708 ms
ジャッジサーバーID
（参考情報） 		judge4 / judge2
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 32
権限があれば一括ダウンロードができます

ソースコード

diff # 

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }


struct ModInt(int M_) {
  import std.conv : to;
  alias M = M_;
  int x;
  this(ModInt a) { x = a.x; }
  this(long a) { x = cast(int)(a % M); if (x < 0) x += M; }
  ref ModInt opAssign(long a) { return (this = ModInt(a)); }
  ref ModInt opOpAssign(string op)(ModInt a) {
    static if (op == "+") { x += a.x; if (x >= M) x -= M; }
    else static if (op == "-") { x -= a.x; if (x < 0) x += M; }
    else static if (op == "*") { x = cast(int)((cast(long)(x) * a.x) % M); }
    else static if (op == "/") { this *= a.inv(); }
    else static assert(false);
    return this;
  }
  ref ModInt opOpAssign(string op)(long a) {
    static if (op == "^^") {
      if (a < 0) return (this = inv()^^(-a));
      ModInt t2 = this, te = ModInt(1);
      for (long e = a; e > 0; e >>= 1) {
        if (e & 1) te *= t2;
        t2 *= t2;
      }
      x = cast(int)(te.x);
      return this;
    } else return mixin("this " ~ op ~ "= ModInt(a)");
  }
  ModInt inv() const {
    int a = x, b = M, y = 1, z = 0, t;
    for (; ; ) {
      t = a / b; a -= t * b;
      if (a == 0) {
        assert(b == 1 || b == -1);
        return ModInt(b * z);
      }
      y -= t * z;
      t = b / a; b -= t * a;
      if (b == 0) {
        assert(a == 1 || a == -1);
        return ModInt(a * y);
      }
      z -= t * y;
    }
  }
  ModInt opUnary(string op: "-")() const { return ModInt(-x); }
  ModInt opBinary(string op, T)(T a) const {
    return mixin("ModInt(this) " ~ op ~ "= a");
  }
  ModInt opBinaryRight(string op)(long a) const {
    return mixin("ModInt(a) " ~ op ~ "= this");
  }
  bool opCast(T: bool)() const { return (x != 0); }
  string toString() const { return x.to!string; }
}

enum MO = 998244353;
alias Mint = ModInt!MO;


enum LIM = 2 * 10^^5 + 10;
Mint[] inv, fac, invFac;
void prepare() {
  inv = new Mint[LIM];
  fac = new Mint[LIM];
  invFac = new Mint[LIM];
  inv[1] = 1;
  foreach (i; 2 .. LIM) {
    inv[i] = -(Mint.M / i) * inv[cast(size_t)(Mint.M % i)];
  }
  fac[0] = invFac[0] = 1;
  foreach (i; 1 .. LIM) {
    fac[i] = fac[i - 1] * i;
    invFac[i] = invFac[i - 1] * inv[i];
  }
}
Mint binom(long n, long k) {
  if (0 <= k && k <= n) {
    assert(n < LIM);
    return fac[cast(size_t)(n)] * invFac[cast(size_t)(k)] * invFac[cast(size_t)(n - k)];
  } else {
    return Mint(0);
  }
}


long brute(int N, int A, int B) {
  long ans;
  auto perm = iota(N).array;
  do {
    int[] simulate(int a) {
      auto ps = perm.dup;
      for (; ; ) {
        foreach (i; 0 .. N) if (ps[i] >= a) {
          foreach_reverse (j; 0 .. N) if (ps[j] < a) {
            if (i < j) {
              swap(ps[i], ps[j]);
              goto found;
            } else {
              goto done;
            }
          }
        }
       found:
      }
     done:
      return ps;
    }
    const ps = simulate(A);
    const qs = simulate(B);
    foreach (i; 0 .. N) {
      if (ps[i] == qs[i]) {
        ++ans;
      }
    }
  } while (perm.nextPermutation);
  return ans;
}

Mint slow(int N, int A, int B) {
  if (A > B) {
    swap(A, B);
  }
  
  /*
    fixed
    
    finally:
    0...0 (1or2...1or2)
    (0or1...0or1) 2...2
  */
  Mint ans0;
  ans0 += Mint(A)^^2;
  ans0 += Mint(B - A)^^2;
  ans0 += Mint(N - B)^^2;
  ans0 *= fac[N - 1];
  debug {
    writeln("  ans0 = ", ans0);
  }
  
  /*
    moved
    
    ........ 2 ... 0 ........
    x0,x1,x2         y0,y1,y2
    
    x1 + x2 = y0
    x2 = y0 + y1
    ==> (x0, x1, x2, y0, y1, y2) = (c - t, 0, t, t, 0, d - t)
  */
  Mint ans1;
  foreach (c; 0 .. A) foreach (d; 0 .. N - B) {
    Mint tmp = 1;
    tmp *= binom(c + d, c);
    tmp *= binom(N - (c + d + 2), A - (c + 1)) * binom((N - (c + d + 2)) - (A - (c + 1)), (N - B) - (d + 1));
    tmp *= fac[A];
    tmp *= fac[B - A];
    tmp *= fac[N - B];
    ans1 += tmp;
  }
  debug {
    writeln("  ans1 = ", ans1);
  }
  
  return ans0 + 2 * ans1;
}

Mint solve(int N, int A, int B) {
  if (A > B) {
    swap(A, B);
  }
  
  Mint ans0;
  ans0 += Mint(A)^^2;
  ans0 += Mint(B - A)^^2;
  ans0 += Mint(N - B)^^2;
  ans0 *= fac[N - 1];
  debug {
    writeln("  ans0 = ", ans0);
  }
  
  /*
    \sum_{c+d=s} 1 / (c! (A - 1 - c)! d! ((N - B) - 1 - d!)
    = binom(A + (N - B) - 2, s) / ((A - 1)! ((N - B) - 1)!)
  */
  /*
  Mint ans1;
  foreach (s; 0 .. (A + (N - B) - 2) + 1) {
    Mint tmp = 1;
    tmp *= fac[s];
    tmp *= fac[N - 2 - s];
    tmp *= invFac[B - A];
    tmp *= binom(A + (N - B) - 2, s) * invFac[A - 1] * invFac[(N - B) - 1];
    ans1 += tmp;
  }
  ans1 *= fac[A];
  ans1 *= fac[B - A];
  ans1 *= fac[N - B];
  */
  /*
            s! (N - 2 - s)! (A + (N - B) - 2)! A! (B - A)! (N - B)!
    \sum_s ------------------------------------------------------------
            (B - A)! s! (A + (N - B) - 2 - s)! (A - 1)! ((N - B) - 1)!
                                           (N - 2 - s)! 
    = A (N - B) (A + (N - B) - 2)! \sum_s ------------------------
                                           (A + (N - B) - 2 - s)!
    = A (N - B) (A + (N - B) - 2)! (B - A)! \sum_s binom(N - 2 - s, B - A)
    = A (N - B) (A + (N - B) - 2)! (B - A)! \sum_{B-A<=i<=N-2} binom(i, B - A)
    = A (N - B) (A + (N - B) - 2)! (B - A)! binom(N - 1, B - A + 1)
       A (N - B) (A + (N - B) - 2)! (B - A)! (N - 1)!
    = ------------------------------------------------
       (B - A + 1)! (N - 2 - (B - A))!
  */
  Mint ans1 = 1;
  ans1 *= A;
  ans1 *= (N - B);
  ans1 *= fac[N - 1];
  ans1 *= inv[B - A + 1];
  debug {
    writeln("  ans1 = ", ans1);
  }
  
  return ans0 + 2 * ans1;
}

void main() {
  prepare;
  
  try {
    for (; ; ) {
      const N = readInt();
      int A = readInt();
      int B = readInt();
      
      const ans = solve(N, A, B);
      writeln(ans);
      debug {
        const slw = slow(N, A, B);
        writeln("slw = ", slw);
        assert(ans.x == slw.x);
        if (N <= 10) {
          const brt = brute(N, A, B);
          writeln("brt = ", brt);
          assert(slw.x == brt);
        }
      }
    }
  } catch (EOFException e) {
  }
}
0