結果

問題 No.1438 Broken Drawers
ユーザー tatt61880tatt61880
提出日時 2021-03-27 12:12:16
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 432 ms / 2,000 ms
コード長 3,924 bytes
コンパイル時間 3,045 ms
コンパイル使用メモリ 149,792 KB
実行使用メモリ 29,184 KB
最終ジャッジ日時 2024-09-16 12:08:15
合計ジャッジ時間 10,798 ms
ジャッジサーバーID
（参考情報） 		judge5 / judge2
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 2 ms
5,248 KB
testcase_01 AC 2 ms
5,376 KB
testcase_02 AC 2 ms
5,376 KB
testcase_03 AC 2 ms
5,376 KB
testcase_04 AC 2 ms
5,376 KB
testcase_05 AC 2 ms
5,376 KB
testcase_06 AC 338 ms
29,056 KB
testcase_07 AC 374 ms
29,056 KB
testcase_08 AC 2 ms
5,376 KB
testcase_09 AC 2 ms
5,376 KB
testcase_10 AC 2 ms
5,376 KB
testcase_11 AC 14 ms
5,376 KB
testcase_12 AC 132 ms
13,312 KB
testcase_13 AC 246 ms
18,944 KB
testcase_14 AC 82 ms
10,368 KB
testcase_15 AC 400 ms
27,004 KB
testcase_16 AC 376 ms
26,368 KB
testcase_17 AC 407 ms
27,520 KB
testcase_18 AC 408 ms
28,032 KB
testcase_19 AC 426 ms
28,160 KB
testcase_20 AC 404 ms
28,416 KB
testcase_21 AC 399 ms
27,756 KB
testcase_22 AC 421 ms
28,544 KB
testcase_23 AC 417 ms
29,056 KB
testcase_24 AC 432 ms
29,184 KB
testcase_25 AC 423 ms
29,056 KB
testcase_26 AC 418 ms
29,056 KB
testcase_27 AC 415 ms
29,184 KB
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var n: int :: cui@inputInt()
	var a: []bool :: #[n + 1]bool
	var map: Map :: #Map
	for i(0, n - 1)
		var key: int :: cui@inputInt()
		var value: int :: i
		do map.add(key, value)
	end for
	var it: Node :: map.begin()
	var ans: int :: 0
	for(1, n)
		var value: int :: it.value
		if(!a[value + 1])
			do a[value] :: true
			do ans :+ 1
		end if
		do it :: it.next
	end for
	do cui@print("\{ans}\n")
	
	class Node()
		+var height: int
		+var key: int
		+var value: int
		+var prev: Node
		+var next: Node
		+var lst: Node
		+var rst: Node
		+func init(key: int, value: int, prev: Node, next: Node): Node
			do me.height :: 1
			do me.key :: key
			do me.value :: value
			do me.prev :: prev
			do me.next :: next
			ret me
		end func
	end class
	func height(t: Node): int
		ret t =& null ?(0, t.height)
	end func
	func bias(t: Node): int
		ret height(t.lst) - height(t.rst)
	end func
	func modHeight(t: Node)
		do t.height :: 1 + lib@max(height(t.lst), height(t.rst))
	end func
	func rotateL(v: Node): Node
		var u: Node :: v.rst
		var t: Node :: u.lst
		do u.lst :: v
		do v.rst :: t
		ret u
	end func
	func rotateR(u: Node): Node
		var v: Node :: u.lst
		var t: Node :: v.rst
		do v.rst :: u
		do u.lst :: t
		ret v
	end func
	func rotateLR(t: Node): Node
		do t.lst :: rotateL(t.lst)
		ret rotateR(t)
	end func
	func rotateRL(t: Node): Node
		do t.rst :: rotateR(t.rst)
		ret rotateL(t)
	end func
	
	; AVL Tree
	class Map()
		var root: Node
		var change: bool
		var lmax: int
		var num: int
		+func size(): int
			ret me.num
		end func
		+func begin(): Node
			var t: Node :: me.root
			while(true)
				if(t.lst =& null)
					ret t
				end if
				do t :: t.lst
			end while
		end func
		+func balanceL(t: Node): Node
			if(!me.change)
				ret t
			end if
			var h: int :: height(t)
			if(bias(t) = 2)
				if(bias(t.lst) >= 0)
					do t :: rotateR(t)
				else
					do t :: rotateLR(t)
				end if
			else
				do modHeight(t)
			end if
			do me.change :: (h <> height(t))
			ret t
		end func
		+func balanceR(t: Node): Node
			if(!me.change)
				ret t
			end if
			var h: int :: height(t)
			if(bias(t) = -2)
				if(bias(t.rst) <= 0)
					do t :: rotateL(t)
				else
					do t :: rotateRL(t)
				end if
			else
				do modHeight(t)
			end if
			do me.change :: (h <> height(t))
			ret t
		end func
		+func add(key: int, value: int)
			do me.root :: me.addSub(me.root, null, key, value)
		end func
		+func addSub(t: Node, root: Node, key: int, value: int): Node
			if(t =& null)
				var a: Node
				do me.change :: true
				if(root =& null)
					do a :: (#Node).init(key, value, null, null)
				elif(key < root.key)
					do a :: (#Node).init(key, value, root.prev, root)
					if(root.prev <>& null)
						do root.prev.next :: a
					end if
					do root.prev :: a
				elif(key > root.key)
					do a :: (#Node).init(key, value, root, root.next)
					if(root.next <>& null)
						do root.next.prev :: a
					end if
					do root.next :: a
				end if
				do me.num :+ 1
				ret a
			elif(key < t.key)
				do t.lst :: me.addSub(t.lst, t, key, value)
				ret me.balanceL(t)
			elif(key > t.key)
				do t.rst :: me.addSub(t.rst, t, key, value)
				ret me.balanceR(t)
			else
				do me.change :: false
				do t.value :: value
				ret t
			end if
		end func
		+func find(key: int): Node
			var t: Node :: me.root
			while loop(t <>& null)
				if(key < t.key)
					do t :: t.lst
				elif(key > t.key)
					do t :: t.rst
				else
					break loop
				end if
			end while
			ret t
		end func
		+func lower_bound(key: int): Node
			var t: Node :: me.root
			if(t =& null)
				ret null
			end if
			while(true)
				if(key < t.key)
					if(t.lst =& null)
						ret t
					end if
					if(key > t.lst.key & t.lst.rst =& null)
						ret t
					end if
					do t :: t.lst
				elif(key > t.key)
					if(t.rst =& null)
						ret null
					end if
					do t :: t.rst
				else
					ret t
				end if
			end while
		end func
	end class
end func
0