結果

問題 No.1508 Avoid being hit
コンテスト
ユーザー te-sh
提出日時 2021-06-08 22:35:43
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 104 ms / 3,000 ms
コード長 4,894 bytes
コンパイル時間 1,444 ms
コンパイル使用メモリ 204,020 KB
実行使用メモリ 14,844 KB
最終ジャッジ日時 2024-06-22 11:27:57
合計ジャッジ時間 5,174 ms
ジャッジサーバーID
（参考情報） 		judge4 / judge5
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 43
権限があれば一括ダウンロードができます

ソースコード

diff # 

// URL: https://yukicoder.me/problems/no/1508

import std;

version(unittest) {} else
void main()
{
  int N, Q; io.getV(N, Q);
  int[] A; io.getA(Q, A); --A[];
  int[] B; io.getA(Q, B); --B[];

  auto s = new Section!int[][](Q+1);
  s[0] ~= section(0, N);

  foreach (i, Ai, Bi; lockstep(A, B)) {
    if (Ai > Bi) swap(Ai, Bi);
    foreach (si; s[i]) {
      auto t = section(max(0, si.start-1), min(N, si.end+1));

      auto avoidHit(Section!int t, int a)
      {
        if (t.include(a)) {
          if (t.length == 1) return section(-1, 0);
          if (a == t.start) {
            t = section(t.start+1, t.end);
          } else if (a == t.end-1) {
            t = section(t.start, t.end-1);
          } else {
            auto ta = section(t.start, a);
            if (!s[i+1].empty && mergeable(s[i+1].back, ta))
              s[i+1][$-1] = merge(s[i+1][$-1], ta);
            else
              s[i+1] ~= ta;
            t = section(a+1, t.end);
          }
        }
        return t;
      }

      t = avoidHit(t, Ai);
      if (t.start == -1) continue;
      t = avoidHit(t, Bi);
      if (t.start == -1) continue;

      if (!s[i+1].empty && mergeable(s[i+1].back, t))
        s[i+1][$-1] = merge(s[i+1][$-1], t);
      else
        s[i+1] ~= t;
    }
  }

  if (s[$-1].empty) {
    io.put("NO");
  } else {
    auto r = new int[](Q+1), i = 0;
    for (; i < N; ++i)
      if (s[$-1].any!(si => si.include(i)))
        break;
    r[0] = i;

    foreach (j; 0..Q) {
      for (auto k = i-1; k <= i+1; ++k)
        if (s[$-j-2].any!(si => si.include(k))) {
          r[j+1] = i = k;
          break;
        }
    }

    io.put("YES");
    foreach_reverse (ri; r) io.put(ri+1);
  }
}

struct Section(T)
{
  T start, end;

  pure nothrow @nogc @safe
  {
    this(T start, T end)
      in { assert(start < end); }
    do
    {
      this.start = start;
      this.end = end;
    }

    auto length() { return end - start; }
  }
}

pure nothrow @nogc @safe
{
  auto section(T)(T start, T end)
    in { assert(start < end); }
  do
  {
    return Section!T(start, end);
  }

  bool include(T)(Section!T a, T b)
  {
    return a.start <= b && b < a.end;
  }
  bool overlaped(T)(Section!T a, Section!T b)
  {
    return a.start < b.end && a.end > b.start;
  }
  bool mergeable(T)(Section!T a, Section!T b)
  {
    return overlaped(a, b) || a.start == b.end || a.end == b.start;
  }
  auto merge(T)(Section!T a, Section!T b)
    in { assert(mergeable(a, b)); }
  do
  {
    return section(min(a.start, b.start), max(a.end, b.end));
  }
}

auto io = IO!()();
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    putMain!conf(v);
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(alias conf, T...)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      foreach (i, w; v) {
        putOne!conf(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(alias conf, T)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      static if (isInputRange!T && !isSomeString!T) putRange!conf(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(alias conf, T)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      auto w = v;
      while (!w.empty) {
        putOne!conf(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}
0