#667090 (D) No.816 Beautiful tuples

• 問題: No.816 Beautiful tuples
• ユーザー: te-sh
• 提出日時: 2021-06-17 14:09:18
• 言語: D (dmd 2.106.1)
• 結果: AC
• 実行時間: 2 ms / 1,500 ms
• コード長: 5,450 bytes
• コンパイル時間: 1,626 ms
• コンパイル使用メモリ: 198,596 KB
• 実行使用メモリ: 6,944 KB
• 最終ジャッジ日時: 2024-06-22 11:33:49
• 合計ジャッジ時間: 2,278 ms
• ジャッジサーバーID （参考情報）: judge5 / judge1

入力	結果	実行時間; 実行使用メモリ
testcase_00	AC	1 ms; 6,812 KB
testcase_01	AC	1 ms; 6,940 KB
testcase_02	AC	1 ms; 6,944 KB
testcase_03	AC	1 ms; 6,944 KB
testcase_04	AC	2 ms; 6,944 KB
testcase_05	AC	1 ms; 6,940 KB
testcase_06	AC	1 ms; 6,940 KB
testcase_07	AC	2 ms; 6,940 KB
testcase_08	AC	2 ms; 6,940 KB
testcase_09	AC	1 ms; 6,940 KB
testcase_10	AC	1 ms; 6,944 KB
testcase_11	AC	1 ms; 6,944 KB
testcase_12	AC	1 ms; 6,940 KB
testcase_13	AC	1 ms; 6,944 KB
testcase_14	AC	1 ms; 6,944 KB

ソースコード

// URL: https://yukicoder.me/problems/no/816

import std;

version(unittest) {} else
void main()
{
  int A, B; io.getV(A, B);

  auto pf = primeFactorSqrtOf(A+B);
  foreach (C; pf.divisors(A+B))
    if (A != C && B != C && (A+C)%B == 0 && (B+C)%A == 0)
      io.put!"{exit: true}"(C);

  io.put(-1);
}

pragma(inline)
{
  auto lowerBoundBy(alias conv = "a", alias comp = "a<b", R, T)(const R a, const T v)
  {
    return a.sortedTuple!(conv, comp).lowerBound(tuple(a.front, v)).map!"a[0]";
  }

  auto upperBoundBy(alias conv = "a", alias comp = "a<b", R, T)(const R a, const T v)
  {
    return a.sortedTuple!(conv, comp).upperBound(tuple(a.front, v)).map!"a[0]";
  }

  auto sortedTuple(alias conv = "a", alias comp = "a<b", R)(const R a)
  {
    alias convFun = unaryFun!conv, compFun = binaryFun!comp;
    return a.map!(e => tuple(e, convFun(e))).assumeSorted!((a, b) => compFun(a[1], b[1]));
  }
}

pure nothrow @nogc @safe
{
  T isqrt(T)(T n)
    if (is(T == int) || is(T == long))
  {
    static if (is(T == int)) auto max = 46_341;
    else static if (is(T == long)) auto max = 3_037_000_500L;
    return iota(T(0), max).lowerBoundBy!("a^^2", "a<=b")(n).back;
  }
  T icbrt(T)(T n)
    if (is(T == int) || is(T == long))
  {
    static if (is(T == int)) auto max = 1_291;
    else static if (is(T == long)) auto max = 2_097_152L;
    return iota(T(0), max).lowerBoundBy!("a^^3", "a<=b")(n).back;
  }
}

struct PrimeFactor
{
  struct Factor(T)
  {
    T prime;
    int exp;
  }

  const int n;
  int[] primes;

  pure nothrow
  {
    this(int n)
    {
      this.n = n;

      auto sieve = BitArray();
      sieve.length((n+1)/2);
      sieve = ~sieve;

      foreach (p; 1..(n.isqrt-1)/2+1)
        if (sieve[p])
          for (auto q = p*3+1; q < (n+1)/2; q += p*2+1)
            sieve[q] = false;

      primes = sieve.bitsSet.map!(p => cast(int)p*2+1).array;
      primes[0] = 2;
    }
  }

  pure nothrow @safe
  {
    Factor!T[] div(T)(T x) const
      if (isIntegral!T)
      in { assert(x > 0 && x.isqrt <= n); }
    do
    {
      Factor!T[] factors;
      auto t = isqrt(x);
      foreach (p; primes) {
        if (p > t) break;
        auto c = 0;
        for (; x%p == 0; x /= p) ++c;
        if (c > 0) factors ~= Factor!T(p, c);
        if (x == 1) break;
      }
      if (x > 1) factors ~= [Factor!T(x, 1)];
      return factors;
    }

    T[] divisors(T)(T x) const
      if (isIntegral!T)
      in { assert(x > 0 && x.isqrt <= n); }
    do
    {
      auto factors = div(x);
      auto r = divisorsProc(factors, 0, 1);
      r.sort();
      return r;
    }
  }

  private
  {
    pure nothrow @safe
    {
      T[] divisorsProc(T)(const Factor!T[] factors, int i, T c) const
      {
        if (i == factors.length) return [c];
        T[] r;
        foreach (j; 0..factors[i].exp+1)
          r ~= divisorsProc(factors, i+1, c*factors[i].prime^^j);
        return r;
      }
    }
  }
}

pure nothrow
{
  auto primeFactor(int n)
  {
    return PrimeFactor(n);
  }

  auto primeFactorSqrtOf(T)(T n)
    if (isIntegral!T)
  {
    return PrimeFactor(cast(int)n.isqrt);
  }
}

auto io = IO!()();
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    putMain!conf(v);
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(alias conf, T...)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      foreach (i, w; v) {
        putOne!conf(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(alias conf, T)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      static if (isInputRange!T && !isSomeString!T) putRange!conf(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(alias conf, T)(T v)
    {
      mixin("const PutConf c = "~conf~";");
      auto w = v;
      while (!w.empty) {
        putOne!conf(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}