結果

問題 No.741 AscNumber(Easy)
ユーザー tatt61880
提出日時 2021-02-21 18:56:23
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 2 ms / 2,000 ms
コード長 1,183 bytes
コンパイル時間 2,351 ms
コンパイル使用メモリ 147,756 KB
実行使用メモリ 5,376 KB
最終ジャッジ日時 2024-09-16 11:36:17
合計ジャッジ時間 3,897 ms
ジャッジサーバーID
（参考情報） 		judge3 / judge2
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
other AC * 55
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var n: int :: cui@inputInt()
	var ans: modInt :: (#modInt).init(1, 10 ^ 9 + 7)
	for i(1, 9)
		do ans.mul(n + i)
		do ans.div(i)
	end for
	do cui@print("\{ans}\n")
	
	; val, mod, a, b: 0 to 2 ^ 31.
	class modInt()
		var val: int
		var mod: int
		+func init(val: int, mod: int): modInt
			do me.val :: val % mod
			do me.mod :: mod
			ret me
		end func
		+func add(a: int): modInt
			do me.val :+ a
			if(me.val > me.mod)
				do me.val :- me.mod
			end if
			ret me
		end func
		+func sub(a: int): modInt
			if(me.val < a)
				do me.val :+ me.mod
			end if
			do me.val :- a
			ret me
		end func
		+func mul(a: int): modInt
			do me.val :: me.val * a % me.mod
			ret me
		end func
		+func div(a: int): modInt
			do me.val :: me.val * me.modPow(a, me.mod - 2) % me.mod
			ret me
		end func
		+func pow(a: int): modInt
			do me.val :: me.modPow(me.val, a)
			ret me
		end func
		+*func toStr(): []char
			ret "\{me.val}"
		end func
		
		func modPow(a: int, b: int): int
			if(b = 0)
				ret 1
			end if
			var res: int :: me.modPow(a, b / 2)
			do res :: res * res % me.mod
			if(b % 2 = 1)
				do res :: res * a % me.mod
			end if
			ret res
		end func
	end class
end func
0