結果

問題 No.1251 絶対に間違ってはいけない最小化問題
ユーザー tatt61880
提出日時 2021-03-18 22:22:05
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 423 ms / 2,000 ms
コード長 872 bytes
コンパイル時間 2,576 ms
コンパイル使用メモリ 149,740 KB
実行使用メモリ 22,528 KB
最終ジャッジ日時 2024-09-16 11:53:19
合計ジャッジ時間 21,938 ms
ジャッジサーバーID
（参考情報） 		judge4 / judge1
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 42
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var n: int :: cui@inputInt()
	var a: []int :: #[n]int
	for i(0, n - 1)
		do a[i] :: cui@inputInt()
	end for
	
	var mid: int :: 0
	var b: []int :: #[n]int
	for i(0, n - 1)
		do b[i] :: cui@inputInt()
		do mid :+ b[i]
	end for
	do mid :/ 2
	
	var c: []@C :: #[n]@C
	for i(0, n - 1)
		do c[i] :: (#@C).init(a[i], b[i])
	end for
	do c.sort()
	
	var sum: int :: 0
	var x: int :: 0
	for i(0, n - 1)
		do sum :+ c[i].b
		if(sum >= mid)
			do x :: c[i].a
			break i
		end if
	end for
	
	var ans: int :: 0
	for i(0, n - 1)
		do ans :+ c[i].b * (x - c[i].a).abs()
	end for
	
	do cui@print("\{x} \{ans}\n")
end func

class C()
	+var a: int
	+var b: int
	+func init(a: int, b: int): C
		do me.a :: a
		do me.b :: b
		ret me
	end func
	+*func cmp(t: kuin@Class): int
		if(me.a < (t $ C).a)
			ret - 1
		elif(me.a > (t $ C).a)
			ret 1
		end if
		ret 0
	end func
end class
0