結果

問題 No.1513 simple 門松列 problem
コンテスト
ユーザー te-sh
提出日時 2021-07-03 14:06:05
言語 Crystal
(1.14.0)
結果
AC  
実行時間 826 ms / 3,000 ms
コード長 4,945 bytes
コンパイル時間 11,435 ms
コンパイル使用メモリ 295,332 KB
実行使用メモリ 200,468 KB
最終ジャッジ日時 2024-06-30 05:58:04
合計ジャッジ時間 16,484 ms
ジャッジサーバーID
（参考情報） 		judge5 / judge2
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 18
権限があれば一括ダウンロードができます

ソースコード

diff # 

def main(io)
  n, k = io.get2

  dp1 = Array.new(n) { Array.new(k) { Array.new(k, Mint.zero) } }
  dp2 = Array.new(n) { Array.new(k) { Array.new(k, Mint.zero) } }
  (0...k).each do |j|
    (0...k).each do |l|
      if j != l
        dp1[1][j][l] = Mint.new(1)
        dp2[1][j][l] = Mint.new(j+l)
      end
    end
  end

  (1...n-1).each do |i|
    (0...k).each do |j|
      c1 = CumulativeSum.new(Array.new(k) { |l| dp1[i][l][j] })
      c2 = CumulativeSum.new(Array.new(k) { |l| dp2[i][l][j] })
      (0...k).each do |l|
        if j > l
          dp1[i+1][j][l] = c1[...j] - dp1[i][l][j]
          dp2[i+1][j][l] = c2[...j] - dp2[i][l][j] + dp1[i+1][j][l]*l
        elsif j < l
          dp1[i+1][j][l] = c1[j+1...] - dp1[i][l][j]
          dp2[i+1][j][l] = c2[j+1...] - dp2[i][l][j] + dp1[i+1][j][l]*l
        end
      end
    end
  end

  ans1 = dp1[-1].map(&.sum).sum
  ans2 = dp2[-1].map(&.sum).sum
  io.put ans1, ans2
end

class CumulativeSum(T)
  def initialize(a : Array(T))
    @n = a.size
    @s = Array(T).new(@n+1, T.additive_identity)
    (0...@n).each do |i|
      @s[i+1] = @s[i] + a[i]
    end
  end

  getter n : Int32

  def [](r : Range)
    b = r.begin
    b = if b.nil?
          0
        elsif b < 0
          @n + b
        else
          b
        end

    e = r.end
    e = if e.nil?
          @n
        elsif e < 0
          r.excludes_end? ? @n + e : @n + e + 1
        else
          r.excludes_end? ? e : e + 1
        end

    @s[e] - @s[b]
  end
end

macro min_u(a, b)
  {{a}} = Math.min({{a}}, {{b}})
end

macro max_u(a, b)
  {{a}} = Math.max({{a}}, {{b}})
end

def isqrt(n : Int32)
  m = 46340
  r = (1..m).bsearch { |i| i**2 > n }
  r.nil? ? m : r - 1
end

def powr(a : T, n : Int, i : T = T.multiplicative_identity) forall T
  powr(a, n, i) { |a, b| a * b }
end

def powr(a : T, n : Int, i : T = T.multiplicative_identity, &block) forall T
  return i if n == 0
  r, b = i, a
  while n > 0
    r = yield r, b if n.bit(0) == 1
    b = yield b, b
    n >>= 1
  end
  r
end

def ext_gcd(a : T, b : T) forall T
  if a == 0
    {b, T.new(0), T.new(1)}
  else
    g, x, y = ext_gcd(b%a, a)
    {g, y-(b//a)*x, x}
  end
end

abstract struct ModInt < Number
  def self.zero
    self.new(0)
  end

  def self.additive_identity
    self.new(0)
  end

  def self.multiplicative_identity
    self.new(1)
  end

  def initialize(v : Int)
    @v = (v % @@mod).to_i64
  end

  def_hash @@mod, @v

  def to_s
    @v.to_s
  end

  def to_s(io : IO) : Nil
    @v.to_s(io)
  end

  getter v : Int64

  delegate to_i, to: @v

  def ==(r : self)
    @v == r.v
  end

  def ==(r : Int)
    @v == (r % @@mod)
  end

  def - : self
    m(-@v)
  end

  def +(r : self)
    m(@v + r.v)
  end

  def +(r : Int)
    self + m(r)
  end

  def -(r : self)
    m(@v - r.v)
  end

  def -(r : Int)
    self - m(r)
  end

  def *(r : self)
    m(@v * r.v)
  end

  def *(r : Int)
    self * m(r)
  end

  def //(r : self)
    self * r.inv
  end

  def //(r : Int)
    self // m(r)
  end

  def **(n : Int)
    powr(self, n)
  end

  def inv
    m(ext_gcd(@v.to_i32, @@mod)[1])
  end


  private def m(v : Int)
    self.class.new(v)
  end
end
struct Mint < ModInt; @@mod : Int32 = 998244353; end

class ProconIO
  def initialize
    @buf = [] of String
    @index = 0
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  def get(*ks : T.class) forall T
    ks.map { |k| get_v(k) }
  end

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({% for j in (1..i) %}k{% if j < i %}, {% end %}{% end %})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  def get_c(n : Int, *ks : T.class) forall T
    a = Array.new(n) { get(*ks) }
    ks.map_with_index { |_, i| a.map { |e| e[i] } }
  end

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {% for j in (1..i) %}k{% if j < i %}, {% end %}{% end %})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  def put(*vs)
    vs.each.with_index do |v, i|
      put_v(v)
      print i < vs.size - 1 ? " " : "\n"
    end
  end

  def put_e(*vs)
    put(*vs)
    exit
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    if @buf.size == @index
      @buf = read_line.split
      @index = 0
    end
    v = @buf[@index]
    @index += 1
    v
  end

  private def put_v(vs : Enumerable)
    vs.each_with_index do |v, i|
      print v
      print " " if i < vs.size - 1
    end
  end

  private def put_v(v)
    print v
  end
end

main(ProconIO.new)
0