#635277 (Kuin) No.1438 Broken Drawers

提出ソース

結果

問題	No.1438 Broken Drawers
ユーザー	tatt61880
提出日時	2021-03-28 10:53:36
言語	Kuin (KuinC++ v.2021.9.17)
結果	AC
実行時間	435 ms / 2,000 ms
コード長	5,027 bytes
コンパイル時間	3,201 ms
コンパイル使用メモリ	149,360 KB
実行使用メモリ	29,312 KB
最終ジャッジ日時	2024-09-16 12:14:42
合計ジャッジ時間	11,077 ms
ジャッジサーバーID （参考情報）	judge4 / judge6

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	2 ms 6,812 KB
testcase_01	AC	2 ms 6,940 KB
testcase_02	AC	2 ms 6,940 KB
testcase_03	AC	2 ms 6,940 KB
testcase_04	AC	2 ms 6,940 KB
testcase_05	AC	2 ms 6,944 KB
testcase_06	AC	357 ms 29,184 KB
testcase_07	AC	347 ms 29,312 KB
testcase_08	AC	2 ms 6,944 KB
testcase_09	AC	2 ms 6,940 KB
testcase_10	AC	2 ms 6,944 KB
testcase_11	AC	14 ms 6,940 KB
testcase_12	AC	134 ms 13,568 KB
testcase_13	AC	226 ms 19,200 KB
testcase_14	AC	83 ms 10,496 KB
testcase_15	AC	381 ms 27,264 KB
testcase_16	AC	380 ms 26,496 KB
testcase_17	AC	402 ms 27,648 KB
testcase_18	AC	399 ms 28,288 KB
testcase_19	AC	414 ms 28,160 KB
testcase_20	AC	421 ms 28,416 KB
testcase_21	AC	413 ms 27,776 KB
testcase_22	AC	412 ms 28,672 KB
testcase_23	AC	421 ms 29,312 KB
testcase_24	AC	435 ms 29,312 KB
testcase_25	AC	420 ms 29,184 KB
testcase_26	AC	418 ms 29,184 KB
testcase_27	AC	426 ms 29,184 KB

権限があれば一括ダウンロードができます

ソースコード

raw source code

func main()
	var n: int :: cui@inputInt()
	var map: @Map :: #@Map
	for i(0, n - 1)
		var key: int :: cui@inputInt()
		var value: int :: i
		do map.add(key, value)
	end for
	
	var ans: int :: 0
	var a: []bool :: #[n + 1]bool
	var it: @Node :: map.begin()
	for(1, n)
		var value: int :: it.value
		if(!a[value + 1])
			do a[value] :: true
			do ans :+ 1
		end if
		do it :: it.next
	end for
	do cui@print("\{ans}\n")
end func

class Node()
	+var height: int
	+var key: int
	+var value: int
	+var prev: Node
	+var next: Node
	+var lst: Node
	+var rst: Node
	+*func toStr(): []char
		ret me.value.toStr()
	end func
	+func init(key: int, value: int, prev: Node, next: Node): Node
		do me.height :: 1
		do me.key :: key
		do me.value :: value
		do me.prev :: prev
		do me.next :: next
		ret me
	end func
end class

; AVL Tree
class Map()
	var root: @Node
	var change: bool
	var lMax: int
	var lMaxValue: int
	var num: int
	+func size(): int
		ret me.num
	end func
	+func begin(): @Node
		var t: @Node :: me.root
		if(t =& null)
			ret null
		end if
		while(true)
			if(t.lst =& null)
				ret t
			end if
			do t :: t.lst
		end while
	end func
	+func add(key: int, value: int)
		do me.root :: me.addSub(me.root, null, key, value)
	end func
	func addSub(t: @Node, parent: @Node, key: int, value: int): @Node
		if(t =& null)
			var a: @Node
			do me.change :: true
			if(parent =& null)
				do a :: (#@Node).init(key, value, null, null)
			elif(key < parent.key)
				do a :: (#@Node).init(key, value, parent.prev, parent)
				if(parent.prev <>& null)
					do parent.prev.next :: a
				end if
				do parent.prev :: a
			elif(key > parent.key)
				do a :: (#@Node).init(key, value, parent, parent.next)
				if(parent.next <>& null)
					do parent.next.prev :: a
				end if
				do parent.next :: a
			end if
			do me.num :+ 1
			ret a
		elif(key < t.key)
			do t.lst :: me.addSub(t.lst, t, key, value)
			ret me.balanceL(t)
		elif(key > t.key)
			do t.rst :: me.addSub(t.rst, t, key, value)
			ret me.balanceR(t)
		else
			do me.change :: false
			do t.value :: value
			ret t
		end if
	end func
	+func del(key: int)
		do me.root :: me.delSub(me.root, key)
	end func
	func delSub(t: @Node, key: int): @Node
		if(t =& null)
			do me.change :: false
			ret null
		elif(key < t.key)
			do t.lst :: me.delSub(t.lst, key)
			ret me.balanceR(t)
		elif(key > t.key)
			do t.rst :: me.delSub(t.rst, key)
			ret me.balanceL(t)
		else
			do me.num :- 1
			if(t.next <>& null)
				do t.next.prev :: t.prev
			end if
			if(t.prev <>& null)
				do t.prev.next :: t.next
			end if
			if(t.lst =& null)
				do me.change :: true
				ret t.rst
			else
				do t.lst :: me.delSubMax(t.lst)
				do t.key :: me.lMax
				do t.value :: me.lMaxValue
				ret me.balanceR(t)
			end if
		end if
	end func
	func delSubMax(t: @Node): @Node
		if(t.rst <>& null)
			do t.rst :: me.delSubMax(t.rst)
			ret me.balanceL(t)
		else
			do me.change :: true
			do me.lMax :: t.key
			do me.lMaxValue :: t.value
			ret t.lst
		end if
	end func
	+func find(key: int): @Node
		var t: @Node :: me.root
		while loop(t <>& null)
			if(key < t.key)
				do t :: t.lst
			elif(key > t.key)
				do t :: t.rst
			else
				break loop
			end if
		end while
		ret t
	end func
	+func exist(key: int): bool
		ret me.find(key) <>& null
	end func
	+func get(key: int): int
		var t: @Node :: me.find(key)
		ret t =& null ?(0, t.value)
	end func
	+func lower_bound(key: int): @Node
		var t: @Node :: me.root
		if(t =& null)
			ret null
		end if
		while(true)
			if(key < t.key)
				if(t.lst =& null)
					ret t
				end if
				do t :: t.lst
			elif(key > t.key)
				if(t.rst =& null)
					ret t.next
				end if
				do t :: t.rst
			else
				ret t
			end if
		end while
	end func
	func height(t: @Node): int
		ret t =& null ?(0, t.height)
	end func
	func bias(t: @Node): int
		ret me.height(t.lst) - me.height(t.rst)
	end func
	func modHeight(t: @Node)
		do t.height :: 1 + lib@max(me.height(t.lst), me.height(t.rst))
	end func
	func rotateL(v: @Node): @Node
		var u: @Node :: v.rst
		var t: @Node :: u.lst
		do u.lst :: v
		do v.rst :: t
		ret u
	end func
	func rotateR(u: @Node): @Node
		var v: @Node :: u.lst
		var t: @Node :: v.rst
		do v.rst :: u
		do u.lst :: t
		ret v
	end func
	func rotateLR(t: @Node): @Node
		do t.lst :: me.rotateL(t.lst)
		ret me.rotateR(t)
	end func
	func rotateRL(t: @Node): @Node
		do t.rst :: me.rotateR(t.rst)
		ret me.rotateL(t)
	end func
	func balanceL(t: @Node): @Node
		if(!me.change)
			ret t
		end if
		var h: int :: me.height(t)
		if(me.bias(t) = 2)
			if(me.bias(t.lst) >= 0)
				do t :: me.rotateR(t)
			else
				do t :: me.rotateLR(t)
			end if
		else
			do me.modHeight(t)
		end if
		do me.change :: h <> me.height(t)
		ret t
	end func
	func balanceR(t: @Node): @Node
		if(!me.change)
			ret t
		end if
		var h: int :: me.height(t)
		if(me.bias(t) = -2)
			if(me.bias(t.rst) <= 0)
				do t :: me.rotateL(t)
			else
				do t :: me.rotateRL(t)
			end if
		else
			do me.modHeight(t)
		end if
		do me.change :: h <> me.height(t)
		ret t
	end func
end class

yukicoder

結果

テストケース

ソースコード