#672909 (Crystal) No.827 総神童数

提出ソース

結果

問題	No.827 総神童数
ユーザー	te-sh
提出日時	2021-07-03 17:27:00
言語	Crystal (1.11.2)
結果	AC
実行時間	197 ms / 2,000 ms
コード長	6,169 bytes
コンパイル時間	16,623 ms
コンパイル使用メモリ	295,896 KB
実行使用メモリ	28,032 KB
最終ジャッジ日時	2024-06-30 09:37:12
合計ジャッジ時間	21,263 ms
ジャッジサーバーID （参考情報）	judge2 / judge3

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	2 ms 5,248 KB
testcase_01	AC	2 ms 5,376 KB
testcase_02	AC	1 ms 5,376 KB
testcase_03	AC	2 ms 5,376 KB
testcase_04	AC	2 ms 5,376 KB
testcase_05	AC	2 ms 5,376 KB
testcase_06	AC	1 ms 5,376 KB
testcase_07	AC	2 ms 5,376 KB
testcase_08	AC	2 ms 5,376 KB
testcase_09	AC	162 ms 28,032 KB
testcase_10	AC	47 ms 12,800 KB
testcase_11	AC	4 ms 5,376 KB
testcase_12	AC	19 ms 7,168 KB
testcase_13	AC	131 ms 22,912 KB
testcase_14	AC	6 ms 5,376 KB
testcase_15	AC	45 ms 12,160 KB
testcase_16	AC	145 ms 23,040 KB
testcase_17	AC	175 ms 26,236 KB
testcase_18	AC	55 ms 14,080 KB
testcase_19	AC	197 ms 27,008 KB
testcase_20	AC	138 ms 21,376 KB
testcase_21	AC	81 ms 17,024 KB
testcase_22	AC	149 ms 22,784 KB
testcase_23	AC	3 ms 5,376 KB
testcase_24	AC	167 ms 24,560 KB
testcase_25	AC	123 ms 20,224 KB
testcase_26	AC	180 ms 24,448 KB
testcase_27	AC	95 ms 18,432 KB
testcase_28	AC	97 ms 18,176 KB
testcase_29	AC	70 ms 15,488 KB
testcase_30	AC	20 ms 6,912 KB
testcase_31	AC	55 ms 12,928 KB
testcase_32	AC	52 ms 12,800 KB
testcase_33	AC	193 ms 26,336 KB
testcase_34	AC	177 ms 24,576 KB
testcase_35	AC	55 ms 13,184 KB
testcase_36	AC	84 ms 16,640 KB
testcase_37	AC	123 ms 20,096 KB
testcase_38	AC	189 ms 26,024 KB

権限があれば一括ダウンロードができます

ソースコード

raw source code

def main(io)
  n = io.get
  g = Graph.new(n)
  (n-1).times do
    u, v = io.get2; u -= 1; v -= 1
    g.add_edge_b(u, v)
  end
  t = g.tree(0)

  f = Fact(Mint).new(n)
  r = Mint.zero
  (0...n).each do |u|
    d = t.depth_of(u)
    r += f.combi(n, d+1) * f.fact(d) * f.fact(n-d-1)
  end

  io.put r
end

class Graph
  alias Node = Int32

  def initialize(@n : Node)
    @g = Array(Array(Node)).new(@n) { [] of Node }
  end

  getter n : Node

  delegate :[], to: @g

  def add_edge(u : Node, v : Node)
    @g[u] << v
  end

  def add_edge_b(u : Node, v : Node)
    @g[u] << v
    @g[v] << u
  end
end

class GraphW(T)
  alias Node = Int32

  struct Edge(T)
    def initialize(@src : Node, @dst : Node, @wt : T)
    end

    getter src : Node, dst : Node

    getter wt : T
  end
      
  def initialize(@n : Node, @inf = 10**9)
    @g = Array(Array(Edge(T))).new(@n) { [] of Edge(T) }
  end

  getter n : Node

  getter inf : T

  delegate :[], to: @g

  def add_edge(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
  end

  def add_edge_b(u : Node, v : Node, wt : T)
    @g[u] << Edge.new(u, v, wt)
    @g[v] << Edge.new(v, u, wt)
  end
end

class Tree
  alias Node = Graph::Node

  def initialize(@g : Graph, @root : Node)
    n = @g.n
    @parent = Array(Node).new(n, 0)
    @depth = Array(Int32).new(n, -1)
    @dfs_order = Array(Node).new

    s = [{@root, @root}]
    until s.empty?
      u, p = s.pop

      @parent[u] = p
      @depth[u] = @depth[p] + 1
      @dfs_order << u

      @g[u].each do |v|
        s.push({v, u}) if v != p
      end
    end

    @size = Array(Int32).new(n, 1)
    @dfs_order.reverse_each do |u|
      @size[@parent[u]] += @size[u] if u != @root
    end
  end

  getter root : Node

  getter dfs_order : Array(Node)

  def parent_of(u : Node)
    @parent[u]
  end

  def depth_of(u : Node)
    @depth[u]
  end

  def size_of(u : Node)
    @size[u]
  end

  def children_of(u : Node)
    @g[u].reject { |v| v == @parent[u] }
  end
end

class Graph
  def tree(root)
    Tree.new(self, root)
  end
end

class Fact(T)
  def initialize(@n : Int32)
    @table = Array(T).new(@n+1, T.new(0))
    @table[0] = T.new(1)
    (1..@n).each do |i|
      @table[i] = @table[i-1] * i
    end

    @inv_table = Array(T).new(@n+1, T.new(0))
    @inv_table[@n] = T.new(1) // @table[@n]
    (1..@n).reverse_each do |i|
      @inv_table[i-1] = @inv_table[i] * i
    end
  end

  getter table : Array(T)

  getter inv_table : Array(T)

  def fact(n : Int)
    @table[n]
  end

  def perm(n : Int, r : Int)
    @table[n] * @inv_table[n-r]
  end

  def combi(n : Int, r : Int)
    @table[n] * @inv_table[r] * @inv_table[n-r]
  end

  def homo(n : Int, r : Int)
    combi(n+r-1, r)
  end
end

macro min_u(a, b)
  {{a}} = Math.min({{a}}, {{b}})
end

macro max_u(a, b)
  {{a}} = Math.max({{a}}, {{b}})
end

def isqrt(n : Int32)
  m = 46340
  r = (1..m).bsearch { |i| i**2 > n }
  r.nil? ? m : r - 1
end

def powr(a : T, n : Int, i : T = T.multiplicative_identity) forall T
  powr(a, n, i) { |a, b| a * b }
end

def powr(a : T, n : Int, i : T = T.multiplicative_identity, &block) forall T
  return i if n == 0
  r, b = i, a
  while n > 0
    r = yield r, b if n.bit(0) == 1
    b = yield b, b
    n >>= 1
  end
  r
end

def ext_gcd(a : T, b : T) forall T
  if a == 0
    {b, T.new(0), T.new(1)}
  else
    g, x, y = ext_gcd(b%a, a)
    {g, y-(b//a)*x, x}
  end
end

abstract struct ModInt < Number
  def self.zero
    self.new(0)
  end

  def self.additive_identity
    self.new(0)
  end

  def self.multiplicative_identity
    self.new(1)
  end

  def initialize(v : Int)
    @v = (v % @@mod).to_i64
  end

  def_hash @@mod, @v

  def to_s
    @v.to_s
  end

  def to_s(io : IO) : Nil
    @v.to_s(io)
  end

  getter v : Int64

  delegate to_i, to: @v

  def ==(r : self)
    @v == r.v
  end

  def ==(r : Int)
    @v == (r % @@mod)
  end

  def - : self
    m(-@v)
  end

  def +(r : self)
    m(@v + r.v)
  end

  def +(r : Int)
    self + m(r)
  end

  def -(r : self)
    m(@v - r.v)
  end

  def -(r : Int)
    self - m(r)
  end

  def *(r : self)
    m(@v * r.v)
  end

  def *(r : Int)
    self * m(r)
  end

  def //(r : self)
    self * r.inv
  end

  def //(r : Int)
    self // m(r)
  end

  def **(n : Int)
    powr(self, n)
  end

  def inv
    m(ext_gcd(@v.to_i32, @@mod)[1])
  end


  private def m(v : Int)
    self.class.new(v)
  end
end
struct Mint < ModInt; @@mod : Int32 = 10**9+7; end

class ProconIO
  def initialize
    @buf = [] of String
    @index = 0
  end

  def get(k : T.class = Int32) forall T
    get_v(k)
  end

  def get(*ks : T.class) forall T
    ks.map { |k| get_v(k) }
  end

  macro define_getn
    {% for i in (2..9) %}
      def get{{i}}(k : T.class = Int32) forall T
        get({% for j in (1..i) %}k{% if j < i %}, {% end %}{% end %})
      end
    {% end %}
  end
  define_getn

  def get_a(n : Int, k : T.class = Int32) forall T
    Array.new(n) { get_v(k) }
  end

  def get_c(n : Int, k : T.class = Int32) forall T
    get_a(n, k)
  end

  def get_c(n : Int, *ks : T.class) forall T
    a = Array.new(n) { get(*ks) }
    ks.map_with_index { |_, i| a.map { |e| e[i] } }
  end

  macro define_getn_c
    {% for i in (2..9) %}
      def get{{i}}_c(n : Int, k : T.class = Int32) forall T
        get_c(n, {% for j in (1..i) %}k{% if j < i %}, {% end %}{% end %})
      end
    {% end %}
  end
  define_getn_c

  def get_m(r : Int, c : Int, k : T.class = Int32) forall T
    Array.new(r) { get_a(c, k) }
  end

  def put(*vs)
    vs.each.with_index do |v, i|
      put_v(v)
      print i < vs.size - 1 ? " " : "\n"
    end
  end

  def put_e(*vs)
    put(*vs)
    exit
  end


  private def get_v(k : Int32.class); get_token.to_i32; end
  private def get_v(k : Int64.class); get_token.to_i64; end
  private def get_v(k : String.class); get_token; end

  private def get_token
    if @buf.size == @index
      @buf = read_line.split
      @index = 0
    end
    v = @buf[@index]
    @index += 1
    v
  end

  private def put_v(vs : Enumerable)
    vs.each_with_index do |v, i|
      print v
      print " " if i < vs.size - 1
    end
  end

  private def put_v(v)
    print v
  end
end

main(ProconIO.new)

yukicoder

結果

テストケース

ソースコード