結果

問題 No.1190 Points
ユーザー sansaquasansaqua
提出日時 2020-08-22 17:00:09
言語 Common Lisp
(sbcl 2.3.8)
結果
AC  
実行時間 102 ms / 2,000 ms
コード長 8,187 bytes
コンパイル時間 1,461 ms
コンパイル使用メモリ 49,976 KB
実行使用メモリ 41,600 KB
最終ジャッジ日時 2024-10-15 11:00:48
合計ジャッジ時間 4,613 ms
ジャッジサーバーID
（参考情報） 		judge3 / judge2
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 11 ms
23,168 KB
testcase_01 AC 10 ms
23,296 KB
testcase_02 AC 10 ms
23,296 KB
testcase_03 AC 53 ms
33,280 KB
testcase_04 AC 46 ms
31,744 KB
testcase_05 AC 51 ms
31,744 KB
testcase_06 AC 61 ms
34,688 KB
testcase_07 AC 75 ms
37,120 KB
testcase_08 AC 80 ms
41,600 KB
testcase_09 AC 86 ms
40,192 KB
testcase_10 AC 83 ms
41,472 KB
testcase_11 AC 63 ms
35,840 KB
testcase_12 AC 82 ms
40,832 KB
testcase_13 AC 60 ms
33,536 KB
testcase_14 AC 21 ms
27,008 KB
testcase_15 AC 99 ms
39,424 KB
testcase_16 AC 18 ms
25,344 KB
testcase_17 AC 88 ms
38,144 KB
testcase_18 AC 56 ms
30,848 KB
testcase_19 AC 17 ms
27,392 KB
testcase_20 AC 67 ms
32,768 KB
testcase_21 AC 28 ms
27,776 KB
testcase_22 AC 30 ms
29,184 KB
testcase_23 AC 101 ms
39,808 KB
testcase_24 AC 102 ms
39,936 KB
testcase_25 AC 67 ms
35,072 KB
testcase_26 AC 45 ms
32,768 KB
testcase_27 AC 64 ms
35,200 KB
権限があれば一括ダウンロードができます
コンパイルメッセージ
; compiling file "/home/judge/data/code/Main.lisp" (written 15 OCT 2024 11:00:43 AM):

; wrote /home/judge/data/code/Main.fasl
; compilation finished in 0:00:00.084

ソースコード

diff # 

(in-package :cl-user)
(eval-when (:compile-toplevel :load-toplevel :execute)
  (sb-int:defconstant-eqx opt
    #+swank '(optimize (speed 3) (safety 2))
    #-swank '(optimize (speed 3) (safety 0) (debug 0))
    #'equal)
  #+swank (ql:quickload '(:cl-debug-print :fiveam) :silent t)
  #-swank (set-dispatch-macro-character
           #\# #\> (lambda (s c p) (declare (ignore c p)) `(values ,(read s nil nil t)))))
#+swank (cl-syntax:use-syntax cl-debug-print:debug-print-syntax)

(defmacro define-int-types (&rest bits)
  `(progn
     ,@(mapcar (lambda (b) `(deftype ,(intern (format nil "UINT~A" b)) () '(unsigned-byte ,b))) bits)
     ,@(mapcar (lambda (b) `(deftype ,(intern (format nil "INT~A" b)) () '(signed-byte ,b))) bits)))
(define-int-types 2 4 7 8 15 16 31 32 62 63 64)

(defconstant +mod+ 1000000007)

(defmacro dbg (&rest forms)
  #+swank (if (= (length forms) 1)
              `(format *error-output* "~A => ~A~%" ',(car forms) ,(car forms))
              `(format *error-output* "~A => ~A~%" ',forms `(,,@forms)))
  #-swank (declare (ignore forms)))

(declaim (inline println))
(defun println (obj &optional (stream *standard-output*))
  (let ((*read-default-float-format* 'double-float))
    (prog1 (princ obj stream) (terpri stream))))

;; BEGIN_INSERTED_CONTENTS
(defpackage :cp/read-fixnum
  (:use :cl)
  (:export #:read-fixnum))
(in-package :cp/read-fixnum)

(declaim (ftype (function * (values fixnum &optional)) read-fixnum))
(defun read-fixnum (&optional (in *standard-input*))
  "NOTE: cannot read -2^62"
  (macrolet ((%read-byte ()
               `(the (unsigned-byte 8)
                     #+swank (char-code (read-char in nil #\Nul))
                     #-swank (sb-impl::ansi-stream-read-byte in nil #.(char-code #\Nul) nil))))
    (let* ((minus nil)
           (result (loop (let ((byte (%read-byte)))
                           (cond ((<= 48 byte 57)
                                  (return (- byte 48)))
                                 ((zerop byte) ; #\Nul
                                  (error "Read EOF or #\Nul."))
                                 ((= byte #.(char-code #\-))
                                  (setq minus t)))))))
      (declare ((integer 0 #.most-positive-fixnum) result))
      (loop
        (let* ((byte (%read-byte)))
          (if (<= 48 byte 57)
              (setq result (+ (- byte 48)
                              (* 10 (the (integer 0 #.(floor most-positive-fixnum 10))
                                         result))))
              (return (if minus (- result) result))))))))

;;;
;;; Queue with singly linked list
;;;

(defpackage :cp/queue
  (:use :cl)
  (:export #:queue #:make-queue #:enqueue #:dequeue #:queue-empty-p #:queue-peek #:enqueue-front))
(in-package :cp/queue)

(defstruct (queue (:constructor make-queue
                      (&optional list &aux (tail (last list))))
                  (:copier nil)
                  (:predicate nil))
  (list nil :type list)
  (tail nil :type list))

(declaim (inline enqueue))
(defun enqueue (obj queue)
  "Pushes OBJ to the end of QUEUE."
  (symbol-macrolet ((list (queue-list queue))
                    (tail (queue-tail queue)))
    (if (null list)
        (setf tail (list obj)
              list tail)
        (setf (cdr tail) (list obj)
              tail (cdr tail))))
  queue)

(declaim (inline dequeue))
(defun dequeue (queue)
  "Removes and returns the element at the front of QUEUE. Returns NIL if QUEUE
is empty."
  (pop (queue-list queue)))

(declaim (inline queue-empty-p))
(defun queue-empty-p (queue)
  (null (queue-list queue)))

(declaim (inline queue-peek))
(defun queue-peek (queue)
  (car (queue-list queue)))

(declaim (inline enqueue-front))
(defun enqueue-front (obj queue)
  "Pushes OBJ to the front of QUEUE."
  (symbol-macrolet ((list (queue-list queue))
                    (tail (queue-tail queue)))
    (if (null list)
        (setf tail (list obj)
              list tail)
        (push obj list))
    queue))

;; BEGIN_USE_PACKAGE
(eval-when (:compile-toplevel :load-toplevel :execute)
  (use-package :cp/queue :cl-user))
(eval-when (:compile-toplevel :load-toplevel :execute)
  (use-package :cp/read-fixnum :cl-user))
(in-package :cl-user)

;;;
;;; Body
;;;

(defconstant +inf+ #x7fffffff)
(declaim (ftype (function * (values (simple-array uint31 (*)) &optional)) make-dists))
(defun make-dists (start graph)
  (declare ((simple-array list (*)) graph))
  (let* ((n (ash (length graph) -1))
         (dists (make-array (* n 2) :element-type 'uint31 :initial-element +inf+))
         (que (make-queue)))
    (setf (aref dists start) 0)
    (enqueue start que)
    (loop until (queue-empty-p que)
          for v = (dequeue que)
          do (dolist (next (aref graph v))
               (when (= +inf+ (aref dists next))
                 (setf (aref dists next) (+ (aref dists v) 1))
                 (enqueue next que))))
    dists))

(defun main ()
  (let* ((n (read))
         (m (read))
         (p (read))
         (s (- (read) 1))
         (g (- (read) 1))
         (graph (make-array (* 2 n) :element-type 'list :initial-element nil)))
    (declare (uint31 n m p s g))
    (dotimes (i m)
      (let ((u (- (read-fixnum) 1))
            (v (- (read-fixnum) 1)))
        (push u (aref graph (+ n v)))
        (push (+ n v) (aref graph u))
        (push v (aref graph (+ n u)))
        (push (+ n u) (aref graph v))))
    (let ((dists-s (make-dists s graph))
          (dists-g (make-dists g graph))
          res)
      #>dists-s
      #>dists-g
      (dotimes (v n)
        (let ((slen-even (aref dists-s v))
              (slen-odd (aref dists-s (+ v n)))
              (glen-even (aref dists-g v))
              (glen-odd (aref dists-g (+ v n))))
          (if (evenp p)
              (when (or (<= (+ slen-even glen-even) p)
                        (<= (+ slen-odd glen-odd) p))
                (push (+ v 1) res))
              (when (or (<= (+ slen-even glen-odd) p)
                        (<= (+ slen-odd glen-even) p))
                (push (+ v 1) res)))))
      (if res
          (write-string
           (with-output-to-string (*standard-output* nil :element-type 'base-char)
             (println (length res))
             (map () #'println (nreverse res))))
          (println -1)))))

#-swank (main)

;;;
;;; Test and benchmark
;;;

#+swank
(defun get-clipbrd ()
  (with-output-to-string (out)
    #+os-windows (run-program "powershell.exe" '("-Command" "Get-Clipboard") :output out :search t)
    #+os-unix (run-program "xsel" '("-b" "-o") :output out :search t)))

#+swank (defparameter *this-pathname* (uiop:current-lisp-file-pathname))
#+swank (defparameter *dat-pathname* (uiop:merge-pathnames* "test.dat" *this-pathname*))

#+swank
(defun run (&optional thing (out *standard-output*))
  "THING := null | string | symbol | pathname

null: run #'MAIN using the text on clipboard as input.
string: run #'MAIN using the string as input.
symbol: alias of FIVEAM:RUN!.
pathname: run #'MAIN using the text file as input."
  (let* ((*standard-output* (or out (make-string-output-stream)))
         (res (etypecase thing
                (null
                 (with-input-from-string (*standard-input* (delete #\Return (get-clipbrd)))
                   (main)))
                (string
                 (with-input-from-string (*standard-input* (delete #\Return thing))
                   (main)))
                (symbol (5am:run! thing))
                (pathname
                 (with-open-file (*standard-input* thing)
                   (main))))))
    (if out res (get-output-stream-string *standard-output*))))

#+swank
(defun gen-dat ()
  (uiop:with-output-file (out *dat-pathname* :if-exists :supersede)
    (format out "")))

#+swank
(defun bench (&optional (out (make-broadcast-stream)))
  (time (run *dat-pathname* out)))

;; To run: (5am:run! :sample)
#+swank
(it.bese.fiveam:test :sample
  (it.bese.fiveam:is
   (equal "4
1
2
3
4
"
          (run "6 5 3
1 4
1 2
1 3
1 4
2 5
3 6
" nil)))
  (it.bese.fiveam:is
   (equal "-1
"
          (run "4 3 4
1 4
1 2
2 3
3 4
" nil)))
  (it.bese.fiveam:is
   (equal "6
1
2
4
7
9
10
"
          (run "10 9 5
1 10
7 2
4 9
5 3
1 9
2 9
8 7
8 5
6 4
10 2
" nil))))
0