結果

問題 No.133 カードゲーム
ユーザー tatt61880tatt61880
提出日時 2021-03-20 22:43:51
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 2 ms / 5,000 ms
コード長 1,229 bytes
コンパイル時間 2,282 ms
コンパイル使用メモリ 144,884 KB
実行使用メモリ 6,944 KB
最終ジャッジ日時 2024-09-16 11:57:22
合計ジャッジ時間 2,998 ms
ジャッジサーバーID
（参考情報） 		judge2 / judge4
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 4
other AC * 19
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var n: int :: cui@inputInt()
	var a: []int :: #[n]int
	for i(0, n - 1)
		do a[i] :: cui@inputInt()
	end for
	var b: []int :: #[n]int
	for i(0, n - 1)
		do b[i] :: cui@inputInt()
	end for
	
	var idxs: []int :: #[n]int
	for i(0, n - 1)
		do idxs[i] :: i
	end for
	
	var cnt: int :: 0
	var cntWin: int :: 0
	while(nextPermutation(idxs), skip)
		do cnt :+ 1
		var win: int :: 0
		var lose: int :: 0
		for i(0, n - 1)
			if(a[idxs[i]] > b[i])
				do win :+ 1
			else
				do lose :+ 1
			end if
		end for
		if(win > lose)
			do cntWin :+ 1
		end if
	end while
	
	var ans: float :: cntWin $ float / cnt $ float
	do cui@print("\{ans}\n")
	
	func nextPermutation(arr: []int): bool
		var len: int :: ^arr
		var left: int :: len - 2
		while(left >= 0 & arr[left] >= arr[left + 1])
			do left :- 1
		end while
		if(left < 0)
			ret false
		end if
		var right: int :: len - 1
		while(arr[left] >= arr[right])
			do right :- 1
		end while
		var tmp: int :: arr[left]
		do arr[left] :: arr[right]
		do arr[right] :: tmp
		do left :+ 1
		do right :: len - 1
		while(left < right)
			do tmp :: arr[left]
			do arr[left] :: arr[right]
			do arr[right] :: tmp
			do left :+ 1
			do right :- 1
		end while
		ret true
	end func
end func
0