結果

問題 No.1092 modular arithmetic
ユーザー tatt61880
提出日時 2021-03-28 08:45:17
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 123 ms / 2,000 ms
コード長 1,401 bytes
コンパイル時間 2,438 ms
コンパイル使用メモリ 148,252 KB
実行使用メモリ 5,376 KB
最終ジャッジ日時 2024-09-16 12:12:15
合計ジャッジ時間 6,325 ms
ジャッジサーバーID
（参考情報） 		judge3 / judge2
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 1
other AC * 32
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var p: int :: cui@inputInt()
	var n: int :: cui@inputInt()
	var a: []int :: #[n]int
	for i(0, n - 1)
		do a[i] :: cui@inputInt()
	end for
	
	var ans: @ModInt :: (#@ModInt).init(a[0], p)
	var s: []char :: cui@input()
	for i(0, n - 2)
		var x: int :: a[i + 1]
		switch(s[i])
		case '+'
			do ans.add(x)
		case '-'
			do ans.sub(x)
		case '*'
			do ans.mul(x)
		case '/'
			do ans.div(x)
		end switch
	end for
	do cui@print("\{ans}\n")
end func

; val, mod, a, b: 0 to 2 ^ 31.
class ModInt()
	+var val: int
	var mod: int
	+*func toStr(): []char
		ret "\{me.val}"
	end func
	+func init(val: int, mod: int): ModInt
		do me.val :: val % mod
		do me.mod :: mod
		ret me
	end func
	+func add(a: int): ModInt
		do me.val :+ a
		if(me.val >= me.mod)
			do me.val :- me.mod
		end if
		ret me
	end func
	+func sub(a: int): ModInt
		if(me.val < a)
			do me.val :+ me.mod
		end if
		do me.val :- a
		ret me
	end func
	+func mul(a: int): ModInt
		do me.val :: me.val * a % me.mod
		ret me
	end func
	+func div(a: int): ModInt
		do me.val :: me.val * me.modPow(a, me.mod - 2) % me.mod
		ret me
	end func
	+func pow(a: int): ModInt
		do me.val :: me.modPow(me.val, a)
		ret me
	end func
	func modPow(a: int, b: int): int
		if(b = 0)
			ret 1
		end if
		var res: int :: me.modPow(a, b / 2)
		do res :: res * res % me.mod
		if(b % 2 = 1)
			do res :: res * a % me.mod
		end if
		ret res
	end func
end class
0