結果

問題 No.1630 Sorting Integers (Greater than K)
コンテスト
ユーザー tatt61880
提出日時 2021-07-30 21:33:08
言語 Kuin
(KuinC++ v.2021.9.17)
結果
AC  
実行時間 292 ms / 2,000 ms
コード長 1,868 bytes
コンパイル時間 2,358 ms
コンパイル使用メモリ 146,364 KB
実行使用メモリ 6,692 KB
最終ジャッジ日時 2024-09-16 12:41:23
合計ジャッジ時間 5,098 ms
ジャッジサーバーID
（参考情報） 		judge4 / judge5
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 5
other AC * 22
権限があれば一括ダウンロードができます

ソースコード

diff # 

func main()
	var n: int :: cui@inputInt()
	var k: []char :: cui@input()
	var a: []int :: #[10]int
	for i(1, 9)
		do a[i] :: cui@inputInt()
	end for
	
	if(n < ^k)
		do cui@print("-1\n")
		ret
	elif(n > ^k)
		for i(1, 9)
			for(1, a[i])
				do cui@print("\{i}")
			end for
		end for
		do cui@print("\n")
		ret
	end if
	
	block
		var ans: []char :: #[n]char
		var j: int :: 0
		for i(9, 1, -1)
			for(1, a[i])
				do ans[j] :: '0'.offset(i)
				do j :+ 1
			end for
		end for
		if(ans <= k)
			do cui@print("-1\n")
			ret
		end if
	end block
	
	var ans: []char :: #[n]char
	var flag: bool :: false
	var failFlag: bool :: false
	for i(0, n - 1)
		if(!failFlag)
			for j(1, 9)
				if(a[j] <> 0)
					if(flag)
						do a[j] :- 1
						do ans[i] :: '0'.offset(j)
						skip i
					end if
					if('0'.offset(j) = k[i])
						do a[j] :- 1
						do ans[i] :: '0'.offset(j)
						skip i
					elif('0'.offset(j) > k[i])
						do flag :: true
						do a[j] :- 1
						do ans[i] :: '0'.offset(j)
						skip i
					end if
				end if
			end for
		end if
		do failFlag :: true
		for j(9, 1, -1)
			if(a[j] <> 0)
				do a[j] :- 1
				do ans[i] :: '0'.offset(j)
				skip i
			end if
		end for
	end for
	if(ans <= k)
		do @nextPermutation(ans)
	end if
	
	for i(0, n - 1)
		do cui@print("\{ans[i]}")
	end for
	do cui@print("\n")
end func

func nextPermutation(arr: []char): bool
	var len: int :: ^arr
	var left: int :: len - 2
	while(left >= 0 & arr[left] >= arr[left + 1])
		do left :- 1
	end while
	if(left < 0)
		ret false
	end if
	var right: int :: len - 1
	while(arr[left] >= arr[right])
		do right :- 1
	end while
	var tmp: char :: arr[left]
	do arr[left] :: arr[right]
	do arr[right] :: tmp
	do left :+ 1
	do right :: len - 1
	while(left < right)
		do tmp :: arr[left]
		do arr[left] :: arr[right]
		do arr[right] :: tmp
		do left :+ 1
		do right :- 1
	end while
	ret true
end func
0