結果

問題 No.1206 OR, OR, OR......
ユーザー 👑 tatt61880tatt61880
提出日時 2021-04-04 12:38:59
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 3 ms / 2,000 ms
コード長 1,385 bytes
コンパイル時間 2,465 ms
コンパイル使用メモリ 155,056 KB
実行使用メモリ 4,356 KB
最終ジャッジ日時 2023-10-14 18:16:44
合計ジャッジ時間 3,145 ms
ジャッジサーバーID
（参考情報） 		judge12 / judge11
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 2 ms
4,352 KB
testcase_01 AC 2 ms
4,348 KB
testcase_02 AC 2 ms
4,356 KB
testcase_03 AC 3 ms
4,348 KB
testcase_04 AC 3 ms
4,348 KB
testcase_05 AC 3 ms
4,348 KB
testcase_06 AC 3 ms
4,352 KB
testcase_07 AC 3 ms
4,348 KB
testcase_08 AC 3 ms
4,348 KB
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	const mod: int :: 998244353
	var t: int :: cui@inputInt()
	for(1, t)
		var n: int :: cui@inputInt()
		var k: int :: cui@inputInt()
		var ans: @ModInt :: (#@ModInt).init(0, mod)
		var x: @ModInt :: (#@ModInt).init(2, mod)
		do x.pow(n)
		do x.pow(k)
		var y: @ModInt :: (#@ModInt).init(2, mod)
		do y.pow(n - 1)
		do y.pow(k)
		do ans.add(x.val)
		do ans.sub(y.val)
		do ans.mul(n)
		do cui@print("\{ans}\n")
	end for
end func

; val, mod, a, b: 0 to 2 ^ 31.
class ModInt()
	+var val: int
	var mod: int
	+*func toStr(): []char
		ret "\{me.val}"
	end func
	+func init(val: int, mod: int): ModInt
		do me.val :: val % mod
		do me.mod :: mod
		ret me
	end func
	+func add(a: int): ModInt
		do me.val :+ a
		if(me.val >= me.mod)
			do me.val :- me.mod
		end if
		ret me
	end func
	+func sub(a: int): ModInt
		if(me.val < a)
			do me.val :+ me.mod
		end if
		do me.val :- a
		ret me
	end func
	+func mul(a: int): ModInt
		do me.val :: me.val * a % me.mod
		ret me
	end func
	+func div(a: int): ModInt
		do me.val :: me.val * me.modPow(a, me.mod - 2) % me.mod
		ret me
	end func
	+func pow(a: int): ModInt
		do me.val :: me.modPow(me.val, a)
		ret me
	end func
	func modPow(a: int, b: int): int
		if(b = 0)
			ret 1
		end if
		var res: int :: me.modPow(a, b / 2)
		do res :: res * res % me.mod
		if(b % 2 = 1)
			do res :: res * a % me.mod
		end if
		ret res
	end func
end class
0