結果

問題 No.1473 おでぶなおばけさん
ユーザー tatt61880tatt61880
提出日時 2021-06-08 17:27:12
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 1,153 ms / 2,000 ms
コード長 6,959 bytes
コンパイル時間 3,692 ms
コンパイル使用メモリ 153,388 KB
実行使用メモリ 36,224 KB
最終ジャッジ日時 2024-09-16 12:36:29
合計ジャッジ時間 25,215 ms
ジャッジサーバーID
（参考情報） 		judge1 / judge6
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 1 ms
5,248 KB
testcase_01 AC 2 ms
5,376 KB
testcase_02 AC 636 ms
33,664 KB
testcase_03 AC 367 ms
29,312 KB
testcase_04 AC 360 ms
19,968 KB
testcase_05 AC 114 ms
9,856 KB
testcase_06 AC 620 ms
31,232 KB
testcase_07 AC 508 ms
34,176 KB
testcase_08 AC 954 ms
34,304 KB
testcase_09 AC 575 ms
34,304 KB
testcase_10 AC 403 ms
25,984 KB
testcase_11 AC 518 ms
25,600 KB
testcase_12 AC 343 ms
25,728 KB
testcase_13 AC 225 ms
18,432 KB
testcase_14 AC 152 ms
14,464 KB
testcase_15 AC 401 ms
23,936 KB
testcase_16 AC 287 ms
25,344 KB
testcase_17 AC 16 ms
5,504 KB
testcase_18 AC 33 ms
6,400 KB
testcase_19 AC 254 ms
21,344 KB
testcase_20 AC 281 ms
26,496 KB
testcase_21 AC 458 ms
28,032 KB
testcase_22 AC 399 ms
31,744 KB
testcase_23 AC 345 ms
26,880 KB
testcase_24 AC 339 ms
27,392 KB
testcase_25 AC 1,153 ms
31,232 KB
testcase_26 AC 1,151 ms
32,512 KB
testcase_27 AC 237 ms
15,232 KB
testcase_28 AC 746 ms
33,792 KB
testcase_29 AC 494 ms
26,240 KB
testcase_30 AC 688 ms
29,824 KB
testcase_31 AC 679 ms
34,304 KB
testcase_32 AC 445 ms
32,256 KB
testcase_33 AC 357 ms
26,624 KB
testcase_34 AC 185 ms
16,000 KB
testcase_35 AC 171 ms
17,536 KB
testcase_36 AC 445 ms
24,832 KB
testcase_37 AC 605 ms
25,472 KB
testcase_38 AC 66 ms
8,576 KB
testcase_39 AC 298 ms
25,856 KB
testcase_40 AC 289 ms
25,728 KB
testcase_41 AC 323 ms
25,728 KB
testcase_42 AC 307 ms
25,728 KB
testcase_43 AC 393 ms
36,224 KB
testcase_44 AC 399 ms
36,224 KB
testcase_45 AC 406 ms
36,096 KB
testcase_46 AC 297 ms
25,472 KB
testcase_47 AC 377 ms
29,952 KB
testcase_48 AC 341 ms
27,520 KB
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var n: int :: cui@inputInt()
	var m: int :: cui@inputInt()
	var graph: []list<@Edge> :: #[n]list<@Edge>
	for i(0, n - 1)
		do graph[i] :: #list<@Edge>
	end for
	for i(0, m - 1)
		var s: int :: cui@inputInt() - 1
		var t: int :: cui@inputInt() - 1
		var d: int :: cui@inputInt()
		do graph[s].add((#@Edge).init(t, d))
		do graph[t].add((#@Edge).init(s, d))
	end for
	
	var ok: int :: 0
	var ng: int :: 10 ^ 9 + 1
	while((ok - ng).abs() > 1)
		var mid: int :: (ok + ng) / 2
		if(isOk(n, graph, mid))
			do ok :: mid
		else
			do ng :: mid
		end if
	end while
	
	var w: int :: ok
	var dist: int :: distance(n, graph, ok)
	do cui@print("\{w} \{dist}\n")
	
	func isOk(n: int, graph: []list<@Edge>, w: int): bool
		var res: []bool :: #[n]bool
		var qu: queue<int> :: #queue<int>
		do qu.add(0)
		
		while loop(^qu <> 0)
			var u: int :: qu.get()
			do graph[u].head()
			for i(0, ^graph[u] - 1)
				var e: @Edge :: graph[u].get()
				var v: int :: e.dst
				var d: int :: e.d
				if(!res[v] & d >= w)
					do res[v] :: true
					do qu.add(v)
				end if
				do graph[u].next()
			end for
		end while
		ret res[n - 1]
	end func
	
	func distance(n: int, graph: []list<@Edge>, w: int): int
		var dist: []int :: #[n]int
		for i(0, n - 1)
			do dist[i] :: n
		end for
		do dist[0] :: 0
		var pq: @Map :: #@Map
		do pq.add(0 * n + 0, 0)
		
		while loop(pq.size() <> 0)
			var p: @Node :: pq.begin()
			var key: int :: p.key
			var u: int :: p.value
			do pq.del(key)
			var dis: int :: key / n
			if(dis > dist[u])
				skip loop
			end if
			
			do graph[u].head()
			for i(0, ^graph[u] - 1)
				var e: @Edge :: graph[u].get()
				var v: int :: e.dst
				var d: int :: e.d
				if(d >= w & dist[v] > dist[u] + 1)
					do dist[v] :: dist[u] + 1
					do pq.add(dist[v] * n + v, v)
				end if
				do graph[u].next()
			end for
		end while
		ret dist[n - 1]
	end func
end func

class Edge()
	+var dst: int
	+var d: int
	+func init(dst: int, d: int): @Edge
		do me.dst :: dst
		do me.d :: d
		ret me
	end func
end class

class Node()
	+var height: int
	+var key: int
	+var value: int
	+var prev: Node
	+var next: Node
	+var lst: Node
	+var rst: Node
	+*func toStr(): []char
		ret me.value.toStr()
	end func
	+func init(key: int, value: int, prev: Node, next: Node): Node
		do me.height :: 1
		do me.key :: key
		do me.value :: value
		do me.prev :: prev
		do me.next :: next
		ret me
	end func
end class

; AVL Tree
class Map()
	var root: @Node
	var change: bool
	var lMax: int
	var lMaxValue: int
	var num: int
	+*func toStr(): []char
		ret me.toGraph(me.root, "", "")
	end func
	func toGraph(t: @Node, head: []char, bar: []char): []char
		var res: []char :: ""
		if(t <>& null)
			do res :~ me.toGraph(t.rst, head ~ "  ", "/")
			do res :~ head ~ bar ~ t.key.toStr() ~ "\n"
			do res :~ me.toGraph(t.lst, head ~ "  ", "`")
		end if
		ret res
	end func
	+func size(): int
		ret me.num
	end func
	+func begin(): @Node
		var t: @Node :: me.root
		if(t =& null)
			ret null
		end if
		while(true)
			if(t.lst =& null)
				ret t
			end if
			do t :: t.lst
		end while
	end func
	+func add(key: int, value: int)
		do me.root :: me.addSub(me.root, null, key, value)
	end func
	func addSub(t: @Node, parent: @Node, key: int, value: int): @Node
		if(t =& null)
			var a: @Node
			do me.change :: true
			if(parent =& null)
				do a :: (#@Node).init(key, value, null, null)
			elif(key < parent.key)
				do a :: (#@Node).init(key, value, parent.prev, parent)
				if(parent.prev <>& null)
					do parent.prev.next :: a
				end if
				do parent.prev :: a
			elif(key > parent.key)
				do a :: (#@Node).init(key, value, parent, parent.next)
				if(parent.next <>& null)
					do parent.next.prev :: a
				end if
				do parent.next :: a
			end if
			do me.num :+ 1
			ret a
		elif(key < t.key)
			do t.lst :: me.addSub(t.lst, t, key, value)
			ret me.balanceL(t)
		elif(key > t.key)
			do t.rst :: me.addSub(t.rst, t, key, value)
			ret me.balanceR(t)
		else
			do me.change :: false
			do t.value :: value
			ret t
		end if
	end func
	+func del(key: int)
		do me.root :: me.delSub(me.root, key)
	end func
	func delSub(t: @Node, key: int): @Node
		if(t =& null)
			do me.change :: false
			ret null
		elif(key < t.key)
			do t.lst :: me.delSub(t.lst, key)
			ret me.balanceR(t)
		elif(key > t.key)
			do t.rst :: me.delSub(t.rst, key)
			ret me.balanceL(t)
		else
			do me.num :- 1
			if(t.next <>& null)
				do t.next.prev :: t.prev
			end if
			if(t.prev <>& null)
				do t.prev.next :: t.next
			end if
			if(t.lst =& null)
				do me.change :: true
				ret t.rst
			else
				do t.lst :: me.delSubMax(t.lst)
				do t.key :: me.lMax
				do t.value :: me.lMaxValue
				ret me.balanceR(t)
			end if
		end if
	end func
	func delSubMax(t: @Node): @Node
		if(t.rst <>& null)
			do t.rst :: me.delSubMax(t.rst)
			ret me.balanceL(t)
		else
			do me.change :: true
			do me.lMax :: t.key
			do me.lMaxValue :: t.value
			ret t.lst
		end if
	end func
	+func find(key: int): @Node
		var t: @Node :: me.root
		while loop(t <>& null)
			if(key < t.key)
				do t :: t.lst
			elif(key > t.key)
				do t :: t.rst
			else
				break loop
			end if
		end while
		ret t
	end func
	+func exist(key: int): bool
		ret me.find(key) <>& null
	end func
	+func get(key: int): int
		var t: @Node :: me.find(key)
		ret t =& null ?(0, t.value)
	end func
	+func lower_bound(key: int): @Node
		var t: @Node :: me.root
		if(t =& null)
			ret null
		end if
		while(true)
			if(key < t.key)
				if(t.lst =& null)
					ret t
				end if
				do t :: t.lst
			elif(key > t.key)
				if(t.rst =& null)
					ret t.next
				end if
				do t :: t.rst
			else
				ret t
			end if
		end while
	end func
	func height(t: @Node): int
		ret t =& null ?(0, t.height)
	end func
	func bias(t: @Node): int
		ret me.height(t.lst) - me.height(t.rst)
	end func
	func modHeight(t: @Node)
		do t.height :: 1 + lib@max(me.height(t.lst), me.height(t.rst))
	end func
	func rotateL(v: @Node): @Node
		var u: @Node :: v.rst
		var t: @Node :: u.lst
		do u.lst :: v
		do v.rst :: t
		ret u
	end func
	func rotateR(u: @Node): @Node
		var v: @Node :: u.lst
		var t: @Node :: v.rst
		do v.rst :: u
		do u.lst :: t
		ret v
	end func
	func rotateLR(t: @Node): @Node
		do t.lst :: me.rotateL(t.lst)
		ret me.rotateR(t)
	end func
	func rotateRL(t: @Node): @Node
		do t.rst :: me.rotateR(t.rst)
		ret me.rotateL(t)
	end func
	func balanceL(t: @Node): @Node
		if(!me.change)
			ret t
		end if
		var h: int :: me.height(t)
		if(me.bias(t) = 2)
			if(me.bias(t.lst) >= 0)
				do t :: me.rotateR(t)
			else
				do t :: me.rotateLR(t)
			end if
		else
			do me.modHeight(t)
		end if
		do me.change :: h <> me.height(t)
		ret t
	end func
	func balanceR(t: @Node): @Node
		if(!me.change)
			ret t
		end if
		var h: int :: me.height(t)
		if(me.bias(t) = -2)
			if(me.bias(t.rst) <= 0)
				do t :: me.rotateL(t)
			else
				do t :: me.rotateRL(t)
			end if
		else
			do me.modHeight(t)
		end if
		do me.change :: h <> me.height(t)
		ret t
	end func
end class
0